LIVE sliders.

[Aceguy]

these sliders behave the exactly the way i want them to....

but is there a way to make them LIVE, Update while dragging.?

expandcollapse popup

#include <GUIConstants.au3>

$Form1 = GUICreate("Form1", 335, 105, 612, 524, -1, BitOR($WS_EX_TOOLWINDOW,$WS_EX_WINDOWEDGE))
$Progress1 = GUICtrlCreateProgress(184, 8, 137, 17, BitOR($PBS_SMOOTH,$WS_BORDER))
$Slider1 = GUICtrlCreateSlider(176, 32, 153, 17,$TBS_NOTICKS)
GUICtrlSetData(-1,85)
$Slider2 = GUICtrlCreateSlider(176, 56, 153, 17,$TBS_NOTICKS)
GUICtrlSetData(-1,60)
$Slider3 = GUICtrlCreateSlider(176, 80, 153, 17,$TBS_NOTICKS)
GUICtrlSetData(-1,25)
GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg =$GUI_EVENT_CLOSE
            Exit

        case $msg = $Slider1
            if guictrlread($Slider2) > guictrlread($slider1)-10 Then
                GUICtrlSetData($Slider2,guictrlread($slider1)-10)
            EndIf
            if guictrlread($slider2) < guictrlread($slider3)+10 Then
                guictrlsetdata($slider3,GUICtrlRead($slider2)-10)
            EndIf
        
    case $msg = $slider2
    if guictrlread($slider2) > guictrlread($slider1)-10 Then
        guictrlsetdata($slider2,guictrlread($slider1)-10)
    elseif guictrlread($slider2) < guictrlread($slider3) Then
        guictrlsetdata($slider3, guictrlread($slider2)-10)
        EndIf
case $msg = $Slider3
    if guictrlread($slider3) > guictrlread($slider2)-10 Then
        GUICtrlSetData($slider3,guictrlread($slider2)-10)
        EndIf
    EndSelect
WEnd

[MrCreatoR]

Hi, here is working example:

#include <GuiConstants.au3>

;Global Const $WM_HSCROLL = 0x0114
;Global Const $WM_VSCROLL = 0x0115

$Gui = GuiCreate("Slider Update Demo", 250, 200)

GUIRegisterMsg($WM_HSCROLL, "WM_HVSCROLL")
GUIRegisterMsg($WM_VSCROLL, "WM_HVSCROLL")

$Vertical_Label = GUICtrlCreateLabel("Vertical Slider Read: 0", 20, 20, 200)
$Horizontal_Label = GUICtrlCreateLabel("Horizontal Slider Read: 0", 80, 120, 200)

$Vertical_Slider = GUICtrlCreateSlider(20, 50, 30, 120, BitOr($GUI_SS_DEFAULT_SLIDER, $TBS_VERT))
$Horizontal_Slider = GUICtrlCreateSlider(60, 150, 160, 30)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func WM_HVSCROLL($hWndGUI, $MsgID, $WParam, $LParam)
    Switch $LParam
        Case GUICtrlGetHandle($Vertical_Slider)
            GUICtrlSetData($Vertical_Label, "Vertical Slider Read: " & GUICtrlRead($Vertical_Slider))
        Case GUICtrlGetHandle($Horizontal_Slider)
            GUICtrlSetData($Horizontal_Label, "Horizontal Slider Read: " & GUICtrlRead($Horizontal_Slider))
    EndSwitch
EndFunc

[Aceguy]

WOW, SPOT ON, thanks MsCreatoR.

And a HAPPY NEW YEAR

Edited December 29, 2007 by Aceguy

[MrCreatoR]

WOW, SPOT ON, thanks MsCreatoR.

And a HAPPY NEW YEAR

Your wellcome

and Happy New Year to you to!