Button inside input?

[MrCreatoR]

Hi,

How can i create a button inside input?

Like this (see img):

When i create it on the same position as input, then if i click the input it become kind of "on top" of the button ...

$Gui = GuiCreate("Test", 320, 100)

$Input = GUICtrlCreateInput("C:\", 10, 40, 300, 22)
$Button = GUICtrlCreateButton("...", 290, 42, 18, 18)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

I tryed use $GUI_ONTOP state on the button, but it not solve the problem..

[MrCreatoR]

The only solution i can see is this (very unstable)...

expandcollapse popup

#include <GuiConstants.au3>

Global Const $WM_COMMAND = 0x0111
Global Const $EN_CHANGE = 0x300
Global Const $EN_SETFOCUS = 0x100

$Gui = GuiCreate("Test", 320, 100)

$Input = GUICtrlCreateInput("C:\", 10, 40, 300, 22)
$Button = GUICtrlCreateButton("...", 290, 42, 18, 18)

GUISetState()
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $Button
            MsgBox(0, "", "Button Pressed")
    EndSwitch
    
    $CurInfo = GUIGetCursorInfo($Gui)
    If IsArray($CurInfo) Then
        If ($CurInfo[4] = $Input Or $CurInfo[4] = $Button) And $CurInfo[2] = 1 Then GUICtrlSetState($Button, $GUI_SHOW)
        If $CurInfo[4] = $Button And $CurInfo[2] = 1 Then ControlClick($Gui, "", $Button)
    EndIf
WEnd

Func WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $hCtrl = $lParam
    
    Switch $nID
        Case $Input
            Switch $nNotifyCode
                Case $EN_SETFOCUS, $EN_CHANGE
                    GUICtrlSetState($Button, $GUI_SHOW)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

[smashly]

Hi,

That looks ever so complex, maybe simplicity is the answer

#include <GUIConstants.au3>
$Gui = GuiCreate("Test", 320, 100)
$Button = GUICtrlCreateButton("...", 290, 42, 18, 18)
$Input = GUICtrlCreateInput("C:\", 10, 40, 300, 22, $WS_CLIPSIBLINGS)


GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Cheers

[MrCreatoR]

Thanks!!! i knew that this will be easy, i just didn't knew where to look (are you checked all styles , or this is an old practice knowlage?)

[smashly]

Your welcome,

I think it's an old prctice , I found it when trying to put an icon on a button or label.

$WS_CLIPSIBLINGS is handy for most overlaying controls , just sometimes you need to reorder the way your controls are created in to get it to work right.

Cheers