FileOpenDialog() option 4

[Mast3rpyr0]

Is there a special function used for reading the output of FileOpenDialog() when multiple files are selected or to you have to use a bunch or _StringBetween()'s?

Edited August 16, 2007 by Mast3rpyr0

[MrCreatoR]

Is there a special function used for reading the output of FileOpenDialog() when multiple files are selected

No, you just make a litle, say, parser?

#include <Array.au3>

$Selected = FileOpenDialog("Title", "C:\", "All (*.*)", 4)

$SelectedArr = _GetSelected($Selected)

_ArrayDisplay($SelectedArr)


Func _GetSelected($String)
    Local $RetArr[1]
    If StringInStr($String, "|") Then
        Local $SplitArr = StringSplit($String, "|"), $InitPath = StringRegExpReplace($SplitArr[1], '([^\\])\\*$', '\1')
        For $i = 2 To UBound($SplitArr)-1
            ReDim $RetArr[UBound($RetArr) + 1]
            $RetArr[UBound($RetArr) - 1] = $InitPath & "\" & $SplitArr[$i]
        Next
        $RetArr[0] = UBound($RetArr) - 1
    Else
        Local $RetArr[2] = [1, $String]
    EndIf
    Return $RetArr
EndFunc

Edit: A litle correction to the function.

Edited August 16, 2007 by MsCreatoR

[Mast3rpyr0]

That looks liek something that will do something lol.

we'll see if it works. if so ill give credits to you, this is going into my BackupUtility

EDIT: Yup that did it thanks MsCreatoR

Edited August 16, 2007 by Mast3rpyr0

[Mast3rpyr0]

Any chance you could comment on each line. I have a habit of doing that and i have no idea what some lines do lol. Heres what i got so far:

; Written By MsCreatoR
Func _GetSelected($String); Parse Source filepath if needed.
    Local $RetArr[1]; Initialize $RetArr array
    If StringInStr($String, "|") Then; If $bkSrcz contains any "|"
        Local $SplitArr = StringSplit($String, "|")
        For $i = 2 To UBound($SplitArr)-1
            ReDim $RetArr[UBound($RetArr) + 1]
            $RetArr[UBound($RetArr) - 1] = $SplitArr[1] & $SplitArr[$i]
        Next
        $RetArr[0] = UBound($RetArr) - 1
    Else
        Local $RetArr[2] = [1, $String]
    EndIf
    Return $RetArr
EndFunc

[MrCreatoR]

Check now, i have made some corrections (in slashs (\) missing and the zero-based returned value of the array... now its return as it should - number of elements included in array).

[MrCreatoR]

Any chance you could comment on each line

Sorry, but it will be not so correct... i mean that english isn't my language, i dont believe my self that i am writing on english here on forums, i am learned my english from TV - i am not joking .

But its realy not hard to understtand it, it's just take the string returned from FileSelectFolder(), and then if it contain | (it's mean that there was selected more then one file), then the string is splited to array, and the first element is the path where was files selected, and else elements are the file names, then For...Next just "glue them" together so the will be as complete paths.

[Mast3rpyr0]

Ok thats fine, Thanks tho.