Convert Alpha-Num to Decimal?

[ken82m]

Okay what I'm actually doing is converting a dell service tag into an express service tag.

Based on what I read this seemed like something easy for Auto-IT but haven't found anything in the Math or Conversion sections of the help file.

Here is an example and description along with a link.

5RFDP01 = 125-423-316-01

http://www.creativyst.com/Doc/Articles/HT/Dell/DellNumb.htm

The dashes are the only thing that might throw you.

• The Service Tag is just a big base-36 number (composed of digits [0-9A-Z]) so,
• Convert it to a big decimal number (12,542,331,601), then
• Add dashes every third digit starting from the left-most (MSD) digit

Thanks again as always,

-Kenny

[sensalim]

I don't know how 5RFDP01 becomes that number, but here's my version. It's not efficient but whatever .

-

Ok I guess my code is not base-36 lol, but it was fun.

Edited April 16, 2008 by sensalim

[junkew]

expandcollapse popup

;From base 36
consolewrite(addDash(ConvertBase("5RFDP01")) & @crLF)
consolewrite(ConvertBase("5rfdP01") & @crLF)
consolewrite(ConvertBase("0") & @crLF)
consolewrite(ConvertBase("Z") & @crLF)
consolewrite(ConvertBase("Z0") & @crLF)
consolewrite(ConvertBase("10") & @crLF)
consolewrite(ConvertBase("200")& @crLF)

;From hex (base 16)
consolewrite(ConvertBase("0",16)& @crLF)
consolewrite(ConvertBase("10",16)& @crLF)

;From binary (base 2)
consolewrite(ConvertBase("11",2)& @crLF)
consolewrite(ConvertBase("100",2)& @crLF)

;Converts from a certain base to base 10
func convertBase($s, $fromBase=36)
    $Total=0
    $BaseValue=1
    
    for $i=stringlen($s) to 1 step -1
        $DecimalValue = asc(stringmid($s,$i,1))-48
        if $DecimalValue >= 17 then $DecimalValue=$DecimalValue-7
        if $DecimalValue >= 42 then $DecimalValue=$DecimalValue-32
        
        if $i=stringlen($s) Then
            $total+=$decimalvalue
        Else
            $total += ($decimalvalue * $BaseValue)
        EndIf
        
;   consolewrite(stringmid($s,$i,1)& " " & $DecimalValue & " " & $decimalvalue * $BaseValue & @CRLF)

        $BaseValue=$BaseValue * $fromBase
    next
    
    return $total
    
EndFunc

;Adds some formatting if needed
func addDash($s)
    local $result = stringleft($s,3)
    For $i=4 To StringLen($s) Step 3
        $result &= "-" & StringMid($s, $i, 3)  
    Next
    Return $result
endFunc

edit:

* Added lowercase a-z to work

* Added dashes logic

* Added different base from logic so can handle binary (base 2), handle hex (base 16) or any other wanted base between 2 and 36

Edited April 16, 2008 by junkew

[sensalim]

Nice. My brain is not that fast.

However you forgot the minor 'dashes' detail.

[martin]

Okay what I'm actually doing is converting a dell service tag into an express service tag.

Based on what I read this seemed like something easy for Auto-IT but haven't found anything in the Math or Conversion sections of the help file.

Here is an example and description along with a link.

5RFDP01 = 125-423-316-01

http://www.creativyst.com/Doc/Articles/HT/Dell/DellNumb.htm

The dashes are the only thing that might throw you.

• The Service Tag is just a big base-36 number (composed of digits [0-9A-Z]) so,
• Convert it to a big decimal number (12,542,331,601), then
• Add dashes every third digit starting from the left-most (MSD) digit

Thanks again as always,

-Kenny

Here's another attempt

MsgBox(0, "result = ", code("5RFDP01"))

Func code($tag)
    Local $factor = 1
    Local $ans = 0
    Local $n
    For $n = StringLen($tag) To 1 Step -1
        $next = StringMid($tag, $n, 1)
        Switch Asc($next)
            Case Asc("A") To Asc("Z")
                $ans += (Asc($next) - Asc("A") + 10) * $factor
            Case Asc("0") To Asc("9")
                $ans += (Asc($next) - Asc("0")) * $factor
        EndSwitch
        $factor *= 36
    Next

    Local $result = StringMid($ans, 1, 3)
    For $n = 4 To StringLen($ans) Step 3
        $result &= "-" & StringMid($ans, $n, 3)
    Next
    Return $result

EndFunc  ;==>code

[DaveF]

Shames me to admit, but I never did a to-AutoIt3 conversion of Dell's own ECMAScript converter code (copied from Dell's support site years and years ago).

Very, very nice, group. Only gotcha is that you need to be sure to convert the initial string to uppercase if you're leveraging the ASCII code for the letters.

[rudi]

@junkew: Respect for your compact code!

[snipped the far better approach]

As I thought this an interesting example to explain base conversion I coded a much too many lines and illustrated approach. As I've written it, I'll post it anyways:

expandcollapse popup

#include <array.au3>

dim $Base36Arr[36][2]
Dim $Base=36
dim $k = -1
#Region fill the base36 lookup table
#Region fill 0-9
for $i = 0 to 9
    $k += 1 
    $Base36Arr[$k][0]=$i
    $Base36Arr[$k][1]=$k
Next
#EndRegion fill 0-9

#Region fill A - Z, A = 65, Z = 90
for $i = 65 to 90
    $k += 1 
    $Base36Arr[$k][0]=chr($i)
    $Base36Arr[$k][1]=$k
Next
#EndRegion fill A - Z, A = 65, Z = 90
_ArrayDisplay($Base36Arr,"The lookup table for base 36 numbers:")
#EndRegion fill the base36 lookup table

#Region Fill the 36^x lookup table
Dim $Exp36Array[7] ; what's the base36 value of this digit, goes 0 to 6
for $i = 0 to 6
    $Exp36Array[$i]=Exp(Log(36)*$i) ; Exp(log(x)*y) = x^y
Next
_ArrayDisplay($Exp36Array,"That's the value of the digits in a base 36 number")
#EndRegion Fill the 36^x lookup table


$DellSrvTg="5RFDP01"
$ExpressSrvTg=0
$Bit36=-1
for $i = StringLen($DellSrvTg) to 1 Step -1
    $Bit36 +=1 
    $NextDigit=StringMid($DellSrvTg,$i,1)
    for $k = 0 to 35
        If $NextDigit = $Base36Arr[$k][0] Then
                     $ExpressSrvTg += $Base36Arr[$k][1] * $Exp36Array[$Bit36]
        EndIf
        #ce
    Next
Next
MsgBox(0,"Your Express Service Tag is:",$ExpressSrvTg)


MsgBox(0,"Final Value:",StringLeft($ExpressSrvTg,3) & "-" & StringMid($ExpressSrvTg,4,3) & "-" & StringMid($ExpressSrvTg,7,3)& "-" & StringRight($ExpressSrvTg,2))

Regards, Rudi.

[junkew]

Very, very nice, group. Only gotcha is that you need to be sure to convert the initial string to uppercase if you're leveraging the ASCII code for the letters.

Removed the gotcha lower characters works fine also

[ken82m]

Great, works perfect. Thanks guys!

DaveF, perhaps could be added to the next release as "AlphaToDec"? Granted I don't know how it would be otherwise useful but we seem to have just about every other conversion in their such as dec, hex, bin etc...

Thanks again,

Kenny

[therks]

DaveF, perhaps could be added to the next release as "AlphaToDec"? Granted I don't know how it would be otherwise useful but we seem to have just about every other conversion in their such as dec, hex, bin etc...

Been there, done that, wasn't accepted. I wrote a _NumBaseConvert function a long time ago.

[rudi]

Been there, done that, wasn't accepted. I wrote a _NumBaseConvert function a long time ago.

Very nice function.

Just range checking would need to be added to recognize if the "$v_Input" isn't a valid number for the given "$i_BaseFrom":

MsgBox(0,"",_numbaseconvert("ffff",2,10) & ", Error: "&@error)

should throw an error instead of returning "225"

I think this is a function worth to "be accepted"

Regards, Rudi.