Find memory usage of process

[Traciatim]

I'm looking for a way to find the memory usage of a process, is there a simple way to do this?

[weaponx]

PSalty made a ProcessGetProperties() UDF:

http://www.autoitscript.com/forum/index.ph...mp;#entry409276

I also used it to graph cpu usage:

http://www.autoitscript.com/forum/index.php?showtopic=55877

[schilbiz]

This link may be useful as well... http://www.autoitscript.com/forum/lofivers...php?t53973.html

[Sardith]

Global Const $PROCESS_QUERY_INFORMATION = 0x400
Global Const $PROCESS_VM_READ = 0x10


MsgBox(0,"",_ProcessGetMemoryUsage("iTunes.exe"))

Func _ProcessGetMemoryUsage($sProcess)
    ;get process ID
    $nPID = ProcessExists($sProcess)
    If $nPID = 0 Then Return -1
    ;get process handle, required for GetProcessMemoryInfo
    $aRet = DllCall("Kernel32.dll", "int", "OpenProcess", _
                                        "dword", $PROCESS_QUERY_INFORMATION+$PROCESS_VM_READ, "dword", False, "dword", $nPID)
    If @error Or ($aRet[0] = 0) Then Return -1
    $hProc = $aRet[0]
    ;create PPROCESS_MEMORY_COUNTERS to receive data, required for GetProcessMemoryInfo
    $structPROCESS_MEMORY_COUNTERS = DllStructCreate("dword; dword; uint peakmemsize; uint memsize; uint; uint; uint; uint; uint; uint")
    $nSize = DllStructGetSize($structPROCESS_MEMORY_COUNTERS)
    ;call GetProcessMemoryInfo
    $aRet = DllCall("Psapi.dll", "int", "GetProcessMemoryInfo", _
                                        "hwnd", $hProc, "ptr", DllStructGetPtr($structPROCESS_MEMORY_COUNTERS), "dword", $nSize)
    ;close process handle
    DllCall("Kernel32.dll", "int", "CloseHandle", "hwnd", $hProc)
    ;return memory size in kb
    Return DllStructGetData($structPROCESS_MEMORY_COUNTERS, "memsize") / 1024
EndFunc

[Traciatim]

Thanks for the awesome quick responses.

[Azmin87]

Sardith,

 

The codes above given,the result in KB or MB?

[user4157124]

Kilobyte (in byte if you remove /1024 from return keyword).

[Nine]

very old thread ... 2007.  there is a current process call that do it in bytes : ProcessGetStats ("process.exe")