How to set Tip on LV item?

[MrCreatoR]

Hi,

I would like to see "tip text" on every item of ListView when i hover them (text of current item content only, nothing else), but if possible, only if the text is can not be seen completly (the item line is to long) - Just like with TreeView controls.

For now i can not set tip at all, GuiCtrlSetTip() not work on ListView items, i don't realy know why .

Thanks for any help.

Edited July 31, 2007 by MsCreatoR

[MrCreatoR]

Is it possible at all?

[martin]

Is it possible at all?

It's possible but the only way I can do it is a bit messy. You find the coords of the mouse, work out the row and the column it's over and display the tooltip.

[MrCreatoR]

Thanks....

You find the coords of the mouse, work out the row and the column it's over and display the tooltip

Hm, how can i find out what item index (or ID) is under the mouse?

[smashly]

maybe you could use $LVS_EX_TRACKSELECT as part of the Listview ex_style then use

Global Const $LVNI_FOCUSED = 0x1 with GUIRegisterMsg()

I'm only stabbing in the dark and haven't tried it yet..

I was also looking at $LVS_EX_INFOTIP, but that only seems to show if the text extends past the column width,

also I didn't see a way to set the info tip with the text you want, it just displays the name that's not fully visable.

Cheers

Edit:

$LVS_EX_TRACKSELECT added as an ex style then you can get the id of any item moused over..

expandcollapse popup

#include <GUIConstants.au3>
#Include <GuiListView.au3>

;~ Global Const $LVS_EX_INFOTIP = 0x400
Global $Last

GUICreate("listview items",220,250, 100,200,-1)
GUISetBkColor (0x00E0FFFF)

$listview = GuiCtrlCreateListView ("col1  |col2|col3  ",10,10,200,150, -1, $LVS_EX_TRACKSELECT)
$button = GuiCtrlCreateButton ("Value?",75,170,70,20)
$item1=GuiCtrlCreateListViewItem("item2|col22|col23",$listview)
$item2=GuiCtrlCreateListViewItem("............item1|col12|col13",$listview)
$item3=GuiCtrlCreateListViewItem("item3|col32|col33",$listview)
$input1=GuiCtrlCreateInput("",20,200, 150)

GuiSetState()

While 1
  $msg = GuiGetMsg ()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $button
            MsgBox(0,"listview item",GUICtrlRead(GUICtrlRead($listview)),2)
        Case $msg = $listview
            MsgBox(0,"listview", "clicked="& GuiCtrlGetState($listview),2)
    EndSelect
 
    If _GUICtrlListViewGetHotItem($listview) <> -1 And _GUICtrlListViewGetHotItem($listview) <> $Last Then
       $Last = _GUICtrlListViewGetHotItem($listview)
       ToolTip(_GUICtrlListViewGetItemText($listview, _GUICtrlListViewGetHotItem($listview))) 
    Elseif _GUICtrlListViewGetHotItem($listview) = -1 Then
       $Last = -1
       ToolTip("")
    EndIf
WEnd

This was a very non cpu friendly crude way , but I still think there'd be a better way using GUIRegisterMsg(), I just haven't worked out exactly how ...yet

Edited August 3, 2007 by smashly

[MrCreatoR]

Thanks smashly! you save me once again!

I have made from your example an UDF that can be puted in the main loop...

expandcollapse popup

#include <GUIConstants.au3>
#Include <GuiListView.au3>

Global $LastHotItem

GUICreate("Listview Set ToolTip Demo")

$ListView = GuiCtrlCreateListView ("Column 1|Column 2|Column 3 ", 10, 10, 380, 380)

For $i = 1 To 10
    GuiCtrlCreateListViewItem("Item " & $i & "|SubItem " & $i & "|More SubItem " & $i, $ListView)
Next

GuiSetState()

While 1
    _GuiCtrlListViewSetToolTip($ListView, -1, $LastHotItem)
    Switch GuiGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GuiCtrlListViewSetToolTip($ListView, $SubItem, ByRef $LastHotItemHotItem)
    Local $GetCurInfo = GUIGetCursorInfo()
    Local $GetHotItem = _GUICtrlListViewGetHotItem($ListView)
    
    If IsArray($GetCurInfo) And $GetCurInfo[4] <> $ListView Then
        ToolTip("")
        Return
    EndIf
    
    If $GetHotItem <> -1 And $GetHotItem <> $LastHotItem Then
        $LastHotItem = $GetHotItem
        ToolTip(_GUICtrlListViewGetItemText($ListView, $GetHotItem, $SubItem))
    ElseIf $GetHotItem = -1 Then
        $LastHotItem = -1
        ToolTip("")
    EndIf
EndFunc

Thanks again!

If you find a better way to do it, please tell me, i know that it can be done with no using the main loop, but for now this solution is working fine!