Edit ListView Item with standard GUICtrlListViewCrteate?

[MrCreatoR]

Hi there,

Again my question related to ListView ...

I trying to make editable list view items using built-in GUICtrlCreateListView(), but it seems that $LVN_BEGINLABELEDIT notification not responding correctly:

expandcollapse popup

#include <GuiListView.au3>

$Gui = GUICreate("Test", 400, 250)

$hListView = GUICtrlCreateListView("Items", 2, 2, 220, 196, BitOR($LVS_EDITLABELS, $LVS_REPORT))
;$hListView = _GUICtrlListView_Create($Gui, "Items", 2, 2, 220, 196, BitOR($LVS_EDITLABELS, $LVS_REPORT))

If Not IsHWnd($hListView) Then $hListView = GUICtrlGetHandle($hListView)

$ListItem1 = _GUICtrlListView_AddItem($hListView, "Item 1",0)
$ListItem2 = _GUICtrlListView_AddItem($hListView, "Item 2",2)
$ListItem3 = _GUICtrlListView_AddItem($hListView, "Item 3",1)
$ListItem4 = _GUICtrlListView_AddItem($hListView, "Item 4",3)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

$Edit_Button = GUICtrlCreateButton("Edit Item", 10, 200)

GUISetState()


While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Edit_Button
            $iSelected = _GUICtrlListView_GetSelectedIndices($hListView)
            If $iSelected <> "" Then _GUICtrlListView_EditLabel($hListView, $iSelected)
    EndSwitch
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)
    
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_BEGINLABELEDIT
                    Local $tInfo = DllStructCreate($tagNMLVDISPINFO, $ilParam)
                    Return False
                Case $LVN_ENDLABELEDIT
                    Local $tInfo = DllStructCreate($tagNMLVDISPINFO, $ilParam)
                    Local $tBuffer = DllStructCreate("char Text[" & DllStructGetData($tInfo, "TextMax") & "]", _
                        DllStructGetData($tInfo, "Text"))
                    Local $sNewText = DllStructGetData($tBuffer, "Text")
                    If StringLen($sNewText) Then Return True
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

If you comment the line with GUICtrlListViewCrteate(...), and uncomment the line with _GUICtrlListView_Create(...), the edit process work ok.

Is there a way to make it work with GUICtrlListViewCrteate()?

P.S

I know about the Edit In Place Listview by eltorro, but i need something simple as in the example above.

[Siao]

If you're running unicode version of AutoIt, the notifications are unicode too (although some notifications do not have separate codes for ansi/unicode). Use:

Switch $iCode
                Case $LVN_BEGINLABELEDIT, $LVN_BEGINLABELEDITW
            ;
                Case $LVN_ENDLABELEDIT, $LVN_ENDLABELEDITW
            ;

Edited January 23, 2008 by Siao

[MrCreatoR]

@Siao, did i ever said that you are the best? Thanks!

[MrCreatoR]

The text on $LVN_ENDLABELEDITW is cuted to one character if i use GUICtrlListViewCrteateItem(...), therefore we need to use wchar instead of char, right?

Local $sBuffer = "char Text[" & $iTextMax & "]"
                    If $iCode = $LVN_ENDLABELEDITW Then $sBuffer = "wchar Text[" & $iTextMax & "]"
                    Local $tBuffer = DllStructCreate($sBuffer, $iText)

[Siao]

Is this correct way?

Yes.

As for the error/crash during LVN_BEGINLABELEDIT, if you check the TextMax and pText values you get from the struct, they aren't valid. Just some trash int, which in case of TextMax happens to be very big, and your DllStructCreate tries to alloc ~2gigs (make that 4gigs in wchar case)...

Why they aren't valid, not sure, but probably they're just not intended to be valid at that point.

If you want text though, you can get it with

_GUICtrlListView_GetItemText($hWndFrom, DllStructGetData($tInfo, "Item"))

, as "Item" member is guaranteed to be valid, as per MSDN: "Pointer to an NMLVDISPINFO structure. The item member of this structure is an LVITEM structure whose iItem member identifies the item being edited."

Edited January 23, 2008 by Siao

[MrCreatoR]

As for the error/crash during LVN_BEGINLABELEDIT, if you check the TextMax and pText values you get from the struct, they aren't valid. Just some trash int, which in case of TextMax happens to be very big, and your DllStructCreate tries to alloc ~2gigs (make that 4gigs in wchar case)...

Ok, now i see what was causing the error/crash, thanks for the details, i starting to learn something about Dll... related functions .

If you want text though, you can get it with

_GUICtrlListView_GetItemText($hWndFrom, DllStructGetData($tInfo, "Item"))

, as "Item" member is guaranteed to be valid

Thanks, that will do what i need.