Calling a custom callback function for a Slider

[Angel]

I have a GUI with a slider in it. If I use the slider callback the callback function is only called when the user unclicks the mouse button. Instead, I'd like to call a function while the user drags the slider, updating my GUI "on the fly" everytime that he mouves the mouse, without him needing to unclick the mouse button.

To do so I want to use the GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND") trick (which I learnt in this forum). However I do not know which are the "notification codes" for the slider events. I looked in winuser.h, but I only found the combo, editbox, etc, but not the slider ones.

Does someone know where I can get those notification codes?

Thanks!

Angel

[MrCreatoR]

Hi,

I would like to know the "GuiRegisterMsg() Method" to, but here is the method i would using for now:

#include <GuiConstants.au3>

Global $LastSliderData = 0

$Gui = GuiCreate("Test")

$Label = GUICtrlCreateLabel("Slider Read is: 0", 20, 20, 200)
$Slider = GUICtrlCreateSlider(20, 40, 160, 30)

GUISetState()

While 1
    If $LastSliderData <> GUICtrlRead($Slider) Then
        $LastSliderData = GUICtrlRead($Slider)
        GUICtrlSetData($Label, "Slider Read is: " & $LastSliderData)
    EndIf
    
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Edited September 13, 2007 by MsCreatoR

[MrCreatoR]

Ok, after making a litle search on MSDN, i think i found a solution...

#include <GuiConstants.au3>

Global Const $WM_HSCROLL = 0x0114
Global Const $WM_VSCROLL = 0x0115

$Gui = GuiCreate("Slider Update Demo", 250, 200)

GUIRegisterMsg($WM_HSCROLL, "WM_HVSCROLL")
GUIRegisterMsg($WM_VSCROLL, "WM_HVSCROLL")

$Vertical_Label = GUICtrlCreateLabel("Vertical Slider Read: 0", 20, 20, 200)
$Horizontal_Label = GUICtrlCreateLabel("Horizontal Slider Read: 0", 80, 120, 200)

$Vertical_Slider = GUICtrlCreateSlider(20, 50, 30, 120, BitOr($GUI_SS_DEFAULT_SLIDER, $TBS_VERT))
$Horizontal_Slider = GUICtrlCreateSlider(60, 150, 160, 30)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func WM_HVSCROLL($hWndGUI, $MsgID, $WParam, $LParam)
    Switch $MsgID
        Case 277
            GUICtrlSetData($Vertical_Label, "Vertical Slider Read: " & GUICtrlRead($Vertical_Slider))
        Case 276
            GUICtrlSetData($Horizontal_Label, "Horizontal Slider Read: " & GUICtrlRead($Horizontal_Slider))
    EndSwitch
EndFunc

EDIT: Changed the example, now it's support the vertical slider as well

Edited September 13, 2007 by MsCreatoR

[rover]

Hi MsCreatoR

I've used this method of using an GUICtrlCreateInput with a vertical slider/trackbar?

in one of my projects.

I found this somewhere on the site awhile back

It addressed the GUI flicker problem with the label update.

expandcollapse popup

If ControlGetFocus($gui) = "msctls_trackbar321" Then
    If GUICtrlRead($Slider) <> GUICtrlRead($input) Then 
       GUICtrlSetData($input,GUICtrlRead($slider))
    EndIf
EndIfoÝ÷ Øý½æuçb¶Ú-ç±jje{*.r^t×¢³hjëh×6#include <GuiConstants.au3>

Global Const $WM_HSCROLL = 0x0114
Global Const $WM_VSCROLL = 0x0115

$Gui = GuiCreate("Slider Update Demo", 250, 200)

GUIRegisterMsg($WM_HSCROLL, "WM_HVSCROLL")
GUIRegisterMsg($WM_VSCROLL, "WM_HVSCROLL")

$Vertical_Label = GUICtrlCreateLabel("Vertical Slider Read:", 20, 20, 200)
$Horizontal_Label = GUICtrlCreateLabel("Horizontal Slider Read:", 80, 120, 200)

$Vinput = GUICtrlCreateInput("0", 120, 20, 30, 20, $ES_READONLY, $WS_EX_TRANSPARENT)
$Hinput = GUICtrlCreateInput("0", 190, 120, 30, 20, $ES_READONLY, $WS_EX_TRANSPARENT)

$Vertical_Slider = GUICtrlCreateSlider(20, 50, 30, 120, BitOr($GUI_SS_DEFAULT_SLIDER, $TBS_VERT))
$Horizontal_Slider = GUICtrlCreateSlider(60, 150, 160, 30)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func WM_HVSCROLL($hWndGUI, $MsgID, $WParam, $LParam)
    Switch $MsgID
        Case 277
            GUICtrlSetData($Vinput,GUICtrlRead($Vertical_Slider))
            ;GUICtrlSetData($Vertical_Label, "Vertical Slider Read: " & GUICtrlRead($Vertical_Slider))
        Case 276
            GUICtrlSetData($Hinput,GUICtrlRead($Horizontal_Slider))
            ;GUICtrlSetData($Horizontal_Label, "Horizontal Slider Read: " & GUICtrlRead($Horizontal_Slider))
    EndSwitch
EndFunc

[MrCreatoR]

Bad idea or No?

It's depending on what we need, if we need just to update a label, then you use simple way (as i shown with labels), but if you need no "touching" the label but update only numbers data (for example if the label text is readable from language file), then your example will help in that case.

[Angel]

Thanks for the tip guys. This did the trick! :-)

Angel

[MrCreatoR]

Here is example wich you can use as many sliders as you want without checking the $MsgID:

#include <GuiConstants.au3>

Global Const $WM_HSCROLL = 0x0114
Global Const $WM_VSCROLL = 0x0115

$Gui = GuiCreate("Slider Update Demo", 250, 200)

GUIRegisterMsg($WM_HSCROLL, "WM_HVSCROLL")
GUIRegisterMsg($WM_VSCROLL, "WM_HVSCROLL")

$Vertical_Label = GUICtrlCreateLabel("Vertical Slider Read: 0", 20, 20, 200)
$Horizontal_Label = GUICtrlCreateLabel("Horizontal Slider Read: 0", 80, 120, 200)

$Vertical_Slider = GUICtrlCreateSlider(20, 50, 30, 120, BitOr($GUI_SS_DEFAULT_SLIDER, $TBS_VERT))
$Horizontal_Slider = GUICtrlCreateSlider(60, 150, 160, 30)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func WM_HVSCROLL($hWndGUI, $MsgID, $WParam, $LParam)
    Switch $LParam
        Case GUICtrlGetHandle($Vertical_Slider)
            GUICtrlSetData($Vertical_Label, "Vertical Slider Read: " & GUICtrlRead($Vertical_Slider))
        Case GUICtrlGetHandle($Horizontal_Slider)
            GUICtrlSetData($Horizontal_Label, "Horizontal Slider Read: " & GUICtrlRead($Horizontal_Slider))
    EndSwitch
EndFunc