Replacing Whole Words Only (String)

[litlmike]

I would like to replace Whole Words only, not just any substring. For instance, if I want to replace the string "and", and I have the word "hand", StringReplace() outputs "h", I would like the output to still be "hand". Again, if I have "Hand and Foot", I would like to replace "and" with "&", I would like to have the output result in "Hand & Foot", not "H& & Foot". Below is an example of what currently takes place.

Thanks in Advance.

$String = "Hand and Foot"
$SearchString = "and"
$ReplaceString = "&"
MsgBox (0, "Test", "Original: " & $String & @CRLF & "Replaced: " & StringReplace ($String, $SearchString, $ReplaceString))

[martin]

I would like to replace Whole Words only, not just any substring. For instance, if I want to replace the string "and", and I have the word "hand", StringReplace() outputs "h", I would like the output to still be "hand". Again, if I have "Hand and Foot", I would like to replace "and" with "&", I would like to have the output result in "Hand & Foot", not "H& & Foot". Below is an example of what currently takes place.

Thanks in Advance.

$String = "Hand and Foot"
$SearchString = "and"
$ReplaceString = "&"
MsgBox (0, "Test", "Original: " & $String & @CRLF & "Replaced: " & StringReplace ($String, $SearchString, $ReplaceString))

But in for more general cases you will probably need StringRegExpReplace.

Edited July 25, 2007 by martin

[MrCreatoR]

Hi, try this my function...

expandcollapse popup

$String = 'Hand and Foot'
$Search = "and"
$Replace = "&"

$NewStr = _StringReplaceEx($String, $Search, $Replace, 3)

MsgBox(0, "Results", "New string is: " & $NewStr & @LF & "Replacments in string: " & @extended)

Func _StringReplaceEx($String, $SearchStr, $ReplaceStr, $Flag=0, $Count=0, $CaseSense=0)
    If $Flag <> 0 Then
        Switch $Flag
            Case 1
                If StringLeft($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, " " & $SearchStr, " " & $ReplaceStr, $Count, $CaseSense)
                EndIf
            Case 2
                If StringRight($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, $SearchStr & " ", $ReplaceStr & " ", $Count, $CaseSense)
                EndIf
            Case 3
                If StringLeft($String, StringLen($SearchStr)) = $SearchStr Or _
                        StringRight($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, " " & $SearchStr & " ", " " & $ReplaceStr & " ", $Count, $CaseSense)
                EndIf
            Case Else
                Return SetError(3, 0, $String)
        EndSwitch
    Else
        $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
    EndIf
    Return SetError(0, @extended, $String)
EndFunc

Flag = 0 - Will replace as standard StringReplace Function.

Flag = 1 - Will replace only if the founded string is whole word from left side

Flag = 2 - Will replace only if the founded string is whole word from right side

Flag = 3 - Will replace only if the founded string is whole word from bouth sides

[MrCreatoR]

Or using RegExp...

Func _StringReplaceEx($String, $SearchStr, $ReplaceStr, $Flag=0, $Count=0, $CaseSense=0)
    If $Flag <> 0 Then
        Local $CaseSensePrefix = "(?i)"
        If $CaseSense = 1 Then $CaseSensePrefix = ""
        Switch $Flag
            Case 1
                $String = StringRegExpReplace($String, $CaseSensePrefix & "\s" & $SearchStr, " " & $ReplaceStr, $Count)
            Case 2
                $String = StringRegExpReplace($String, $CaseSensePrefix & "" & $SearchStr & "\s", $ReplaceStr & " ", $Count)
            Case 3
                $String = StringRegExpReplace($String, $CaseSensePrefix & "\s" & $SearchStr & "\s", " " & $ReplaceStr & " ", $Count)
            Case Else
                Return SetError(3, 0, $String)
        EndSwitch
    Else
        $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
    EndIf
    Return SetError(0, @extended, $String)
EndFunc

[martin]

Hi, try this my function...

expandcollapse popup

$String = 'Hand and Foot'
$Search = "and"
$Replace = "&"

$NewStr = _StringReplaceEx($String, $Search, $Replace, 3)

MsgBox(0, "Results", "New string is: " & $NewStr & @LF & "Replacments in string: " & @extended)

Func _StringReplaceEx($String, $SearchStr, $ReplaceStr, $Flag=0, $Count=0, $CaseSense=0)
    If $Flag <> 0 Then
        Switch $Flag
            Case 1
                If StringLeft($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, " " & $SearchStr, " " & $ReplaceStr, $Count, $CaseSense)
                EndIf
            Case 2
                If StringRight($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, $SearchStr & " ", $ReplaceStr & " ", $Count, $CaseSense)
                EndIf
            Case 3
                If StringLeft($String, StringLen($SearchStr)) = $SearchStr Or _
                        StringRight($String, StringLen($SearchStr)) = $SearchStr Then
                    $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
                Else
                    $String = StringReplace($String, " " & $SearchStr & " ", " " & $ReplaceStr & " ", $Count, $CaseSense)
                EndIf
            Case Else
                Return SetError(3, 0, $String)
        EndSwitch
    Else
        $String = StringReplace($String, $SearchStr, $ReplaceStr, $Count, $CaseSense)
    EndIf
    Return SetError(0, @extended, $String)
EndFunc

Good idea but it needs some changes. Maybe the default $Count should be 1 not 0.

If you change the search string to "and hand foot" it will all go wrong.

[GEOSoft]

Better with StringRegExpReplace() as martin said.

It can also be done using _FileReadToArray() and StringSplit()

$F_Array = ""
_FileReadToArray($File, $F_Array)
For $I = 1 To Ubound($F_Array)-1
 $Line = StringSplit($F_Array[$I], Chr(32))
    $O_Line = ""
    For $J = 1 To $Line[0]
       If $Line[$J] = "and" Then $Line[$J] = "Replace"
       $O_Line &= $Line[$J] & Chr(32)
    Next
    $F_Array[$I] = $O_Line
Next

And then write $F_Array to $File

Edit: The word to search for and the replacement strings can also be sent as variables

$S = "and"
$R = "replace"

In the second loop use

If $Line[$J] = $S Then $LIne[$J] = $R

Another method is to do a StringReplace() that includes the white space so you don't need the second loop

$F_Array[$I] = StringReplace($F_Array[$I], " and ", " or ")

But that will fail in cases where there is no leading and trailing white space.

Edited July 25, 2007 by GEOSoft

[big_daddy]

This will work as well...

#include <Word.au3>
$oWordApp = _WordCreate(@ScriptDir & "\Test.doc")
$oDoc = _WordDocGetCollection($oWordApp, 0)
$oDoc.Range.Text = "Hand and Foot"
$oFind = _WordDocFindReplace($oDoc, "and", "&", 2, 0, 0, 1)

[bluebearr]

I'm no Regex expert, but doesn't this work?

$test = "This is my test text. It is about a hand and a foot. The " & @LF _
    & "hand wanted to be a head, " & @LF _
    & "and, also, the foot wanted the " & @LF _
    & "word 'and' tattooed on it. Theirs was a strange relationship."

MsgBox(0, "RegEx Replace Test", StringRegExpReplace($test, "\band\b", "&"))

[GEOSoft]

I'm no Regex expert, but doesn't this work?

$test = "This is my test text. It is about a hand and a foot. The " & @LF _
    & "hand wanted to be a head, " & @LF _
    & "and, also, the foot wanted the " & @LF _
    & "word 'and' tattooed on it. Theirs was a strange relationship."

MsgBox(0, "RegEx Replace Test", StringRegExpReplace($test, "\band\b", "&"))

What we are trying to show is that there are multiple methods of doing it.

RegExReplace was mentioned as the better method to use but some people are not comfortable with RegEx anything.

Edited July 25, 2007 by GEOSoft

[MrCreatoR]

Maybe the default $Count should be 1 not 0.

Why? if it 0 then all intance will be replaced, just as in standard StringReplace function.

See my last version.

[bluebearr]

RegExReplace was mentioned as the better method to use but some people are not comfortable with RegEx anything.

I hear that. I struggle through it every time I need to use it.

[martin]

Why? if it 0 then all intance will be replaced, just as in standard StringReplace function.

See my last version.

Only because, as I said, with your function to result of

$String = 'and so I handed the wand to Mandy'
$Search = "and"
$Replace = "&"

$NewStr = _StringReplaceEx($String, $Search, $Replace, 3)

is

"& so I h&ed the w$ to M&y" which is not what was wanted.

[litlmike]

Hmmm, this is quite interesting to see the differences of opinions here. I really thought that this would a clear cut issue that many have dealt with in the past, even though I couldn't find much by using "Search". It seems that StringRegEx will work as long as I specify a blank space (" ") before/after the word I am replacing?

Funny enough big_daddy's suggestion works nicely with the rest of the script I am using. However, is there a case where StringRegExpReplace will not work?

[GEOSoft]

However, is there a case where StringRegExpReplace will not work?

Not as far as I can foresee.

[MrCreatoR]

which is not what was wanted

I get this (with LAST VERSION):

and so I handed the wand to Mandy

If you want to replace only the "and ", then you must use $Flag = 2 and $Count = 1...

$String = 'and so I handed the wand to Mandy'
$Search = "and"
$Replace = "&"

$NewStr = _StringReplaceEx($String, $Search, $Replace, 2, 1)
ConsoleWrite($NewStr)

[SmOke_N]

I get this (with LAST VERSION):

If you want to replace only the "and ", then you must use $Flag = 2 and $Count = 1...

$String = 'and so I handed the wand to Mandy'
$Search = "and"
$Replace = "&"

$NewStr = _StringReplaceEx($String, $Search, $Replace, 2, 1)
ConsoleWrite($NewStr)

Some words aren't always just separated by spaces, you may want to see this thread: http://www.autoitscript.com/forum/index.ph...st&p=378823 and see the regexp that will more than likely be the closest for finding words.

[MrCreatoR]

Some words aren't always just separated by spaces

But if we search for "Whole word Only", that means that eather this word is founded like this: "..... Word .....", eather like this: "Word ....." (or also like this: ".... Word").

So for what this topic is about, i think my function is good enouth .

[bluebearr]

Just wanted to point out my example earlier. In it, '\b' is recognized by the StringRegExpReplace function as a word boundary, so it will only substitute '&' for 'and' if it is a whole word. Apparently, the '\b' anchor has a lot of intelligence in it regarding what constitutes a word boundary. This includes if the word 'and' is at the beginning of the line, at the end of a sentence, and surrounded by punctuation. In all of these circumstances, using the string ' and ' will fail.

In short, this code:

$test = "This is my test text. It is about a hand and a foot. The " & @LF _
    & "hand wanted to be a head, " & @LF _
    & "and, also, the foot wanted the " & @LF _
    & "word 'and' tattooed on it. Theirs was a strange relationship."

MsgBox(0, "RegEx Replace Test", StringRegExpReplace($test, "\band\b", "&"))

returns this result:

This is my test text. It is about a hand & a foot. The

hand wanted to be a head,

&, also, the foot wanted the

word '&' tattooed on it. Theirs was a strange relationship.

Note that the 'and's at the beginning of the line and with single quotes around them got properly substituted, but the 'hand's were not. Edited July 27, 2007 by bluebearr