Listview - import picture as subitems

[tchomane]

Hi to all,

I didn't find anywhere how to import a picture as bitmap thumbnail into a listview.

Do you know how to do this?

i know how to import an icon but not a picture with a size like this : 160x160

thanks.

[tchomane]

Up !

I'm trying to import a picture into a cell of a Listview but I cannot do this.

Does anyone know how to?

Regards.

[redsleeves]

I use this to add icons.

_GUIImageList_AddIcon

_GUICtrlListView_AddItem, _GUICtrlListView_AddSubItem

See _GUIImageList_SetBkColor in the help file for a great example.

[tchomane]

Thanks a lot redsleeves.

I updated Autoit to latest version and it's ok.

As I see we can't import big picture in Listview.

Regards.

[GaryFrost]

Thanks a lot redsleeves.

I updated Autoit to latest version and it's ok.

As I see we can't import big picture in Listview.

Regards.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hImage, $hListView, $pix = 32; width and height
    Local $iIndex

    ; Create GUI
    GUICreate("ListView Add Item", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268, -1, $LVS_EX_SUBITEMIMAGES)
    GUISetState()

    ; Load images
    $hImage = _GUIImageList_Create($pix, $pix, 5, 1, 5, 20)
    _GUIImageList_AddBitmap($hImage, @WindowsDir & "\Coffee Bean.bmp")
    _GUIImageList_AddBitmap($hImage, @WindowsDir & "\FeatherTexture.bmp")
    _GUIImageList_AddBitmap($hImage, @WindowsDir & "\Gone Fishing.bmp")
    _GUIImageList_AddBitmap($hImage, @WindowsDir & "\GreenStone.bmp")
    _GUIImageList_AddBitmap($hImage, @WindowsDir & "\Soap Bubbles.bmp")
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Add columns
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)

    ; Add items
    For $x = 0 To 4
        $iIndex = _GUICtrlListView_AddItem($hListView, "Row " & $x + 1 & ": Col 1", $x)
        For $y = 1 To 2
            _GUICtrlListView_AddSubItem($hListView, $iIndex, "Col " & $y + 1, $y, Random(0, 4, 1))
        Next
    Next


    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

[tchomane]

Thanks a lot Gary ! That's good enough for me. I endly understand what _GUIImageList is about. You're a master.