MsgBox not pause script

[Klexen]

I have a timer that pops up a Msgbox when it runs out. I have it continue counting during this period. However, you cant see time that has elapsed passed until you click ok on the msgbox.

Is there a way to prevent this from happening?

[cdkid]

Msgbox will pause the script until it's been closed. The only thing i can think of would be instead of msgbox() run another script that creates a msgbox so that one can continue.

~cdkid

[PsaltyDS]

I have a timer that pops up a Msgbox when it runs out. I have it continue counting during this period. However, you cant see time that has elapsed passed until you click ok on the msgbox.

Is there a way to prevent this from happening?

Code your own GuiCreate() instead of using the default MsgBox(). It's not that hard. Post what you get for some help if you get stuck.

[Valuater]

I have a timer that pops up a Msgbox when it runs out. I have it continue counting during this period. However, you cant see time that has elapsed passed until you click ok on the msgbox.

Is there a way to prevent this from happening?

; Move Message Box
; Author - herewasplato

_MoveMsgBox(0, "testTitle", "testText", 0, 10)

Func _MoveMsgBox($MBFlag, $MBTitle, $MBText, $x, $y)
    Local $file = FileOpen(EnvGet("temp") & "\MoveMB.au3", 2)
    If $file = -1 Then Return;if error, give up on the move
    
    Local $line1 = 'AutoItSetOption(' & '"WinWaitDelay", 0' & ')'
    Local $line2 = 'WinWait("' & $MBTitle & '", "' & $MBText & '")'
    Local $line3 = 'WinMove("' & $MBTitle & '", "' & $MBText & '"' & ', ' & $x & ', ' & $y & ')'
    FileWrite($file, $line1 & @CRLF & $line2 & @CRLF & $line3)
    FileClose($file)
    
    Run(@AutoItExe & " /AutoIt3ExecuteScript " & EnvGet("temp") & "\MoveMB.au3")
    
    MsgBox($MBFlag, $MBTitle, $MBText)
    
    FileDelete(EnvGet("temp") & "\MoveMB.au3")
EndFunc;==>_MoveMsgBox; Move Message Box

... Now they can see it... many other helpful scriptlets here too

Autoit Wrappers

8)

Edited August 19, 2007 by Valuater

[Klexen]

; Move Message Box
; Author - herewasplato

_MoveMsgBox(0, "testTitle", "testText", 0, 10)

Func _MoveMsgBox($MBFlag, $MBTitle, $MBText, $x, $y)
    Local $file = FileOpen(EnvGet("temp") & "\MoveMB.au3", 2)
    If $file = -1 Then Return;if error, give up on the move
    
    Local $line1 = 'AutoItSetOption(' & '"WinWaitDelay", 0' & ')'
    Local $line2 = 'WinWait("' & $MBTitle & '", "' & $MBText & '")'
    Local $line3 = 'WinMove("' & $MBTitle & '", "' & $MBText & '"' & ', ' & $x & ', ' & $y & ')'
    FileWrite($file, $line1 & @CRLF & $line2 & @CRLF & $line3)
    FileClose($file)
    
    Run(@AutoItExe & " /AutoIt3ExecuteScript " & EnvGet("temp") & "\MoveMB.au3")
    
    MsgBox($MBFlag, $MBTitle, $MBText)
    
    FileDelete(EnvGet("temp") & "\MoveMB.au3")
EndFunc;==>_MoveMsgBox; Move Message Box

... Now they can see it... many other helpful scriptlets here too

Autoit Wrappers

8)

Thanks guys...

@Valuater The reason they can't see elapsed time is not because of box is in the way of the timer. The timer stops counting up until you click OK. (Although after you do click ok and the timer starts counting again, it actually start counting from when timer stopped, not from time msgbox was clicked.) I will try creating a GUI instead of msgbox.

[MrCreatoR]

Move Message Box

But it's only for installed AutoIt, and what about compiled program?

I suggesting this method:

#NoTrayIcon

If $CmdLine[0] > 0 And $CmdLine[1] = "/ShowMsgBox" Then
    MsgBox(64, "MsgBox", "Some text")
    Exit
EndIf

Opt("TrayIconHide", 0)

_CallCmdLine("/ShowMsgBox")


For $i = 1 To 5000
    ConsoleWrite("Here is what the parent script process doing; Counting untill 5000 ;) [" & $i & "]" & @LF)
Next

Func _CallCmdLine($Cmd)
    Local $RunLine = @AutoItExe & ' "' & @ScriptFullPath & '" ' & $Cmd
    If @Compiled Then $RunLine = @AutoItExe & ' ' & $Cmd
    Run($RunLine)
EndFunc

[ChrisL]

But it's only for installed AutoIt, and what about compiled program?

No it's not!

When the application is compiled and even run on a computer without autoit installed you can still run a second third etc etc script by calling @Autoitexe & " /AutoIt3ExecuteScript "

It will use the autoit executable which is compilled

If you run Msgbox(0,"",@autoitexe) on a compiled script it will point to the compiled script!

Edited August 19, 2007 by ChrisL

[cramaboule]

I have a timer that pops up a Msgbox when it runs out. I have it continue counting during this period. However, you cant see time that has elapsed passed until you click ok on the msgbox.

Is there a way to prevent this from happening?

look here

[MrCreatoR]

When the application is compiled and even run on a computer without autoit installed you can still run a second third etc etc script by calling @Autoitexe & " /AutoIt3ExecuteScript "

Wow! so the compiled script can be used as an interpratator for sources scripts?! it's amaizing! thanks, i didn't know about it .

[MrCreatoR]

And about the moving MsgBox, it can be done without using temp files:

_MoveMsgBox(64, "Hello World!", "Hi!", 0, 10)

Func _MoveMsgBox($Flag, $Title, $Text, $X, $Y, $Time=0)
    Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(' & $Flag & ', ''' & $Title & ''', ''' & $Text & ''',' & $Time & ')"')
    WinWait($Title)
    WinMove($Title, $Text, $X, $Y)
EndFunc