_SetFolderIcon

[XxXFaNtA]

Hey there

This is one of my first UDFs that I publish and I wanted to share it with you

It's just a simple Function to change some things on a Folder, for example the Icon and the BG Image

$pFolder is the Path to the Folder

$pIcon the Path to the Icon

$pIconIndex is the Index if the Icon is referring a dll

$sInfoTip will display a ToolTip when the Mouse is over the Folder

$pBG is the Path to the pattern Image

Func _SetFolderIcon($pFolder,$pIcon,$iIconIndex=0,$sInfoTip="",$pBG="")
    If StringInStr(FileGetAttrib($pFolder & "\desktop.ini"),"R") Then FileSetAttrib($pFolder & "\desktop.ini","-R")
    IniWrite($pFolder & "\Desktop.ini",".ShellClassInfo","IconFile",$pIcon)
    IniWrite($pFolder & "\Desktop.ini",".ShellClassInfo","IconIndex",$iIconIndex)
    FileSetAttrib($pFolder,"+S")
    If NOT $sInfoTip = "" Then IniWrite($pFolder & "\Desktop.ini",".ShellClassInfo","InfoTip",$sInfoTip)
    If NOT $pBG = "" Then IniWrite($pFolder & "\Desktop.ini","{BE098140-A513-11D0-A3A4-00c04FD706EC}","IconArea_Image",$pBG)
    FileSetAttrib($pFolder & "\Desktop.ini","+RSH")
    Return 1
EndFunc

Hope that somebody might find this usefull

It can be also improved to change some textColors I think, but that should be okay

Ah and don't forget to refresh either the Folder or if you changed the BG of it to go out the folder and in again

FaNtA

[Achilles]

I like this, it should prove useful.

I have a suggestion though, it wouldn't be that hard to detect if the window that your changing is open so you could automatically refresh it if it is open (or if it's a folder in quick launch then refresh that). That's just my opinion...

[MrCreatoR]

A while ago i needed such function, and i wrote it like this :

Func _DirSetIcon($Dir_Path, $IconFile, $IconIndex=0, $TipText="")
    If Not StringInStr(FileGetAttrib($Dir_Path), "D") Then Return SetError(1, 0, -1)
    $Dir_Path = StringRegExpReplace($Dir_Path, '\\+\z', '')
    
    If StringRight($Dir_Path , 1) = ':' Then
        Local $IconStr = '"' & $IconFile & '", ' & $IconIndex
        If $IconIndex = 0 Then $IconStr = $IconFile
        If $IconFile = -1 Then $IconStr = ''
        IniWrite($Dir_Path & '\Autorun.inf', 'Autorun', 'icon', $IconStr)
        DriveSetLabel($Dir_Path, DriveGetLabel($Dir_Path))
        Return 1
    EndIf
    
    Local $DirSetFile = $Dir_Path & "\Desktop.ini"
    FileSetAttrib($DirSetFile, "-R")
    IniWrite($DirSetFile, ".ShellClassInfo", "IconFile", $IconFile)
    IniWrite($DirSetFile, ".ShellClassInfo", "IconIndex", $IconIndex)
    IniWrite($DirSetFile, ".ShellClassInfo", "InfoTip", $TipText)
    
    FileSetAttrib($DirSetFile, "+R")
    
    If Not FileSetAttrib($Dir_Path, "S") Then Return SetError(2, 0, 0)
    If Not FileSetAttrib($DirSetFile, "+HS") Then Return SetError(3, 0, 0)
    EnvUpdate()
    
    $ExplorerWinArr = WinList("[CLASS:CabinetWClass]")
    For $i = 1 To $ExplorerWinArr[0][0]
        If ControlGetText($ExplorerWinArr[$i][1], "", "Edit1") = StringLeft($Dir_Path, StringInStr($Dir_Path, "\", 0, -1)) Then
            WinActivate($ExplorerWinArr[$i][1])
            WinWaitActive($ExplorerWinArr[$i][1], "", 5)
            Send("{F5}")
            ExitLoop
        EndIf
    Next
    Return 1
EndFunc

As you can see, it works also on Drives.

Edited September 20, 2007 by MsCreatoR