How to start GUI at its previous position?

[qwert]

Would anyone happen to know of a UDF or code snippet that, upon exiting a GUI, will note the current window position -- and then provide those coordinates to the same script the next time it is run?

I would think this is a common need and that it has been solved already. However, if I'm unable to locate existing code, my plan is to use WinGetPos in an exit function as a basis for writing a simple text file -- and then (at startup) have the script read the file and position accordingly.

Any suggestions of a better method will be appreciated.

Thanks in advance.

[Generator]

Would anyone happen to know of a UDF or code snippet that, upon exiting a GUI, will note the current window position -- and then provide those coordinates to the same script the next time it is run?

I would think this is a common need and that it has been solved already. However, if I'm unable to locate existing code, my plan is to use WinGetPos in an exit function as a basis for writing a simple text file -- and then (at startup) have the script read the file and position accordingly.

Any suggestions of a better method will be appreciated.

Thanks in advance.

Technically there aren't any snippets or UDF for this, your only approach would either be writing a txt file and reading it or write a registry value and read it again later.

[qwert]

Technically there aren't any snippets or UDF for this, your only approach would either be writing a txt file and reading it or write a registry value and read it again later.

Thanks for weighing in on this. I'm not to keen on writing to the registry, so I guess the text file is my best bet.

[MrCreatoR]

Here is an example...

expandcollapse popup

#include <GuiConstants.au3>

Global $ConfigFile = StringTrimRight(@ScriptFullPath, 3) & "ini"

$GUI = GUICreate("GUI Restore Position", 300, 200, -1, -1, BitOr($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))
_GUIRestorePositions($GUI, $ConfigFile)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _GUISavePositions($GUI, $ConfigFile)
            Exit
    EndSwitch
WEnd

Func _GUISavePositions($hGUI, $sConfigFile, $sSectName="Window Positions")
    Local $aGUI_Pos = WinGetPos($hGUI)
    If @error Then Return 0
    
    IniWrite($sConfigFile, $sSectName, "Left", $aGUI_Pos[0])
    IniWrite($sConfigFile, $sSectName, "Top", $aGUI_Pos[1])
    IniWrite($sConfigFile, $sSectName, "Width", $aGUI_Pos[2])
    IniWrite($sConfigFile, $sSectName, "Height", $aGUI_Pos[3])
    
    Return 1
EndFunc

Func _GUIRestorePositions($hGUI, $sConfigFile, $sSectName="Window Positions", $iDefWidth=300, $iDefHeight=200)
    Local $iGUI_Left = IniRead($sConfigFile, $sSectName, "Left", -1)
    Local $iGUI_Top = IniRead($sConfigFile, $sSectName, "Top", -1)
    Local $iGUI_Width = IniRead($sConfigFile, $sSectName, "Width", $iDefWidth)
    Local $iGUI_Height = IniRead($sConfigFile, $sSectName, "Height", $iDefHeight)
    
    If $iGUI_Left = -1 Then $iGUI_Left = (@DesktopWidth / 2) - ($iGUI_Width / 2)
    If $iGUI_Top = -1 Then $iGUI_Top = (@DesktopHeight / 2) - ($iGUI_Height / 2)
    
    Return WinMove($hGUI, "", $iGUI_Left, $iGUI_Top, $iGUI_Width, $iGUI_Height)
EndFunc

[qwert]

Thank you, sir. That's exactly what I was looking for. Now, thanks to you, the technique exists!