Creating new windows explorer window

[CrimsonRiot]

How would I create a new explorer window to open a specific location, such as "c:\WINDOWS\system32\"?

[NELyon]

$dirPath = "c:\WINDOWS\system32"

If FileExists($dirPath) Then
      run("explorer.exe "& $dirPath)
Else
      MsgBox(0, "error", "Directory does not exist")
EndIf

[weaponx]

Make sure you put the path in quotes if it has spaces in it.

$dirPath = "c:\WINDOWS\system32"
If FileExists($dirPath) Then
      run('explorer.exe "'& $dirPath & '"')
Else
      MsgBox(0, "error", "Directory does not exist")
EndIf

[CrimsonRiot]

excellent! ty very much. I was on the right track, just needed a little push.

[NELyon]

Make sure you put the path in quotes if it has spaces in it.

$dirPath = "c:\WINDOWS\system32"
If FileExists($dirPath) Then
      run('explorer.exe "'& $dirPath & '"')
Else
      MsgBox(0, "error", "Directory does not exist")
EndIf

I didn't really bother as c:\WINDOWS\system32\ doesn't have any spaces in it

[JohnBailey]

Another Method:

Local $dirPath = "c:\WINDOWS\system32"
If Not FileExists($dirPath) Then
      MsgBox(0, "Explorer Open - Error", "Directory does not exist: "&$dirPath)
      Exit
EndIf
$oShell = ObjCreate("shell.application") 
$oShell.open($dirPath)
;OR $oShell.explore($dirPath); this will get the explorerbar to open with the Folders toolbar

If you're interested in control it once it's opened

Local $dirPath = "c:\WINDOWS\system32"
If Not FileExists($dirPath) Then
      MsgBox(0, "Explorer Open - Error", "Directory does not exist: "&$dirPath)
      Exit
EndIf
$oShell = ObjCreate("shell.application") 
Local $oShellWindows = $oShell.windows
Local $currentTotal = $oShell.windows.count;First get the current explorer window count
Local $PreviousBound = $currentTotal-1;Used later
$oShell.open($dirPath);Open new
$PreviousBound +=1
        While 1;This will give it time to open (if you don't do this it will error out)
            Local $currentTotal = $oShell.windows.count
            ConsoleWrite('$currentTotal: '&$currentTotal & ' vs '&($PreviousBound+1)&@LF)
            If  $currentTotal = ($PreviousBound+1) Then
                ExitLoop
            EndIf           
            Sleep(100)          
        WEnd
Local $Window = $oShell.windows.item($PreviousBound)
Local $WindowHwnd = HWnd($window.HWnd());NOW you have the Handler for the new Explorer Window
; Examples for manipulation to the new Explorer Window
WinSetTitle($WindowHwnd,'','New Window')


MsgBox(0,'Explorer Command','Navigation to C:\ will take place in five seconds or on ok.',5)
$window.Navigate('C:\'); Notice how with the COM commands you don't use the HWnd