UDF: _GaugeCopy

[piccaso]

Needs cp.exe From Unixtools (attached) to be in @ScriptDir or %PATH% to work.

No Multiple File support (jet?).

According to the docs of Unixtools cp.exe works only on NT, works nice on WinXP Sp1, can someone test other platforms?

and please tell me what you think.

is it usefull to someone else?

are the time and speed calculations correct? (not 100% sure about it)

suggestions? ...

expandcollapse popup

Func _GaugeCopy($source, $dest)
    Local $RunErrorsFatalBackup, $sourcesize, $cppid, $destsize, $progress, $timer, $eta, $spd
    If FileExists($source) == 0 Then Return 0
    If FileExists($dest) == 1 Then Return 0
   $RunErrorsFatalBackup = Opt("RunErrorsFatal", 0)
    $cppid = Run(@ComSpec & ' /c cp "' & $source & '" "' & $dest & '"', @ScriptDir,@SW_HIDE)
    If @error = 1 Then
      Opt("RunErrorsFatal", $RunErrorsFatalBackup)
        Return 0
    EndIf
   Opt("RunErrorsFatal", $RunErrorsFatalBackup)
    $timer = TimerInit()
    $sourcesize = FileGetSize($source)
    If $sourcesize > 524288 Then
        ProgressOn($dest, "")
        While ProcessExists($cppid)
            Sleep(500)
            $destsize = FileGetSize($dest)
            $progress = Int(100 / $sourcesize * $destsize)
            $spd = Round($destsize * 1000 / TimerDiff($timer) / 1024, 2); kb/sec
            $eta = Round(Round($sourcesize - $destsize, 0) / 1024 / $spd, 2); sec
            If $spd > 1024 Then 
                $spd = Round($spd / 1024, 2) & " Mb/Sec"
            Else
                $spd = $spd & " Kb/Sec"
            EndIf
            If $eta > 0 Then
                If $eta > 60 Then 
                    $eta = Round($eta / 60, 0) & " Min"
                Else
                    $eta = $eta & " Sec"
                EndIf
            Else
                $eta = "";
            EndIf
            ProgressSet($progress, "Eta: " & $eta & " @ " & $spd)
        Wend
        ProgressOff()   
    EndIf
   if FileExists($dest) Then Return 1
EndFunc

Edited October 2, 2004 by piccaso