Countdown to a reboot

[mbouchard]

I am working on a reboot script that can be called from another script with the time to wait till reboot. I think that I have a basic script working but think that I know of one point of failure. I am using @hour @ min and to get the start time and then using @hour@min+my commandline to get the end time. I then compare the two. My problem pops up if the start time is just before the bottom of the hour and the command line would push the end time over 60.

Also, I am trying to figure out how to have a countdown in my message box so that the user will know how much time they have left before a reboot will happen. I have thought about using a progress bar but lose the ability to give a way to reboot immediately.

Any ideas would be apprciated,

Mike

If $CmdLine[0]>0 then
  $mTime = $CmdLine[1]
  $begin = @Hour & ":" & @min
  $end = @Hour & ":" & @min + $mTime
EndIf

MsgBox(48, "Test", "To complete the install, your computer will be rebooted in " & $mTime & " minute(s) at " & $end & "." & @CR & @CR & "Clicking the OK button below will cause the computer to reboot now." & @CR & "The reboot is automatic and there will be no further warning messages. ",$mTime*60)

Do
Sleep(2000)
Until @Hour & ":" & @min > $End

MsgBox(48, "Test2", "Start: " & $begin & " End: " & @hour & ":" & @min,100)
;Shutdown(6) ;Force a reboot

[CyberSlug]

$timeInHours = 2
$timeInMilliseconds = $timeInHours * 60 * 60 * 1000 

$t = TimerInit()
While TimerDiff($t) < $timeInMilliseconds
   sleep(1000)
 ;stuff could go here such as a progress meter
 ;  depending on the value of TimerDiff($t)
WEnd

[ezzetabi]

For $c = 10 to 0 Step -1
   ToolTip('Secs ' & $c)
Next
Shutdown(9+4)

[charlesg7]

mbouchard

Did you by chance come up with  a solution?? I could really use it for a couple of servers...

[UEZ]

This thread is over 10 years old!

Anyhow, try this:

#AutoIt3Wrapper_Change2CUI=y
#include <Date.au3>
#include <EditConstants.au3>

If Not $CmdLine[0] Then Exit ConsoleWrite(@CRLF & "Usage: RebootWrapper.exe <seconds>" & @CRLF & @CRLF)
Global $iSeconds = Int($CmdLine[1])
Global Const $hGUI = GUICreate("RebootWrapper", 320, 200)
Global Const $iLabel_Text = GUICtrlCreateLabel("System will be rebooted in: ", 10, 50, 190, 20)
GUICtrlSetFont(-1, 12)
GUICtrlSetBkColor(-1, 0xFF0000)
Global Const $iInp_Seconds = GUICtrlCreateInput("", 210, 50, 30, 20, BitOR($ES_NUMBER, $ES_READONLY))
Global Const $iBtn_Abort = GUICtrlCreateButton("Abort", 10, 120, 100, 50)
Global Const $iBtn_Now = GUICtrlCreateButton("Reboot now", 200, 120, 100, 50)
GUISetState()
Global $sEndTime = _DateAdd("s", $iSeconds, _NowCalc()), $sDiff

Do
    $sDiff = _DateDiff("s", _NowCalc(), $sEndTime)
    GUICtrlSetData($iInp_Seconds, $sDiff)
    If $sDiff < 1 Then ExitLoop
    Switch GUIGetMsg()
        Case $iBtn_Abort
            GUIDelete()
            ConsoleWrite("Rebooting has been aborted!" & @CRLF)
            Exit
        Case $iBtn_Now
            ExitLoop
    EndSwitch
Until False
GUIDelete()
ConsoleWrite("Rebooting system..." & @CRLF)

 

Edited May 28, 2015 by UEZ

[water]

mbouchard has been offline for 2 years. You do not expect him to answer, do you