FileSelectDrive and DirCopy

[Mast3rpyr0]

Its me, back from the dead.

Any such function or maybe a macro you can use in FileSelectFolder to select just a drive?

Edited January 10, 2008 by Mast3rpyr0

[Xenobiologist]

HI,

you can StringLeft the folder choice.

So long,

Mega

[Mast3rpyr0]

is that the only way? if so id rather just have someone type the drive letter

[MrCreatoR]

Hi,

You can use a root directory:

FileSelectFolder("Choose a folder.", "c:\")

Or what do you mean by «select just a drive»?

[MrCreatoR]

I think i understand what you need...

You probably will have to build your own Gui with File Select folder.. you just use DriveGetDrive, and make an TreeView elements.

[GaryFrost]

expandcollapse popup

#include <GUIListBox.au3>

Opt('MustDeclareVars', 1)

Global $hListBox

Example_Internal()

Func Example_Internal()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("(Internal) List Box Dir", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Add files
    _GUICtrlListBox_BeginUpdate ($hListBox)
;~  _GUICtrlListBox_Dir ($hListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir ($hListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate ($hListBox)

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_Internal

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $hWndListBox
    If Not IsHWnd($hListBox) Then $hWndListBox = GUICtrlGetHandle($hListBox)
    $hWndFrom = $ilParam
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
    $iCode = BitShift($iwParam, 16) ; Hi Word

    Switch $hWndFrom
        Case $hListBox, $hWndListBox
            Switch $iCode
                Case $LBN_SELCHANGE ; Sent when the selection in a list box has changed
                    _DebugPrint("$LBN_SELCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Value:" & @TAB & GUICtrlRead($hListBox))
                    ; no return value
            EndSwitch
    EndSwitch
    ; Proceed the default Autoit3 internal message commands.
    ; You also can complete let the line out.
    ; !!! But only 'Return' (without any value) will not proceed
    ; the default Autoit3-message in the future !!!
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_text)
    $s_text = StringReplace($s_text, @LF, @LF & "-->")
    ConsoleWrite("!===========================================================" & @LF & _
            "+===========================================================" & @LF & _
            "-->" & $s_text & @LF & _
            "+===========================================================" & @LF)
EndFunc   ;==>_DebugPrint

[Mast3rpyr0]

does it need to be that complicated? i think i got it with drivegetdrive

[Mast3rpyr0]

ok i got this

#include <GUIConstants.au3>
#include <Constants.au3>

$mainWindow = GUICreate("Select Drive", 200, 100)
$drives = DriveGetDrive("ALL")

If NOT @error Then
    $ctrl = GUICtrlCreateTreeView(3, 3, 194, 94)
    For $i = 1 to $drives[0]
        $treeItems = GUICtrlCreateTreeViewItem($drives[$i], $ctrl)
    Next
EndIf

GUISetState(@SW_SHOW, $mainWindow)

While 1
    $gMsg = GUIGetMsg()
    Switch $gMsg
    Case $GUI_EVENT_CLOSE
        Exit
    EndSwitch
WEnd

Now how do i get which is selected. i cant exactly change the variable each TreeviewItem uses can i? an array didnt work.

[smashly]

Hi, On Event mode maybe?

expandcollapse popup

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

$Gui = GUICreate("", 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "Event")
$TreeViev = GUICtrlCreateTreeView(3, 3, 94, 94)
_GetDrives()
GUISetState(@SW_SHOW, $Gui)

While 1
    Sleep(100)
Wend

Func Event()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If GUICtrlRead(@GUI_CtrlId, 1) <> "No Drives Available" Then
                MsgBox(64,'Drive Selected.', "You've Selected Drive: " & GUICtrlRead(@GUI_CtrlId, 1))
            Else
                MsgBox(64,'No Drives Available.', "No Drives Available To Select.")
            EndIf
    EndSwitch
EndFunc

Func _GetDrives()
    Local $DGD = DriveGetDrive("ALL")
    If @error Then
        GUICtrlCreateTreeViewItem("No Drives Available", $TreeViev)
        GUICtrlSetOnEvent(-1, "Event")
        GUICtrlSetImage($TreeViev, "shell32.dll", -54, 2)
        GUICtrlSetImage($TreeViev, "shell32.dll", -54, 4)
    Else
        For $d = 1 To $DGD[0]
            GUICtrlCreateTreeViewItem("(" & StringUpper($DGD[$d]) & ")", $TreeViev)
            GUICtrlSetOnEvent(-1, "Event")
            GUICtrlSetImage($TreeViev, "shell32.dll", -9, 2)
            GUICtrlSetImage($TreeViev, "shell32.dll", -9, 4)
        Next
    EndIf
EndFunc

Other ways would be using GUIRegisterMsg()

Cheers

[Mast3rpyr0]

thanks smashly works like a charm

[rasim]

Or:

#include <GUIConstants.au3>

Dim $data

$mainWindow = GUICreate("Select Drive", 200, 100)
$drives = DriveGetDrive("ALL")

If NOT @error Then
    $SelectDrive = GUICtrlCreateCombo("", 50, 30, 100, 17, $CBS_DROPDOWNLIST)
    For $i = 1 to $drives[0]
        $data &= DriveGetType($drives[$i]) &" "& StringUpper($drives[$i]) & "|"
    Next
    ConsoleWrite($data)
    GUICtrlSetData(-1, StringTrimRight($data, 1), StringRegExpReplace($data, "\|.*", ""))
EndIf

GUISetState(@SW_SHOW, $mainWindow)

While 1
    $gMsg = GUIGetMsg()
    Switch $gMsg
    Case $GUI_EVENT_CLOSE
        Exit
    EndSwitch
WEnd

[smashly]

Your welcome

If you want the drive icons to suit the drives (in xp that is) try this mild addition

expandcollapse popup

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

$Gui = GUICreate("", 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "Event")
$TreeViev = GUICtrlCreateTreeView(3, 3, 94, 94)
_GetDrives()
GUISetState(@SW_SHOW, $Gui)

While 1
    Sleep(100)
Wend

Func Event()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If GUICtrlRead(@GUI_CtrlId, 1) <> "No Drives Available" Then
                MsgBox(64,'Drive Selected.', "You've Selected Drive: " & GUICtrlRead(@GUI_CtrlId, 1))
            Else
                MsgBox(64,'No Drives Available.', "No Drives Available To Select.")
            EndIf
    EndSwitch
EndFunc

Func _GetDrives()
    Local $DGD = DriveGetDrive("ALL")
    If @error Then
        GUICtrlCreateTreeViewItem("No Drives Available", $TreeViev)
        GUICtrlSetOnEvent(-1, "Event")
        GUICtrlSetImage($TreeViev, "shell32.dll", _GetIco(-1), 2)
        GUICtrlSetImage($TreeViev, "shell32.dll", _GetIco(-1), 4)
    Else
        For $d = 1 To $DGD[0]
            GUICtrlCreateTreeViewItem("(" & StringUpper($DGD[$d]) & ")", $TreeViev)
            GUICtrlSetOnEvent(-1, "Event")
            GUICtrlSetImage(-1, "shell32.dll", _GetIco($DGD[$d]), 2)
            GUICtrlSetImage(-1, "shell32.dll", _GetIco($DGD[$d]), 4)
        Next
    EndIf
EndFunc

Func _GetIco($Drv = -1)
    If $Drv = -1 Then Return -54
    $DR = StringRegExpReplace($Drv, "[()]", "",2)
    Local $DGT = DriveGetType($DR)
    If @error Or $DGT = "" Then Return -54
    Switch $DGT
        Case "Removable"
            If $DR = "A:" Or $DR = "B:" Then Return -7
            Return -8
        Case "Fixed"
            Return -9
        Case "Network"
            If DriveStatus($DR) = "INVALID" Then Return -11
            Return -10
        Case "CDROM"
            Return -12
        Case "RAMDisk"
            Return -13
        Case "Unknown"
            Return -54
    EndSwitch
EndFunc

Cheers

[Mast3rpyr0]

cool thanks.

gah i hate forgetting things, stupid AP computer science people teaching java....

is there anyway to track the status of a dir copy?

[smashly]

If your using Autoit to do the directory copy then you could do a _FileListToArray() then step through the array , this way you can track it as the files are copying , other then that you could probably use the win api functions in some way to monitor the process, but I don't have an example of doing it via api.

Cheers

[Mast3rpyr0]

i could get all the files but how could i track it. and it also seems i cant do anything else until the copy is done

[smashly]

If your just after a file copy dialog then you could maybe have a look at Windows - copy with progress function by JdeB.

It's short, sweet and easy to use..

Cheers

[GEOSoft]

i could get all the files but how could i track it. and it also seems i cant do anything else until the copy is done

Look back to somewhere around August or September and I think I posted some file/folder functions that use the Windows progress indicator.