$CBN_EDITUPDATE sent before text updated in Combo box?

[MrCreatoR]

Hi all,

I am trying to understand one simple(?) thing:

#include <GuiComboBox.au3>

$Changed = False

$hGUI = GUICreate("ComboBox", 400, 296)
$hCombo = GUICtrlCreateCombo("test", 2, 2, 396, 296) ;erase the "text" and data will updated correctly

GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

Do
    If $Changed Then
        ConsoleWrite(GUICtrlRead($hCombo, 1) & @LF)
        $Changed = False
    EndIf
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode
    
    $hWndFrom = $ilParam
    $iIDFrom = BitAND($iwParam, 0xFFFF)
    $iCode = BitShift($iwParam, 16)
    
    Switch $hWndFrom
        Case GUICtrlGetHandle($hCombo)
            Switch $iCode
                Case $CBN_EDITUPDATE
                    ;$Changed = True
                    ConsoleWrite(GUICtrlRead($hCombo, 1) & @LF) ;comment this and uncommend the line with $Changed
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

Here i expecting that when i type/delete text in the combo box control, it will updated respectively in the console, but the text updated only on second attempt - if the initial combo control have no data ("") the data updated correctly, and also if we use main loop to handle the update checking process, all data updated correctly (follow the comments).

I am just curious, why it wont return current data (using GuiCtrlRead()) on the first attempt?

Using _GUICtrlComboBox_Create... funcs also responding correctly, but i am intresting in the «classic method»

Edited January 18, 2008 by MsCreatoR

[Siao]

It may have something to do with how GuiCtrlRead gets the data. And probably has to do with the fact that combo box is one of those complex controls which have multiple controls rolled into one. I'm not sure how things work internally, so I'll just stop here.

But you can get the correct text during CBN_EDITUPDATE with a _GUICtrlComboBox_GetEditText() on first try.

Edited January 18, 2008 by Siao

[ValeryVal]

But you can get the correct text during CBN_EDITUPDATE with a _GUICtrlComboBox_GetEditText() on first try

Or just replace

ConsoleWrite(GUICtrlRead($hCombo) & @LF)

to

ConsoleWrite(ControlGetText ( "ComboBox", "", 'Edit1') & @LF)

[MrCreatoR]

Yes, ControlGetText handle with it very well too, it seems that this is a limit/bug of GUICtrlRead()...

[GaryFrost]

Yes, ControlGetText handle with it very well too, it seems that this is a limit/bug of GUICtrlRead()...

A limit not a bug, until there is a return from the event the internal reads can't read the data.

I remember a long time ago trying to figure that one out and Holger pointed it out to me.

[MrCreatoR]

A limit not a bug, until there is a return from the event the internal reads can't read the data.

Perhaps this limit should be mentioned in the help file (under GUICtrlRead())?