Folder search and delete

[ttoscan]

I am trying to uninstall an application, then install a newer version of it. When I uninstall it using my autoit script, it uninstalls fine, but leaves a folder for the application in each user's profile\application data folder under documents and settings. This will prevent the newer version from installing correctly.

I am trying to add to my script to search for the folder, then delete it, but not knowing each user's profile name.

Can anybody give me any ideas. I first tried to use comspec, but cannot get it to delete a folder. It works great for searching for a specific file and deleteing it.

Thanks.

Tom T.

[Zedna]

Use Run() with these Windows commandline commands:

DEL - for recursive deleting all files in your folder

RD - (Remove Dirrectory) for deleting your empty folder

[GEOSoft]

If you only need it for the current user then use the @AppDataDir macro to get the Current users Application Data folder. If you need it for the All Users Application Data folder then @AppDataCommonDir.

For locating the Application Data folder for several users you would start by locating the Documents and settings folder

$ds_Fldr = @HomeDrive & "\Documents and Settings\" and then work it out from there.

[MHz]

Can anybody give me any ideas.

Perhaps this code example may help you

; Target folder to remove
Const $FOLDERNAME = 'Microsoft'

; Change current directory
If FileChangeDir(@UserProfileDir & '\..') Then
    ConsoleWrite('WorkingDir = ' & @WorkingDir & @CRLF); Test purpose only
    ; Create a search handle
    $handle_search = FileFindFirstFile("*")
    If $handle_search <> -1 Then
        While 1
            ; Get the next file/folder
            $folder_profile = FileFindNextFile($handle_search)
            If @error Then ExitLoop
            ; Check that it is a folder
            if StringInStr(FileGetAttrib($folder_profile), 'D') Then
                ; Skip these profiles
                Switch $folder_profile
                    Case 'All Users', 'Default User', 'LocalService', 'NetworkService'
                        ContinueLoop
                EndSwitch
                ; Build a relative path to the target folder
                $folder_target = $folder_profile & '\Application Data\' & $FOLDERNAME
                If FileExists($folder_target) Then
                    ; Remove the target folder
                    ConsoleWrite('Target = ' & $folder_target & @CRLF); Test purpose only
                    ;DirRemove($folder_target, 1); Uncomment for folder removal
                EndIf
            EndIf
        WEnd
        FileClose($handle_search)
    EndIf
EndIf

Tested output looks ok

WorkingDir = C:\Documents and Settings

Target = Michael\Application Data\Microsoft

You can set $FOLDERNAME to your target folder, remove the ConsoleWrite() functions and uncomment the the DirRemove() when satisfied.