check whether the mouse is left/right clicked on certain TrayIcon

[D4llower]

Greetings...

I want to konw that is there any way to check whether the mouse is left/right clicked on certain TrayIcon.

Or how to get the handle of certain TrayIcon when the TrayIcon is clicked?

Thanks very much!

[D4llower]

I want to add a contextmenu for a program which have a TrayIcon but without a TrayMenu...

any help?

[D4llower]

Does someone have ideas?

[d4rk]

Greetings...

I want to konw that is there any way to check whether the mouse is left/right clicked on certain TrayIcon.

Or how to get the handle of certain TrayIcon when the TrayIcon is clicked?

Thanks very much!

which icon ? an external ones or your scripts ?

[rasim]

Greetings...

I want to konw that is there any way to check whether the mouse is left/right clicked on certain TrayIcon.

Or how to get the handle of certain TrayIcon when the TrayIcon is clicked?

Thanks very much!

This?

expandcollapse popup

#include <GuiToolBar.au3>
#include <WinAPI.au3>
#include <Misc.au3>

HotKeySet("{Pause}", "_Exit")

Global $DllHandle = DllOpen("user32.dll")

_SysTray_GetClick("Opera")

;========================================================================================
;
;Function Name:    _SysTray_GetClick()
;Description:      Show what mouse button clicked on certain icon in system tray
;Parameters:       $iTitle - The title of the item in Windows system tray (you can see the _
;                  title of the item when mouse cursor hovered on item).
;                  
;Return Value(s):  On success - Write in SciTE console what the mouse button pressed on item
;                  On failure - Error message if required item not found
;Requirement(s):   AutoIt 3.2.10.0
;
;========================================================================================
Func _SysTray_GetClick($sTitle = "")
    If $sTitle = "" Then
        DllClose($DllHandle)
        Return False
    EndIf
    
    Local $hParent, $hChild, $hToolBar, $iCount, $iID = 0, $iText, $iIndex, $iHot
    
    $hParent = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hChild = ControlGetHandle($hParent, "", "TrayNotifyWnd1")
    $hToolBar = ControlGetHandle($hChild, "", "ToolbarWindow321")
    
    $iCount = _GUICtrlToolbar_ButtonCount($hToolBar)
    
    For $i = 0 To $iCount - 1
        $iID = _GUICtrlToolbar_IndexToCommand($hToolBar, $i)
        $iText = _GUICtrlToolbar_GetButtonText($hToolBar, $iID)
        If StringInStr($iText, $sTitle) Then ExitLoop
    Next
    
    If $iID = 0 Then
        MsgBox(16, "Error", "Required item not found")
        Return False
    EndIf
    
    $iIndex = _GUICtrlToolbar_CommandToIndex($hToolBar, $iID)
    
    While 1
        $iHot = _GUICtrlToolbar_GetHotItem($hToolBar)
        If ($iHot = $iIndex) And (_IsPressed("01", $DllHandle) = 1) Then
            ConsoleWrite("Left mouse button clicked on " & $iText & " item" & @LF)
            Sleep(100)
        ElseIf ($iHot = $iIndex) And (_IsPressed("02", $DllHandle) = 1) Then
            ConsoleWrite("Right mouse button clicked on " & $iText & " item" & @LF)
            Sleep(100)
        EndIf
        Sleep(50)
    WEnd
EndFunc   ;==>_SysTray_GetClick

Func _Exit()
    DllClose($DllHandle)
    Exit
EndFunc

[D4llower]

This?

expandcollapse popup

#include <GuiToolBar.au3>
#include <WinAPI.au3>
#include <Misc.au3>

HotKeySet("{Pause}", "_Exit")

Global $DllHandle = DllOpen("user32.dll")

_SysTray_GetClick("Opera")

;========================================================================================
;
;Function Name:    _SysTray_GetClick()
;Description:      Show what mouse button clicked on certain icon in system tray
;Parameters:       $iTitle - The title of the item in Windows system tray (you can see the _
;                  title of the item when mouse cursor hovered on item).
;                  
;Return Value(s):  On success - Write in SciTE console what the mouse button pressed on item
;                  On failure - Error message if required item not found
;Requirement(s):   AutoIt 3.2.10.0
;
;========================================================================================
Func _SysTray_GetClick($sTitle = "")
    If $sTitle = "" Then
        DllClose($DllHandle)
        Return False
    EndIf
    
    Local $hParent, $hChild, $hToolBar, $iCount, $iID = 0, $iText, $iIndex, $iHot
    
    $hParent = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hChild = ControlGetHandle($hParent, "", "TrayNotifyWnd1")
    $hToolBar = ControlGetHandle($hChild, "", "ToolbarWindow321")
    
    $iCount = _GUICtrlToolbar_ButtonCount($hToolBar)
    
    For $i = 0 To $iCount - 1
        $iID = _GUICtrlToolbar_IndexToCommand($hToolBar, $i)
        $iText = _GUICtrlToolbar_GetButtonText($hToolBar, $iID)
        If StringInStr($iText, $sTitle) Then ExitLoop
    Next
    
    If $iID = 0 Then
        MsgBox(16, "Error", "Required item not found")
        Return False
    EndIf
    
    $iIndex = _GUICtrlToolbar_CommandToIndex($hToolBar, $iID)
    
    While 1
        $iHot = _GUICtrlToolbar_GetHotItem($hToolBar)
        If ($iHot = $iIndex) And (_IsPressed("01", $DllHandle) = 1) Then
            ConsoleWrite("Left mouse button clicked on " & $iText & " item" & @LF)
            Sleep(100)
        ElseIf ($iHot = $iIndex) And (_IsPressed("02", $DllHandle) = 1) Then
            ConsoleWrite("Right mouse button clicked on " & $iText & " item" & @LF)
            Sleep(100)
        EndIf
        Sleep(50)
    WEnd
EndFunc   ;==>_SysTray_GetClick

Func _Exit()
    DllClose($DllHandle)
    Exit
EndFunc

Oh, so great!

It's just the effect I hope to realize...

Thank you so much!