$WS_EX_MDICHILD - How to create moveable child window with his parent?

[MrCreatoR]

Hi all...

I am trying to create a child window, that must move with his parent (when the parent moved, the child must move with it)...

From the help file:

$WS_EX_MDICHILD -> Create a child window that will be moved with its parent.

(simulation of a MDI window maximize/minimize are not simulated).

I am trying like this:

#include <GuiConstants.au3>

$Gui = GuiCreate("Test", 300, 200)
$ChildGui = GuiCreate("Child test", 300, 200, -1, -1, -1, $WS_EX_MDICHILD, $Gui)

$ParentPosArr = WinGetPos($Gui)
WinMove($ChildGui, "", $ParentPosArr[0]+$ParentPosArr[2], $ParentPosArr[1])

GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_SHOW, $ChildGui)

While 1
    $Msg = GUIGetMsg(1)
    Select
        Case $Msg[1] = $Gui And $Msg[0] = -3
            Exit
    EndSelect
WEnd

But only what i get, is some strange "effect" - the window of parent gui is kind of copying itself, and the screen is filed with it's "tail"... (until we minimize or close the parent window)

How to get it work? (move child widow with parent without any strange "effects").

P.S

I know that it's possible to do it using WinMove/WinGetPos etc... but why it's wont work with this style? (it also will save to as many lines of code).

Edited July 17, 2007 by MsCreatoR

[Siao]

The child is being moved alright, it's just the repaint that gets messed up for some reason.

Here's my lolsome solution:

#include <GuiConstants.au3>

$Gui = GuiCreate("Test", 300, 200)
$ChildGui = GuiCreate("Child test", 300, 200, -1, -1, -1, $WS_EX_MDICHILD, $Gui)

$ParentPosArr = WinGetPos($Gui)
WinMove($ChildGui, "", $ParentPosArr[0]+$ParentPosArr[2], $ParentPosArr[1])

GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_SHOW, $ChildGui)
GUIRegisterMsg(0x231, "On_WM_ENTERSIZEMOVE")
GUIRegisterMsg(0x232, "On_WM_EXITSIZEMOVE")

While 1
    $Msg = GUIGetMsg(1)
    Select
        Case $Msg[1] = $Gui And $Msg[0] = -3
            Exit
    EndSelect
WEnd
Func On_WM_ENTERSIZEMOVE()
    WinSetTrans($ChildGui, '', 254)
EndFunc
Func On_WM_EXITSIZEMOVE()
    WinSetTrans($ChildGui, '', 255)
EndFunc

There's a better way of doing it than this workaround, but I'm no GUI expert, so go from here on your own if you want.

Maybe WM_PAINT or something...

[evilertoaster]

#include <GuiConstants.au3>

$Gui = GuiCreate("Test", 300, 200)
$ChildGui = GuiCreate("Child test", 300, 200, -1, -1, -1,-1, $Gui)

$ParentPosArr = WinGetPos($Gui)
WinMove($ChildGui, "", $ParentPosArr[0]+$ParentPosArr[2], $ParentPosArr[1])

GUISetState(@SW_SHOW, $Gui)
GUIRegisterMsg (0x0003,"Move")
GUISetState(@SW_SHOW, $ChildGui)
GUIRegisterMsg (0x0003,"Move")

While 1
    $Msg = GUIGetMsg(1)
    Select
        Case $Msg[1] = $Gui And $Msg[0] = -3
            Exit
    EndSelect
WEnd
func Move($hWndGUI)
    if $hWndGUI=$Gui then
        $ParentPosArr = WinGetPos($Gui)
        WinMove($ChildGui, "", $ParentPosArr[0]+$ParentPosArr[2], $ParentPosArr[1])
    Else
        $ChildPosArr = WinGetPos($ChildGui)
        WinMove($Gui, "", $ChildPosArr[0]-$ChildPosArr[2], $ChildPosArr[1])
    EndIf
EndFunc

[MrCreatoR]

Thanks guys for the solution, but what i can not understand, is why the style $WS_EX_MDICHILD not working as it suppouse to, maby i should report about it as possible bug?

[evilertoaster]

http://en.wikipedia.org/wiki/Multiple_document_interface

MDI child windows are made so you can have a child window inside and parent window, not outside.