GUICtrlCreateCheckbox + GUICtrlSetColor.

[Info]

GUICtrlCreateCheckbox ("Lol", 50, 40, 100, 20)
GUICtrlSetColor(-1, 0xFFFFFF)

My background color is black, so I wanted to change the CheckBox'es text color to white.

Doesn't work.

Help?

Edited February 18, 2008 by Info

[rasim]

GUICtrlCreateCheckbox ("Lol", 50, 40, 100, 20)
GUICtrlSetColor(-1, 0xFFFFFF)

My background color is black, so I wanted to change the CheckBox'es text color to white.

Doesn't work.

Help?

Try this trick

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 200, 100)
GUISetBkColor(0x000000, $GUI)

GUICtrlCreateLabel("LOL", 68, 42, 50, 17)
GUICtrlSetColor(-1, 0xFFFFFF)

GUICtrlCreateCheckbox ("", 50, 40, 14, 15)

GUISetState(@SW_SHOW, $GUI)

Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

[Squirrely1]

What version of Windows are you using? I looked in the AutoIt Help file under "GUICtrlSetColor" and found this caveat:

Checkbox, Radio or Progress controls cannot be painted if the "Windows XP style" is used.

Button controls are always painted in "Windows Classic style".

Code-wise, checkboxes are actually buttons having a special style to them.

I don't know which syle you might need to use for your GUI window to get white text for those checkboxes.

Edited February 18, 2008 by Squirrely1

[Info]

Try this trick

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 200, 100)
GUISetBkColor(0x000000, $GUI)

GUICtrlCreateLabel("LOL", 68, 42, 50, 17)
GUICtrlSetColor(-1, 0xFFFFFF)

GUICtrlCreateCheckbox ("", 50, 40, 14, 15)

GUISetState(@SW_SHOW, $GUI)

Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

That sucks =[

What version of Windows are you using? I looked in the AutoIt Help file under "GUICtrlSetColor" and found this caveat:

Code-wise, checkboxes are actually buttons having a special style to them.

I don't know which syle you might need to use for your GUI window to get white text for those checkboxes.

You right, I switched the style to classic and it worked.

I'll check if it works as an .exe file in WinXP style.

EDIT:

Not working, too bad for me.

I guess I'll have to use rasim's trick... =[

Edited February 18, 2008 by Info

[Squirrely1]

I thought of rasim's technique just about the time he posted it. I haven't tested his code but can guarantee that the workaround is typical of what we have to do in AutoIt sometimes. But this one isn't even radical in the least, there is no trickery involved - the saints while not smiling on it, would not condemn it. Perfectly legal.

[rasim]

Info

That sucks =[

Thank you for good words.

Try this:

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 200, 100)
GUISetBkColor(0x000000, $GUI)

$hCheckBox = GUICtrlCreateCheckbox ("Lol", 50, 40, 50, 15)
GUICtrlSetColor(-1, 0xFFFFFF)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hCheckBox), "wstr", "", "wstr", "")

GUISetState(@SW_SHOW, $GUI)

Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

[MrCreatoR]

http://www.autoitscript.com/forum/index.ph...st&p=480855

[Valuater]

The uses above actually change the XP settings, however this little UDF will do what you need and replace the users original settings

#include <GUIConstants.au3>
Dim $XS_n

GUICreate("My GUI Checkbox")  ; will create a dialog box that when displayed is centered
GUISetBkColor(0x000000)
If XPStyle(1) Then MsgBox(0,0,"on", 2)
$checkCN = GUICtrlCreateCheckbox("CHECKBOX 1", 10, 10, 120, 15)
GUICtrlSetColor($checkCN, 0xFF0000)
GUICtrlSetBkColor($checkCN, 0x000000);0xFFFFFF)
If XPStyle(0) Then MsgBox(0,0,"off", 2)
GUISetState()       ; will display an  dialog box with 1 checkbox

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

Func XPStyle($OnOff = 1)   
    If $OnOff And StringInStr(@OSTYPE, "WIN32_NT") Then
        $XS_n = DllCall("uxtheme.dll", "int", "GetThemeAppProperties")
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
        Return 1
    ElseIf StringInStr(@OSTYPE, "WIN32_NT") And IsArray($XS_n) Then
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", $XS_n[0])
        $XS_n = ""
        Return 1
    EndIf
    Return 0
EndFunc   ;==>XPStyle

MSCreator knows this one too!!..??

... there are more helpful snippets in Autoit Wrappers

8)

[MrCreatoR]

MSCreator knows this one too!!..??

Yes sure, i pulled out from this example the line with DllCall

Btw, i do not like much the idea of using Global declaration here, maybe this function should return the old theme value?

Like this:

#include <GUIConstants.au3>

GUICreate("_SetThemeAppProperties Example", 200, 100)  ; will create a dialog box that when displayed is centered
GUISetBkColor(0x000000)

$iOld_AppTheme = _SetThemeAppProperties(0)

$CheckBox = GUICtrlCreateCheckbox("CHECKBOX", 60, 40, 120, 15)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)

_SetThemeAppProperties($iOld_AppTheme)


GUISetState() ; will display an  dialog box with 1 checkbox

; Run the GUI until the dialog is closed
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func _SetThemeAppProperties($iTheme=0)
    If Not StringInStr(@OSTYPE, "WIN32_NT") Then Return 0
    
    Local $a_Old_AppTheme = DllCall("uxtheme.dll", "int", "GetThemeAppProperties")
    If @error Then Return 0
    
    DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", $iTheme)
    If @error Then Return 0
    
    Return $a_Old_AppTheme[0]
EndFunc   ;==>SetThemeAppProperties

[Info]

Thank you all, really helped me.