Creating Log file wich writes entries in the top of the file

[Iznogoud]

Good evening,

I am struggling with FileWriteline and _FileWriteLine() to make a simple script wich writes the date and time and username to a text file.

This is easy in the normal way wich the script add the line in the end of the file, but what i want to accomplish is it writes the new line above all the others.

So you got the new entries in the top of the text document when you open it.

Are there any other commands to accomplish this or is this to hard to do?

[FreeRider]

Hi Iznogoud,

it's not so hard to do... just let me few minutes and I come back with a sample script...

Good evening,

I am struggling with FileWriteline and _FileWriteLine() to make a simple script wich writes the date and time and username to a text file.

This is easy in the normal way wich the script add the line in the end of the file, but what i want to accomplish is it writes the new line above all the others.

So you got the new entries in the top of the text document when you open it.

Are there any other commands to accomplish this or is this to hard to do?

[MrCreatoR]

Here is a little changed _FileWriteLog() UDF:

_FileWriteLogEx(@ScriptDir & "\LogFile.log", "This is the first log entry" & @CRLF, 1)

Sleep(1000)

_FileWriteLogEx(@ScriptDir & "\LogFile.log", "This is the second log entry" & @CRLF, 1)

Sleep(1000)

_FileWriteLogEx(@ScriptDir & "\LogFile.log", "This is the third log entry..." & @CRLF, 1)

;And this one goes to the End:
_FileWriteLogEx(@ScriptDir & "\LogFile.log", @CRLF & "== This is the Ending line ==" & @CRLF, -1)

Func _FileWriteLogEx($sLogPath, $sLogMsg, $iFlag=-1)
    ;==============================================
    ; Local Constant/Variable Declaration Section
    ;==============================================
    Local $sDateNow, $sTimeNow, $sMsg, $iWriteFile, $hOpenFile, $iOpenMode = 1
    
    $sDateNow = @YEAR & "-" & @MON & "-" & @MDAY
    $sTimeNow = @HOUR & ":" & @MIN & ":" & @SEC
    $sMsg = $sDateNow & " " & $sTimeNow & " : " & $sLogMsg
    
    If $iFlag <> -1 Then
        $sMsg &= FileRead($sLogPath)
        $iOpenMode = 2
    EndIf
    
    $hOpenFile = FileOpen($sLogPath, $iOpenMode)
    If $hOpenFile = -1 Then Return SetError(1, 0, 0)
    
    $iWriteFile = FileWriteLine($hOpenFile, $sMsg)
    If $iWriteFile = -1 Then Return SetError(2, 0, 0)
    
    Return FileClose($hOpenFile)
EndFunc

Edited April 24, 2008 by MsCreatoR

[FreeRider]

I'm back...

Try this... it's lite, simple and easy to use (I've made a quick test and it works).

#include <Date.au3>
#include <File.au3>

If not FileExists(@ScriptDir & "\" & StringTrimRight(@ScriptName,3) & "log") Then _FileCreate (@ScriptDir & "\" & StringTrimRight(@ScriptName,3) & "log")
For $i = 1 to 3
_FileWriteToLine(@ScriptDir & "\" & StringTrimRight(@ScriptName,3) & "log",1,_Now() & " - " & @UserName)
sleep (1000)
Next

Bye,

Good evening,

I am struggling with FileWriteline and _FileWriteLine() to make a simple script wich writes the date and time and username to a text file.

This is easy in the normal way wich the script add the line in the end of the file, but what i want to accomplish is it writes the new line above all the others.

So you got the new entries in the top of the text document when you open it.

Are there any other commands to accomplish this or is this to hard to do?