Changing the color of GUICtrlCreateProgress

[Emiel Wieldraaijer]

Hi All,

I want to change the color of GUICtrlCreateProgress

I've tried GUICtrlSetBkColor(-1, 0xff0000) and GUICtrlSetColor(-1, 0x00ff00)

but both appear to have no effect

Does anyone have a solution

i could also use DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0) but it will change the complete appearance of the GUI

Thnx

Emiel

[star2]

I don't wanna suppose that you did not refer to the right VAR?

$bar = GUICtrlCreateProgress (10,10,200,20)
GUICtrlSetColor($bar,32250)

[Siao]

i could also use DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0) but it will change the complete appearance of the GUI

Use SetWindowTheme to change theme of single control. Search forum for examples.

[Valuater]

This will do the trick!!!

expandcollapse popup

#include <GuiConstants.au3>
Global $XS_n

$Gui = GuiCreate("Test")
GUISetBkColor(0x0)

XPStyleToggle(1)
$RadioButton = GUICtrlCreateRadio("Text", 20, 40, 40)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$bar = GUICtrlCreateProgress (100,100,210,20)
GUICtrlSetColor($bar,32250)
XPStyleToggle(0)

GUISetState()

for $x = 1 to 100
    GUICtrlSetData($bar, $x)
    Sleep(100)
Next

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func XPStyleToggle($OnOff = 1)
    If Not StringInStr(@OSTYPE, "WIN32_NT") Then Return 0
    If $OnOff Then
        $XS_n = DllCall("uxtheme.dll", "int", "GetThemeAppProperties")
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
        Return 1
    ElseIf IsArray($XS_n) Then
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", $XS_n[0])
        $XS_n = ""
        Return 1
    EndIf
    Return 0
EndFunc

8)

[Emiel Wieldraaijer]

@Star2

-1 points to the $var used above it

@Siao

Thnx will take a look -> Thnx this will solve my problem

@Valuater

Thnx for the code explaination

Edited December 28, 2007 by Emiel Wieldraaijer

[Emiel Wieldraaijer]

@Valuater

and i see my problem and it's better explained with your example

when XPStyleToggle(1) i'm able to change the color of the progressbar and with XPStyleToggle(0) the color is changed back to it's defaults.. and i'm unable to change the color.. could it be a bug ???

Thnx

Emiel