A strange "Subscript used with non-array variable" error

[duncanchaos]

I have written a script to control my Flexwriter DVD/CD copy/print station. The script runs fine when I run it from SciTE4 and gets no errors when it is compiled, but when I run the exe it immediately errors out with an Autoit error window:

The windows title is AutoIt Error

Line -1:

Error: Subscript used with non-array Variable.

I cannot figure out what is happening here, especially when the script runs fine from within the editor. I have copied my code into the post. There are 2 variables that capture array data. Any help would be appreciated.

CODE

#include <GUIConstants.au3>

#include <commMG.au3>

;create GUI

GUICreate("Flexwriter DVD Transfer",400,160)

;create target path button

$Button1 = GUICtrlCreateButton("Destination Path",10,70)

$lbltarget = GUICtrlCreateInput("",110,70,280)

;create source optical drive list

$drvlist = DriveGetDrive( "CDROM" )

$CmboSrcDrv = GUICtrlCreateCombo("",10,40,85)

For $pl = 1 To $drvlist[0]

GUICtrlSetData($CmboSrcDrv, $drvlist[$pl])

Next

GUICtrlSetData($CmboSrcDrv, $drvlist[1]);show the first DVD drive found

$CDDrive = GUICtrlRead(5);set variable

$lblSrcDrv = GUICtrlCreateLabel("Choose the DVD Source Drive", 110, 40)

;create COM port list

$portlist = _CommListPorts(0)

$CmboPortsAvailable = GUICtrlCreateCombo("", 10,10,85)

For $pl = 1 To $portlist[0]

GUICtrlSetData($CmboPortsAvailable, $portlist[$pl]);_CommListPorts())

Next

GUICtrlSetData($CmboPortsAvailable, $portlist[1]);show the first port found

$iPort = StringTrimLeft(GUICtrlRead(7),3);trim the COM from the String and set variable

$lblportlist = GUICtrlCreateLabel("Choose the Flexwriter COM port connection", 110, 10)

;create OK button

$ButtonOK = GUICtrlCreateButton("OK",10,120,190)

;create quit button

$ButtonQuit = GUICtrlCreateButton("Quit",200,120,190)

GUISetState()

Do

$Answr = GUIGetMsg()

Select

Case $Answr = $button1

Do

$target = FileSelectFolder("Select Image Folder", "", 1)

If @error Then

MsgBox(4096,"Warning 1","No Folder selected")

ExitLoop

Else

$YesNo = MsgBox(4132, "Confirm", $target & @CRLF & @CRLF & "Is this the correct folder?")

If $YesNo = 6 Then

$YesNo = "X"

GUICtrlSetData(4, $target)

EndIf

EndIf

Until $YesNo = "X"

Case $Answr = $CmboPortsAvailable

$iPort = StringTrimLeft(GUICtrlRead(7),3)

Case $Answr = $CmboSrcDrv

$CDDrive = GUICtrlRead(5)

Case $Answr = $ButtonQuit

Exit

Case $Answr = $ButtonOK

If $target = "" Then

MsgBox(0,"ERROR","No Target Folder selected")

Else

ExitLoop

EndIf

EndSelect

Until $Answr = $gui_event_close

;MsgBox(0,"Program Settings","Port is COM" & $iPort & @crlf & "DVD Drive is " & $CDDrive & @CRLF & "Target Folder is " & $target)

;open COM Port to connect to the Flexwriter

$sErr=0;set error variable

$msg =_CommSetPort($iPort,$sErr,9600,8,0,1,2)

if $msg=0 Then

msgbox(0,"COM Port Error",$sErr & @CRLF & "Please check selected COM port")

Exit

EndIf

;send activation string to flexwriter

$iWaitComplete=1

$msg = _CommSendString("v",$iWaitComplete)

Sleep(2000) ; 2seconds

$return = _Commgetstring()

GUISetState(@SW_HIDE)

GUICreate("DVD Transfer Status",400,160)

GUISetState()

$font="Arial Bold"

$lbl1 = GUICtrlCreateLabel("Please Wait" & @CRLF & "Currently copying the following DVD:",20,20,360,60,$SS_CENTER)

GUICtrlSetFont (-1,14,400,1, $font)

$lbl2 = GUICtrlCreateLabel("",20,100,360,60,$SS_CENTER)

GUICtrlSetFont (-1,14,400,1, $font)

GUISetState()

;Setup loop for disks

While 1

;send get disk and insert command

CDTray($CDDrive, "open")

$msg = _CommSendString("i",$iWaitComplete)

Do

$return = _Commgetstring()

Until $return <> ""

if $return = "E" Then

ExitLoop

EndIf

CDTray($CDDrive, "close")

Sleep(20000)

$drvstat = DriveStatus($CDDrive)

if $drvstat = "READY" Then

;check volume label. If label is empty then populate variable

$vollbl = DriveGetLabel($CDDrive)

If $vollbl = "" Then

$vollbl = "DVDMovie"

EndIf

;check to see if directory that matches vl exists and if so add count to vl

$lblcount=""

Do

$fileexist = FileExists($target & "\" & $vollbl & $lblcount)

if $fileexist=1 Then

$lblcount=$lblcount + 1

EndIf

Until $fileexist = 0

;copy the data to the target drive

GUICtrlSetData($lbl2,$vollbl & $lblcount)

DirCopy($CDDrive, $target & "\" & $vollbl & $lblcount, 1)

;send retrieve disk command

CDTray($CDDrive, "open")

$msg = _CommSendString("a",$iWaitComplete)

Do

$return = _Commgetstring()

Until $return <> ""

Else

; if the drive cannot read the disk correctly, remove and reject disk

CDTray($CDDrive, "open")

$msg = _CommSendString("p",$iWaitComplete)

Do

$return = _Commgetstring()

Until $return <> ""

if $return = "E" Then

ExitLoop

EndIf

CDTray($CDDrive, "close")

$msg = _CommSendString("h",$iWaitComplete)

Do

$return = _Commgetstring()

Until $return <> ""

if $return = "E" Then

ExitLoop

EndIf

EndIf

WEnd

CDTray($CDDrive, "close")

$msg = _CommClosePort()

[MrCreatoR]

Ho, wellcome to the forums!

It's a little dificult to debug, because you have not provided the include file <commMG.au3>...

But here is a little fixed version, where i checked the array with Ubound:

expandcollapse popup

#include <GUIConstants.au3>
#include <commMG.au3>

;create GUI
GUICreate("Flexwriter DVD Transfer", 400, 160)

;create target path button
$Button1 = GUICtrlCreateButton("Destination Path", 10, 70)
$lbltarget = GUICtrlCreateInput("", 110, 70, 280)

;create source optical drive list
$drvlist = DriveGetDrive("CDROM")
$CmboSrcDrv = GUICtrlCreateCombo("", 10, 40, 85)
For $pl = 1 To UBound($drvlist) - 1
    GUICtrlSetData($CmboSrcDrv, $drvlist[$pl])
Next
If UBound($drvlist) > 1 Then GUICtrlSetData($CmboSrcDrv, $drvlist[1]);show the first DVD drive found
$CDDrive = GUICtrlRead(5);set variable
$lblSrcDrv = GUICtrlCreateLabel("Choose the DVD Source Drive", 110, 40)


;create COM port list
$portlist = _CommListPorts (0)
$CmboPortsAvailable = GUICtrlCreateCombo("", 10, 10, 85)
For $pl = 1 To UBound($portlist) - 1
    GUICtrlSetData($CmboPortsAvailable, $portlist[$pl]);_CommListPorts())
Next
If UBound($portlist) > 1 Then GUICtrlSetData($CmboPortsAvailable, $portlist[1]);show the first port found
$iPort = StringTrimLeft(GUICtrlRead(7), 3);trim the COM from the String and set variable
$lblportlist = GUICtrlCreateLabel("Choose the Flexwriter COM port connection", 110, 10)

;create OK button
$ButtonOK = GUICtrlCreateButton("OK", 10, 120, 190)

;create quit button
$ButtonQuit = GUICtrlCreateButton("Quit", 200, 120, 190)

GUISetState()

Do
    $Answr = GUIGetMsg()

    Select

        Case $Answr = $Button1
            Do
                $target = FileSelectFolder("Select Image Folder", "", 1)
                If @error Then
                    MsgBox(4096, "Warning 1", "No Folder selected")
                    ExitLoop
                Else
                    $YesNo = MsgBox(4132, "Confirm", $target & @CRLF & @CRLF & "Is this the correct folder?")
                    If $YesNo = 6 Then
                        $YesNo = "X"
                        GUICtrlSetData(4, $target)
                    EndIf
                EndIf
            Until $YesNo = "X"

        Case $Answr = $CmboPortsAvailable
            $iPort = StringTrimLeft(GUICtrlRead(7), 3)

        Case $Answr = $CmboSrcDrv
            $CDDrive = GUICtrlRead(5)

        Case $Answr = $ButtonQuit
            Exit

        Case $Answr = $ButtonOK

            If $target = "" Then
                MsgBox(0, "ERROR", "No Target Folder selected")

            Else
                ExitLoop
            EndIf

    EndSelect


Until $Answr = $gui_event_close

;MsgBox(0,"Program Settings","Port is COM" & $iPort & @crlf & "DVD Drive is " & $CDDrive & @CRLF & "Target Folder is " & $target)

;open COM Port to connect to the Flexwriter
$sErr = 0;set error variable
$msg = _CommSetPort ($iPort, $sErr, 9600, 8, 0, 1, 2)

If $msg = 0 Then
    MsgBox(0, "COM Port Error", $sErr & @CRLF & "Please check selected COM port")
    Exit
EndIf

;send activation string to flexwriter
$iWaitComplete = 1
$msg = _CommSendString ("v", $iWaitComplete)
Sleep(2000) ; 2seconds
$return = _Commgetstring ()

GUISetState(@SW_HIDE)

GUICreate("DVD Transfer Status", 400, 160)
GUISetState()

$font = "Arial Bold"
$lbl1 = GUICtrlCreateLabel("Please Wait" & @CRLF & "Currently copying the following DVD:", 20, 20, 360, 60, $SS_CENTER)
GUICtrlSetFont(-1, 14, 400, 1, $font)
$lbl2 = GUICtrlCreateLabel("", 20, 100, 360, 60, $SS_CENTER)
GUICtrlSetFont(-1, 14, 400, 1, $font)

GUISetState()



;Setup loop for disks
While 1
    ;send get disk and insert command
    CDTray($CDDrive, "open")
    $msg = _CommSendString ("i", $iWaitComplete)

    Do
        $return = _Commgetstring ()
    Until $return <> ""
    If $return = "E" Then
        ExitLoop
    EndIf

    CDTray($CDDrive, "close")
    Sleep(20000)
    $drvstat = DriveStatus($CDDrive)
    If $drvstat = "READY" Then

        ;check volume label. If label is empty then populate variable
        $vollbl = DriveGetLabel($CDDrive)
        If $vollbl = "" Then
            $vollbl = "DVDMovie"
        EndIf

        ;check to see if directory that matches vl exists and if so add count to vl
        $lblcount = ""
        Do
            $fileexist = FileExists($target & "\" & $vollbl & $lblcount)
            If $fileexist = 1 Then
                $lblcount = $lblcount + 1
            EndIf
        Until $fileexist = 0

        ;copy the data to the target drive
        GUICtrlSetData($lbl2, $vollbl & $lblcount)
        DirCopy($CDDrive, $target & "\" & $vollbl & $lblcount, 1)

        ;send retrieve disk command
        CDTray($CDDrive, "open")
        $msg = _CommSendString ("a", $iWaitComplete)

        Do
            $return = _Commgetstring ()
        Until $return <> ""

    Else
        ; if the drive cannot read the disk correctly, remove and reject disk
        CDTray($CDDrive, "open")
        $msg = _CommSendString ("p", $iWaitComplete)
        Do
            $return = _Commgetstring ()
        Until $return <> ""
        If $return = "E" Then
            ExitLoop
        EndIf
        CDTray($CDDrive, "close")
        $msg = _CommSendString ("h", $iWaitComplete)
        Do
            $return = _Commgetstring ()
        Until $return <> ""
        If $return = "E" Then
            ExitLoop
        EndIf


    EndIf

WEnd

CDTray($CDDrive, "close")

$msg = _CommClosePort ()

[duncanchaos]

Thanks for the welcome and the help MsCreatoR! I have been using AutoIt for a couple of years now, but this is the first major stumbling block that I have had.

I appreciate the code updates. I have not had to use arrays much. I tend to use AutoIt as a deployment tool as I am a Systems Engineer with Toshiba in the Computer Systems Division.

I tried the updated code and it will run after compiled but the COM port combo box is not filled. When the script is run from the editor it works fine. This must have something to do with the "commMG.au3" UDF. I found it in the AutoIt forums. It along with it's supplied dll give me the COM port controls. I will see what I can find from the author of it.

Thanks again!

[duncanchaos]

I just commented out the _CommListPorts section and added the items to the combo box during the create. The compiled exe works great. The issue is definitely with the _CommListPorts array.

Thanks

[duncanchaos]

The issue turned out to be the dll file for the "commMG.au3" UDF. I had the dll in the AutoIt3 directory but not in c:\windows\system32, so running from the editor worked but the compiled exe could not find the dll.

Case closed.

[martin]

The issue turned out to be the dll file for the "commMG.au3" UDF. I had the dll in the AutoIt3 directory but not in c:\windows\system32, so running from the editor worked but the compiled exe could not find the dll.

Case closed.

You should be able to run it if the dll is in the same folder as the exe. I have never put the dll in system32, though if that works - well, fine.

[duncanchaos]

Hey martin!

Thanks for the "commMG.au3" UDF. It works great! I have already written a couple of utilities for my Flexwriter using it.

As for the dll location, this is fully my fault. I was saving my compiled exe file to my desktop and running it from there but I had put your dll in the AutoIT program directory so it was not finding it.

Have a great New Year!

You should be able to run it if the dll is in the same folder as the exe. I have never put the dll in system32, though if that works - well, fine.