Avoid High CPU Usage

[Jester009]

Hi,

I'm trying to make a reminder program. I have come up with a code, but the problem is it makes my cpu usage to go very high

_NowTime() specially makes it very high. How can I avoid this??

#include <GUIConstants.au3>
#include <Date.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 271, 143, 193, 125)
$Input1 = GUICtrlCreateInput("", 48, 40, 41, 21)
$Input2 = GUICtrlCreateInput("", 112, 40, 41, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            Exit
        Case String(_NowTime(5)) = GUICtrlRead($Input1)&":"&GUICtrlRead($Input2)&":00"
            MsgBox(0, "Reminder", "Some Text")
    EndSelect
WEnd

Please help...

Thanks

Jester009

[MrCreatoR]

Hi,

In this specific case you can use the macros directly:

#include <GUIConstants.au3>
#include <Date.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 271, 143, 193, 125)
$Input1 = GUICtrlCreateInput("", 48, 40, 41, 21)
$Input2 = GUICtrlCreateInput("", 112, 40, 41, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            $Input1Read = GUICtrlRead($Input1)
            $Input2Read = GUICtrlRead($Input2)
            If $Input1Read <> "" And $Input2Read <> "" And GetNowTime() = $Input1Read & ":" & $Input2Read & ":00" Then
                MsgBox(0, "Reminder", "Some Text")
                ;.....
            EndIf
    EndSwitch
WEnd

Func GetNowTime()
    Return @HOUR & ":" & @MIN & ":" & @SEC
EndFunc

[Jester009]

Hi MsCreatoR,

Thanks for replying. Even on your script the CPU usage stays high.

can't see a solution...

[Jos]

It only uses 0-1% on my pc...

This version uses even less CPU:

#include <GUIConstants.au3>
#include <Date.au3>
Opt("GUIOnEventMode",1)
#region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 271, 143, 193, 125)
$Input1 = GUICtrlCreateInput("", 48, 40, 41, 21)
$Input2 = GUICtrlCreateInput("", 112, 40, 41, 21)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetState(@SW_SHOW)
#endregion ### START Koda GUI section ### Form=
While 1
    If String(_NowTime(5)) = GUICtrlRead($Input1) & ":" & GUICtrlRead($Input2) & ":00" Then
            MsgBox(0, "Reminder", "Some Text")
    EndIf
    Sleep(500)  
WEnd

Func SpecialEvents()
    Exit
EndFunc

[MrCreatoR]

Even on your script the CPU usage stays high

How high? i my machine it's 0%

If you don't want to check the inputs in the main loop, you will have to check the input changes (using GuiRefisterMsg with WM_COMMAND)...

Edited November 30, 2007 by MsCreatoR

[MrCreatoR]

Something like this:

expandcollapse popup

#include <GUIConstants.au3>

Global Const $WM_COMMAND = 0x0111
Global Const $EN_CHANGE = 0x300
Global $InputTime = ""

$Form1 = GUICreate("Form1", 271, 143, 193, 125)

$Input1 = GUICtrlCreateInput("", 48, 40, 41, 21)
$Input2 = GUICtrlCreateInput("", 112, 40, 41, 21)
GUISetState(@SW_SHOW)

GUISetState()
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If $InputTime <> "" And GetNowTime() = $InputTime Then
                MsgBox(0, "Reminder", "Some Text")
            EndIf
    EndSwitch
WEnd

Func GetNowTime()
    Return @HOUR & ":" & @MIN & ":" & @SEC
EndFunc

Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    
    Switch $nID
        Case $Input1, $Input2
            Switch $nNotifyCode
                Case $EN_CHANGE
                    $Input1Read = GUICtrlRead($Input1)
                    $Input2Read = GUICtrlRead($Input2)
                    If $Input1Read <> "" And $Input2Read <> "" Then
                        $InputTime = $Input1Read & ":" & $Input2Read & ":00"
                    Else
                        $InputTime = ""
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

But the solution by Jos is the best (using OnEvent mode)