Listview column header text (NOT GUI)

[EddieAdams]

This seems an obvious question but havent been able to find a similar question nor answer. How to get the text values from the column headers within a listview (NOT GUI)?

[lod3n]

PaulIA's Auto3Lib library of AutoIt functions contains _ListView_GetColumn, which should do this for you. Once you have it installed, dissect his "Listview 1.au3" example script to see how it works.

http://www.autoitscript.com/forum/index.php?showtopic=33677

[PsaltyDS]

You actually have to use both A3LListView.au3 AND A3LHeader.au3:

#include <GuiConstants.au3>
#include <A3LHeader.au3>
#include <A3LListView.au3>

$hGUI = GUICreate("ListView Edit Lable", 400, 300)
$ListView = GUICtrlCreateListView("col1|col2|col3", 10, 10, 380, 240)
GUICtrlCreateListViewItem("line1|data1|more1", $ListView)
GUICtrlCreateListViewItem("line2|data2|more2", $ListView)
GUICtrlCreateListViewItem("line3|data3|more3", $ListView)
GUICtrlCreateListViewItem("line4|data4|more4", $ListView)
GUICtrlCreateListViewItem("line5|data5|more5", $ListView)
$Btn_Header = GUICtrlCreateButton("Header", 150, 260, 100, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Btn_Header
            $hListView = ControlGetHandle($hGUI, "", $ListView)
            $iColCnt = _ListView_GetColumnCount ($hListView)
            ConsoleWrite("Debug: $iColCnt = " & $iColCnt & @LF)
            $hHeader = _ListView_GetHeader ($hListView)
            $sMsg = "ListView Column Headers:" & @CRLF
            For $i = 0 To $iColCnt - 1
                $sMsg &= @CRLF & $i & ": " & _Header_GetItemText ($hHeader, $i)
            Next
            MsgBox(64, "Results", $sMsg)
    EndSwitch
WEnd