Ijji GameLoader

[Generator]

Hmm, I haven't been releasing in these days, school is busy and i have lessons after school. Not going to make a long story here, made a while ago and been using it for few months ;basically this is a program that logs you in to Ijji.com and launch the game for you without you entering the website, it uses IE UDF, and thanks for the example lod3n and Au3Lib maker. The Login came from my IE Automation thread(see sig).

Something to do:

Make the combo box read only(didn't find a way)

Make curl transparent edge for the png

Here is the source:

expandcollapse popup

#NoTrayIcon
#include<A3LGDIPlus.au3>
#include<GUIConstants.au3>
#include<GUICombo.au3>
#include<Misc.au3>
#include<IE.au3>
Opt("GUIOnEventMode", 1)

_Singleton("Ijji GameLoader")
DirCreate(@AppDataDir & "\Ijji GameLoader\Images\")
FileInstall("GameGuard.png", @AppDataDir & "\Ijji GameLoader\Images\GameGuard.png", 1)
FileInstall("BkImage.jpg", @AppDataDir & "\Ijji GameLoader\Images\BkImage.jpg", 1)

Global Const $AC_SRC_ALPHA = 1
Global Const $ULW_ALPHA = 2

_GDIP_Startup ()
$PngDir = @AppDataDir & "\Ijji GameLoader\Images\GameGuard.png"
$hImage = _GDIP_ImageLoadFromFile ($PngDir)
$Width = _GDIP_ImageGetWidth ($hImage)
$Height = _GDIP_ImageGetHeight ($hImage)
$mainfrm = GUICreate("Ijji GameLoader", $Width, $Height, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
_SetBitmap($mainfrm, $hImage, 0)
GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")
GUISetState()
WinSetOnTop($mainfrm, "", 1)
For $i = 0 To 255 Step 5
    _SetBitmap($mainfrm, $hImage, $i)
Next
$childfrm = GUICreate("ControlGUI", $Width, $Height, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $mainfrm)
GUICtrlCreatePic(@AppDataDir & "\Ijji GameLoader\Images\BkImage.jpg", 0, 0, $Width, $Height)
GUICtrlSetState(-1, $GUI_DISABLE)
$Combo = GUICtrlCreateCombo("", 20, 5, 300, 20, -1)
GUICtrlSetData($Combo, "Soldier Front|Gunbound|Gunz|Kwonho|Drift City|Royal Chess|GoStop|Rounders Poker", "Soldier Front")
GUICtrlSetFont($Combo, 12, 500, 0, "Tahoma")
_GUICtrlComboSetCurSel($Combo, 0)
GUICtrlCreateLabel("UserName:", 20, 45, 85, 20, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
GUICtrlSetFont(-1, 12, 500, 0, "Tahoma")
GUICtrlCreateLabel("Password:", 20, 70, 85, 20, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
GUICtrlSetFont(-1, 12, 500, 0, "Tahoma")
$nameinput = GUICtrlCreateInput("UserName", 110, 45, 210, 20)
GUICtrlSetFont(-1, 10, 400, 0, "Tahoma")
$passinput = GUICtrlCreateInput("Password", 110, 70, 210, 20, $ES_PASSWORD)
GUICtrlSetFont(-1, 10, 400, 0, "Tahoma")
GUICtrlCreateButton("Log Me In", 180, 100, 140, 30, $BS_DEFPUSHBUTTON)
GUICtrlSetFont(-1, 12, 500, 0, "Tahoma")
GUICtrlSetBkColor(-1, 0xFFFFFF)
GUICtrlSetOnEvent(-1, "_LogIn")
GUICtrlCreateButton("Registration", 20, 100, 140, 30)
GUICtrlSetFont(-1, 12, 500, 0, "Tahoma")
GUICtrlSetBkColor(-1, 0xFFFFFF)
GUICtrlSetOnEvent(-1, "_Register")
GUISetState()
While 1
    If _IsPressed("1B") And WinActive($mainfrm, "") Then _Bye()
    If _IsPressed("0D") And WinActive($mainfrm, "") Then _LogIn()
    Sleep(1)
WEnd
Func _LogIn()
    Do
        Sleep(1)
    Until Not _IsPressed("0D")
    $Index = _GUICtrlComboGetCurSel($Combo)
    Select
        Case $Index = 0
            $Game = "sfront"
        Case $Index = 1
            $Game = "gunbound"
        Case $Index = 2
            $Game = "gunz"
        Case $Index = 3
            $Game = "kwonho"
        Case $Index = 4
            $Game = "drift"
        Case $Index = 5
            $Game = "chess"
        Case $Index = 6
            $Game = "gostop"
        Case $Index = 7
            $Game = "rounders"
    EndSelect
    _IjjiGameLoad(GUICtrlRead($nameinput), GUICtrlRead($passinput), $Game, Ping("http://" & $Game & ".ijji.com/") + 5500)
EndFunc   ;==>_LogIn
Func _Bye()
    For $i = 255 To 0 Step - 5
        _SetBitmap($mainfrm, $hImage, $i)
    Next
    _API_DeleteObject ($hImage)
    _GDIP_Shutdown ()
    Exit
EndFunc   ;==>_Bye
Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($hWnd = $mainfrm) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST
Func _SetBitmap($hGUI, $hImage, $iOpacity)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _API_GetDC (0)
    $hMemDC = _API_CreateCompatibleDC ($hScrDC)
    $hBitmap = _GDIP_BitmapCreateHBITMAPFromBitmap ($hImage)
    $hOld = _API_SelectObject ($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIP_ImageGetWidth ($hImage))
    DllStructSetData($tSize, "Y", _GDIP_ImageGetHeight ($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", $AC_SRC_ALPHA)
    _API_UpdateLayeredWindow ($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _API_ReleaseDC (0, $hScrDC)
    _API_SelectObject ($hMemDC, $hOld)
    _API_DeleteObject ($hBitmap)
    _API_DeleteDC ($hMemDC)
EndFunc   ;==>_SetBitmap
Func _IjjiGameLoad($oUserName, $oPassword, $oGameType, $oTimeout)
    Local $oIE, $oForm, $oQuery, $o_Query
    _IEErrorHandlerRegister()
    _IELoadWaitTimeout($oTimeout)
    ProgressOn("Ijji GameLoader", "", "")
    $oIE = _IECreate("http://" & $oGameType & ".ijji.com/", 0, 0, 1)
    WinSetState(_IEPropertyGet($oIE, "hwnd"), "", @SW_HIDE)
    For $i = 1 To 20
        ProgressSet($i)
        Sleep(150)
    Next
    _IELoadWait($oIE, $oTimeout, $oTimeout)
    ProgressSet(40)
    $oForm = _IEGetObjById($oIE, "form")
    $oQuery = _IEGetObjByName($oIE, "memberid")
    $o_Query = _IEGetObjByName($oIE, "password")
    _IEFormElementSetValue($oQuery, $oUserName)
    _IEFormElementSetValue($o_Query, $oPassword)
    ProgressSet(60)
    _IEFormSubmit($oForm)
    For $i = 60 To 80
        ProgressSet($i)
        Sleep(100)
    Next
    _IELoadWait($oIE, $oTimeout, $oTimeout)
    _IELinkClickByText($oIE, "Play Live Button", 0)
    ProgressSet(100)
    Sleep(2500)
    ProgressOff()
    _IEErrorHandlerDeRegister()
    _IEQuit($oIE)
EndFunc   ;==>_IjjiGameLoad
Func _Register()
    _IECreate("http://member.ijji.com/register.nhn", 0, 1, 0, 0)
EndFunc   ;==>_Register

Edited October 11, 2007 by Generator

[JustinReno]

I'm guessing to disable the combo box you could use $Gui_Disabled or something like that as a style?

[Generator]

I'm guessing to disable the combo box you could use $Gui_Disabled or something like that as a style?

Didn't think it would work, just tried, you can't select anything from combobox after you disable it.

[Kreatorul]

UUh 10x so much I was gettin' tired of having to login to play gunz