checking software version

[gettyhd]

anyone know what the script is to check for a software version before it executes. I'm trying to include a "if" statement, "if you will" to check the software version. if the version exist.....I want autoit to exit, but if it doesn't continue with installation. Help!

[SpookMeister]

You could look at the file date for the program executable... or whatever applicable file would be appropriate.

Edited January 9, 2008 by SpookMeister

[big_daddy]

You can also check the registry for a version key.

[Kerros]

FileGetVersion ( "filename" [,"stringname"] )

[Danny35d]

gettyhd welcome to autoit

UDF _SoftwareList() give you a 2 dimensional array with the software name and version.

Array[n][0] = Software Name

Array[n][1] = Software Version

#include <Array.au3>

$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

$List = _SoftwareList()
_ArrayDisplay($List)

$List = _SoftwareList('microsoft .net framework 1.1')
_ArrayDisplay($List)

Func _SoftwareList($sSoftwareName = '')
    Dim $aSoftwareList[1][2]
    $objInstaller = ObjCreate('WindowsInstaller.Installer')

    $Products = $objInstaller.Products
    For $Product In $Products
        If $sSoftwareName <> '' And $sSoftwareName <> $objInstaller.ProductInfo($Product, 'ProductName') Then ContinueLoop
        ReDim $aSoftwareList[UBound($aSoftwareList) + 1][2]
        $aSoftwareList[UBound($aSoftwareList) - 1][0] = $objInstaller.ProductInfo($Product, 'ProductName')
        $aSoftwareList[UBound($aSoftwareList) - 1][1] = $objInstaller.ProductInfo($Product, 'VersionString')
    Next
    $aSoftwareList[0][0] = UBound($aSoftwareList) - 1
    Return ($aSoftwareList)
EndFunc   ;==>_SoftwareList

Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite("We intercepted a COM Error !" & @CRLF & _
            "Number is: " & $HexNumber & @CRLF & _
            "Windescription is: " & $oMyError.windescription)

    SetError(1) ; something to check for when this function returns
EndFunc   ;==>MyErrFunc

Edit: Forgot to add MyErrFunc() UDF

Edited January 10, 2008 by Danny35d