Shell Properties

[Gif]

OK i want the properties of a folder/program. How do i do it quietly in AutoIt??

ShellExecute() with properties as a verb doesnt work for me. I ve also looked for shell.application object.. nothing there to.

Thanks in advance

[MrCreatoR]

Hi, i have asked for this too (here), i even posted a bug report, the answer i found much later then i ask ...

Here it is:

expandcollapse popup

HotKeySet("{Esc}", "OnExit")

$sFile = @ScriptName

_ShellExecuteEx($sFile, "", @ScriptDir, "properties")

$sWinText = StringTrimRight($sFile, 4)
WinWait("[CLASS:#32770]", $sWinText)
WinWaitClose("[CLASS:#32770]", $sWinText)

Func _ShellExecuteEx($sCmd, $Args = "", $sFolder = "", $Verb = "", $rState = @SW_SHOWNORMAL, $hWnd = 0)
    Local $struINFO = DllStructCreate("long;long;long;ptr;ptr;ptr;ptr;long;long;long;ptr;long;long;long;long")
    Local $struVerb = DllStructCreate("char[15];char")
    Local $struPath = DllStructCreate("char[255];char")
    Local $struArgs = DllStructCreate("char[255];char")
    Local $struWDir = DllStructCreate("char[255];char")
    
    DllStructSetData($struVerb, 1, $Verb)
    If StringRight($sCmd, 3) = "lnk" Then
        Local $aShortcutInfo = FileGetShortcut($sCmd)
        If IsArray($aShortcutInfo) Then
            DllStructSetData($struPath, 1, $aShortcutInfo[0])
            DllStructSetData($struWDir, 1, $aShortcutInfo[1])
            DllStructSetData($struArgs, 1, $aShortcutInfo[2])
            $rState = $aShortcutInfo[6]
        Else
            Return 0
        EndIf
    Else
        DllStructSetData($struPath, 1, $sCmd)
        DllStructSetData($struWDir, 1, $sFolder)
        DllStructSetData($struArgs, 1, $Args)
    EndIf

    DllStructSetData($struINFO, 1, DllStructGetSize($struINFO))
    DllStructSetData($struINFO, 2, BitOR(0xC, 0x40, 0x400))
    DllStructSetData($struINFO, 3, $hWnd)
    DllStructSetData($struINFO, 4, DllStructGetPtr($struVerb))
    DllStructSetData($struINFO, 5, DllStructGetPtr($struPath))
    DllStructSetData($struINFO, 6, DllStructGetPtr($struArgs))
    DllStructSetData($struINFO, 7, DllStructGetPtr($struWDir))
    DllStructSetData($struINFO, 8, $rState)

    Local $iRet = DllCall("shell32.dll", "int", "ShellExecuteEx", "ptr", DllStructGetPtr($struINFO))
    Return $iRet[0]
EndFunc   ;==>_ShellExecuteEx

Func OnExit()
    Exit
EndFunc   ;==>OnExit

Only problem that when autoit script exits, the Properties dialog disappear too

[Gif]

Thank you so much, just when i found this, but you've saved me a lot of time .

(To much work now..)

[NDog]

I have modified this script a little bit. All I need it for is to open up the properties window of the My Documents folder. To do this however, it needs to open the registry and find the path of the my documents folder. Unfortuanatley this wont work if the registry value for Personal is %USERPROFILE%\My Documents. It cant find the path of %USERPROFILE% when read from the registry.

expandcollapse popup

Func ChangeMyDocumentsPath()
    $sFile = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" , "Personal")

_ShellExecuteEx($sFile, "", @ScriptDir, "properties")

$sWinText = StringTrimRight($sFile, 4)
WinWait("[CLASS:#32770]", $sWinText)
WinWaitClose("[CLASS:#32770]", $sWinText)
EndFunc

Func _ShellExecuteEx($sCmd, $Args = "", $sFolder = "", $Verb = "", $rState = @SW_SHOWNORMAL, $hWnd = 0)
    Local $struINFO = DllStructCreate("long;long;long;ptr;ptr;ptr;ptr;long;long;long;ptr;long;long;long;long")
    Local $struVerb = DllStructCreate("char[15];char")
    Local $struPath = DllStructCreate("char[255];char")
    Local $struArgs = DllStructCreate("char[255];char")
    Local $struWDir = DllStructCreate("char[255];char")
   
    DllStructSetData($struVerb, 1, $Verb)
    If StringRight($sCmd, 3) = "lnk" Then
        Local $aShortcutInfo = FileGetShortcut($sCmd)
        If IsArray($aShortcutInfo) Then
            DllStructSetData($struPath, 1, $aShortcutInfo[0])
            DllStructSetData($struWDir, 1, $aShortcutInfo[1])
            DllStructSetData($struArgs, 1, $aShortcutInfo[2])
            $rState = $aShortcutInfo[6]
        Else
            Return 0
        EndIf
    Else
        DllStructSetData($struPath, 1, $sCmd)
        DllStructSetData($struWDir, 1, $sFolder)
        DllStructSetData($struArgs, 1, $Args)
    EndIf

    DllStructSetData($struINFO, 1, DllStructGetSize($struINFO))
    DllStructSetData($struINFO, 2, BitOR(0xC, 0x40, 0x400))
    DllStructSetData($struINFO, 3, $hWnd)
    DllStructSetData($struINFO, 4, DllStructGetPtr($struVerb))
    DllStructSetData($struINFO, 5, DllStructGetPtr($struPath))
    DllStructSetData($struINFO, 6, DllStructGetPtr($struArgs))
    DllStructSetData($struINFO, 7, DllStructGetPtr($struWDir))
    DllStructSetData($struINFO, 8, $rState)

    Local $iRet = DllCall("shell32.dll", "int", "ShellExecuteEx", "ptr", DllStructGetPtr($struINFO))
    Return $iRet[0]
EndFunc  ;==>_ShellExecuteEx

[FreeFry]

Yes, you sure can get the path from such a string as %userprofile%, all you need to do is use this:

Opt("ExpandEnvStrings", 1)

Otherwise, would not using the macro @MyDocumentsDir work? alternatively @DocumentsCommonDir ?