unexpected error since 3.2.6.0

[PaulBaumann]

Hi,

I got a strange problem: Since 3.2.6.0 the script (part of it) below works well

if it's interpreted. It also works well if it's "compiled".

But after commenting the line "msgbox(0,"","comment me!")" the

compiled script will give an Error:

Line:-1

$error Arry variable subscript badly fromatted.

AutoIt3Wrapper GUI v.1.9.2

AutoIt 3.2.6.0

Can anyone help me?

Best wishes

Paul

expandcollapse popup

#Region;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=x.exe
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Res_Comment=Löschen von schädlichen Registy Einträgen aus der SVS Schichten
#AutoIt3Wrapper_Res_Fileversion=1.0.0.19
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
#AutoIt3Wrapper_Res_LegalCopyright=RAL
#EndRegion;**** Directives created by AutoIt3Wrapper_GUI ****


Dim $i
Const $start = "HKLM\SOFTWARE\fslrdr"

Dim $SuchString
Dim $pattern

Dim $KeyList[10000]
Dim $KeyListIdx = 0


FillList($start)
ReDim $KeyList[$KeyListIdx]

Func FillList($startpoint)
    
    Local $i = 0
    Local $var
    Local $KeyPath
        
    While True
        $i = $i + 1

        $var = RegEnumKey($startpoint, $i)
        msgbox(0,"","Comment me!")
        If @error <> 0 Then ExitLoop

        $KeyPath = $startpoint & "\" & $var
        $KeyList[$KeyListIdx] = $KeyPath
        $KeyListIdx += 1
        If $KeyListIdx = UBound($KeyList) Then ReDim $KeyList[UBound($KeyList) + 5000]
        FillList($KeyPath)
    WEnd
EndFunc  ;==>FillList

[weaponx]

$var = RegEnumKey($startpoint, $i)

msgbox(0,"","Comment me!")

If @error <> 0 Then ExitLoop

3rd line here is never going to get an @error because msgbox is always successful

Whatever @error is returned from RegEnumKey is being reset by msgbox

[PaulBaumann]

$var = RegEnumKey($startpoint, $i)

msgbox(0,"","Comment me!")

If @error <> 0 Then ExitLoop

3rd line here is never going to get an @error because msgbox is always successful

Whatever @error is returned from RegEnumKey is being reset by msgbox

That's not the point!

Compile this script using V3260 and run it. The script will run without an error.

Now commentout or delete the line msgbox... and compile again. Try to run it and you will get an

Line:-1

$error Arry variable subscript badly fromatted.

error.

NB. running this script using the interpreter, will give no error!

[MrCreatoR]

You get the error because that line with If @error <> 0 Then ExitLoop is activated (there is error from RegEnumKey), and the function is ended, then when you do Redim $KeyList[$KeyListIdx] (outside the function), you get the error message, because you can not redim on zero (0), witch is the value of $KeyListIdx (it's not changed since the function ended without any additions to variable $KeyListIdx).

And Btw: you will get the same error even if you not compile your script, just run it not from scite editor - you even see the line number where the error is accourd.

Edited August 30, 2007 by MsCreatoR

[Jos]

That's not the point!

Compile this script using V3260 and run it. The script will run without an error.

Now commentout or delete the line msgbox... and compile again. Try to run it and you will get an

Line:-1

$error Arry variable subscript badly fromatted.

error.

NB. running this script using the interpreter, will give no error!

Yes that is a valid point.

The "If @error" test will test the @error generated by MsgBox() when the line isn;t commented !

[PaulBaumann]

You get the error because that line with If @error <> 0 Then ExitLoop is activated (there is error from RegEnumKey), and the function is ended, then when you do Redim $KeyList[$KeyListIdx] (outside the function), you get the error message, because you can not redim on zero (0), witch is the value of $KeyListIdx (it's not changed since the function ended without any additions to variable $KeyListIdx).

And Btw: you will get the same error even if you not compile your script, just run it not from scite editor - you even see the line number where the error is accourd.

Ah, you're right in case the key to enum is not found at all.

Change Const $start = "HKLM\SOFTWARE\fslrdr" to a key that exists on your machine e.g. "HKLM\SOFTWARE" an try again.

I checked out this script with v3249 and it runs without any error, even if it's compiled.

Compiling with V3260 gives the error mentioned above!

[MrCreatoR]

Change Const $start = "HKLM\SOFTWARE\fslrdr" to a key that exists on your machine e.g. "HKLM\SOFTWARE" an try again.

I don't need to, i think that error that you talking about is causing by wrong ReDim usage...

Just do some Error checking and you will see:

FillList($start)
If $KeyListIdx = 0 Then
    MsgBox(0, "", "Error! - $KeyListIdx = 0")
Else
    ReDim $KeyList[$KeyListIdx]
EndIf

If the problem is not in the redim func, then check all possible errors that might causing this crash... when (and if) you find it, maybe you should report in Bug Report Forum.

[MrCreatoR]

And BTW: what you trying to do is much easyer to do it like this (and i doubt that this will cause any errors):

#include <Array.au3>

Global $RegRoot = "HKLM\SOFTWARE\fslrdr"
$RegListArr = ReadRegistry($RegRoot)

_ArrayDisplay($RegListArr)

Func ReadRegistry($sPath)
    Local $KeysListArr[1], $SubKeysListArr, $Instance = 0, $Enum, $CurrentKeyPath
    
    While 1
        $Instance += 1
        $Enum = RegEnumKey($sPath, $Instance)
        If @error Then ExitLoop
        
        $CurrentKeyPath = $sPath & "\" & $Enum
        
        ReDim $KeysListArr[UBound($KeysListArr)+1]
        $KeysListArr[UBound($KeysListArr)-1] = $CurrentKeyPath
        
        $SubKeysListArr = ReadRegistry($CurrentKeyPath)
        If IsArray($SubKeysListArr) Then
            For $j = 1 To UBound($SubKeysListArr)-1
                ReDim $KeysListArr[UBound($KeysListArr)+1]
                $KeysListArr[UBound($KeysListArr)-1] = $SubKeysListArr[$j]
            Next
        EndIf
    WEnd
    $KeysListArr[0] = UBound($KeysListArr)-1
    Return $KeysListArr
EndFunc