API to Turn Off Monitor

[elvis]

Do you know the DLL for turn off the monitor ?

thanks

elvis

[Micha1405]

Hi i found this in the forum

expandcollapse popup

AdlibEnable("Mem")
MsgBox(0, "Started", @ScriptName & " has started.... F12 = Monitor off, F11 = Monitor on, Esc = Exit Program.")
Opt ("WinTitleMatchMode", 4)
While 1
    Sleep(10)
    If _IsPressed(0x1B) Then
        $hwnd = WinGetHandle('classname=Progman')
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', -1)
        MsgBox(0, "Closing...", "Closing program.....")
        Exit
    ElseIf _IsPressed(0x7A) Then
        $hwnd = WinGetHandle('classname=Progman')
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', -1)
        Sleep(10)
    ElseIf _IsPressed(0x7B) Then
        $hwnd = WinGetHandle('classname=Progman')
        Sleep(500)
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', 2)
        Sleep(10)
    EndIf
    Sleep(20)
WEnd
Func _IsPressed($hexKey)
    Global $aR, $bRv
    $dll = DllOpen("user32.dll")
    $aR = DllCall($dll, "int", "GetAsyncKeyState", "int", $hexKey)
    DllClose($dll)
    If $aR[0] <> 0 Then
        $bRv = 1
    Else
        $bRv = 0
    EndIf
    Return $bRv
EndFunc;==>_IsPressed
Func Mem()
    Local $aHandle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1F0FFF, 'int', False, 'int', -1), $aReturn = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $aHandle[0])
    DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $aHandle[0])
    Return $aReturn[0]
EndFunc;==>Mem

[MrCreatoR]

found this in the forum

This example is good, but when you move the mouse, monitor is on .

Here is more advanced example:

expandcollapse popup

#NoTrayIcon

Global $MonitorIsOff = False
Global $hwnd = WinGetHandle('[CLASS:Progman]')

HotKeySet("{F11}", "Monitor_Off")
HotKeySet("{F10}", "Monitor_On")
HotKeySet("{Esc}", "Quit")

MsgBox(64, "Monitor On/Off", "Press F11 to turn off the monitor." & @LF & _
                            "Press F10 to turn on the monitor back." & @LF & _
                            "Press ESC to turn on the monitor and exit program.")

While 1
    Sleep(10)
WEnd

Func Quit()
    Monitor_On()
    Exit
EndFunc

Func Monitor_On()
    DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', -1)
    $MonitorIsOff = False
EndFunc

Func Monitor_Off()
    $MonitorIsOff = True
    While $MonitorIsOff = True
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', 2)
        Sleep(10)
        _IdleWaitCommit(0)
    WEnd
EndFunc

Func _IdleWaitCommit($idlesec)
    Local $iSave, $LastInputInfo = DllStructCreate ("uint;dword")
    DllStructSetData ($LastInputInfo, 1, DllStructGetSize ($LastInputInfo))
    DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
    Do
        $iSave = DllStructGetData ($LastInputInfo, 2)
        Sleep(100)
        DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
    Until (DllStructGetData ($LastInputInfo, 2)-$iSave) > $idlesec Or $MonitorIsOff = False
    Return DllStructGetData ($LastInputInfo, 2)-$iSave
EndFunc

[elvis]

thanks all !!!!

for turn off monitor, i used only this 3 instructions:

Opt ("WinTitleMatchMode", 4)

$hwnd = WinGetHandle('classname=Progman')

DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', $hwnd, 'int', 274, 'int', 61808, 'int', 2)

Edited November 20, 2007 by elvis

[MrCreatoR]

for turn off monitor, i used only this 3 instructions:

In that case you can use only one instruction:

DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', WinGetHandle('[CLASS:Progman]'), 'int', 274, 'int', 61808, 'int', 2)