AdlibEnable

[Nahuel]

Maybe this is a stupid quick question: Why can't I use AdlibEnable more than once?

Example:

AdlibEnable("func1",1000)
AdlibEnable("func2",2000)

Func func1()
    SplashTextOn("","This is func1",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
EndFunc

Func func2()
    SplashTextOn("","This is func2",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
EndFunc

While 1
    Sleep(10)
WEnd

This will only call func2.

[Xenobiologist]

Hi,

so you have to put the logic in the one func.

So long,

Mega

[Nahuel]

Thanks but I'm not sure I get what you mean...

[AdmiralAlkex]

He means that you should merge the code from both functions into one since it is not possible to have two adlibs on at the same time

[wolf9228]

Maybe this is a stupid quick question: Why can't I use AdlibEnable more than once?

Example:

AdlibEnable("func1",1000)
AdlibEnable("func2",2000)

Func func1()
    SplashTextOn("","This is func1",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
EndFunc

Func func2()
    SplashTextOn("","This is func2",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
EndFunc

While 1
    Sleep(10)
WEnd

This will only call func2.

Parameters

function The name of the adlib function to call.

time [optional] how often in milliseconds to call the function. Default is 250 ms.

Return Value

None.

AdlibEnable("func1",1000) 


Func func1()
    SplashTextOn("","This is func1",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
    AdlibEnable("func2",2000)
EndFunc

Func func2()
    SplashTextOn("","This is func2",200,25,-1,-1,1)
    Sleep(500)
    SplashOff()
    AdlibEnable("func1",1000)
EndFunc

While 1
    Sleep(10)
WEnd

Edited September 16, 2007 by wolf9228

[PsaltyDS]

No need to modify the AdLibEnable() when it's called, just put the logic in the function to know what to do. This technique would allow an unlimited number of different timers:

HotKeySet("{ESC}", "_Quit")

AdlibEnable("_FuncX")

Global $Timer_1 = TimerInit(), $Timer_2 = TimerInit()

While 1
    Sleep(10)
WEnd

Func _FuncX()
    If TimerDiff($Timer_1) >= 2000 Then _Func1()
    If TimerDiff($Timer_2) >= 5000 Then _Func2()
EndFunc   ;==>_FuncX

Func _Func1()
    $Timer_1 = TimerInit()
    SplashTextOn("", "This is func1", 200, 25, -1, -1, 1)
    Sleep(500)
    SplashOff()
EndFunc   ;==>_Func1

Func _Func2()
    $Timer_2 = TimerInit()
    SplashTextOn("", "This is func2", 200, 25, -1, -1, 1)
    Sleep(500)
    SplashOff()
EndFunc   ;==>_Func2

Func _Quit()
    Exit
EndFunc   ;==>_Quit

[Nahuel]

^aahh awesome. Thanks a lot!