[SOLVED] GuiSetAccelerators Help

[zackrspv]

Now, I know that you have to use beta, which I am

What I want to accomplish: Alt+Shift+N, Alt+Shift+C, Alt+Shift+Q and Up and Down need to be hotkeys only available WITHIN my app. I figured since i'm writing this entire program in beta, i'd give it a go. Was looking at the forum for Accelerator, and it says like:

include <GUIConstantsEx.au3>
GUICreate("Custom Msgbox", 210, 80)
GUICtrlCreateLabel("Please click a button!", 10, 10)
$YesID = GUICtrlCreateButton("Yes", 10, 50, 50, 20)
$NoID = GUICtrlCreateButton("No", 80, 50, 50, 20)
$ExitID = GUICtrlCreateButton("Exit", 150, 50, 50, 20)
; Set accelerators for Ctrl+y and Ctrl+n
Dim $AccelKeys[2][2]=[["^y", $YesID], ["^n", $NoID]]
GUISetAccelerators($AccelKeys)
GUISetState(); display the GUI

So, to me, in order for accelerators to work, it has to have an associated control id in the array, ok so no problem.

I figured then, i'd write:

Local Enum $SQueue = "3922", $Snew, $SClose, $SUP, $SDown
Dim $AccelKeys[5][2] = [["!+q", $SQueue],["!+n", $Snew],["!+c", $SClose],["{UP}", $SUP],["{DOWN}", $SDown]]
GUISetAccelerators($AccelKeys)

To give it mock ID's. But turns out when you press those keys nothing happens. Must i actually define a control? I mean, i'm not opposed to creating 5 invisible buttons lol, but still. I figured the enum trick would work. Any thoughts?

Edited May 16, 2008 by zackrspv

[Zedna]

1) Post WHOLE reproducing script

2) Look here

[zackrspv]

1) Post WHOLE reproducing script

2) Look here

1) In effect, it was the whole script; the rest were just case handlers.

2) That's where i got the idea for accelerators from

#include<GUIConstantsEx.au3>
$form = GUICreate("test", 500, 500)
Local Enum $SQueue = "3922", $Snew, $SClose, $SUP, $SDown
Dim $AccelKeys[5][2] = [["!+q", $SQueue],["!+n", $Snew],["!+c", $SClose],["{UP}", $SUP],["{DOWN}", $SDown]]
GUISetAccelerators($AccelKeys)
GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $SQueue
            ConsoleWrite("queue" & @CRLF)
        Case $Snew
            ConsoleWrite("new" & @CRLF)
        Case $SClose
            ConsoleWrite("close" & @CRLF)
        Case $SUP
            ConsoleWrite("up" & @CRLF)
        Case $SDown
            ConsoleWrite("down" & @CRLF)
    EndSwitch
WEnd

Note, when you press any of those keys, nothing happens . So setting your own Identifiers for them doesn't seem to work. Which, of course, and i'm not being rude here, my apologizes if it sounds like it, brings me back to my question: Do i really need to create 5 hidden buttons here? lol

Edited May 15, 2008 by zackrspv

[Siao]

Do i really need to create 5 hidden buttons here? lol

GUICtrlCreateDummy would work

[zackrspv]

GUICtrlCreateDummy would work

Sure enough does, thanks much bud

#include<GUIConstantsEx.au3>
$form = GUICreate("test", 500, 500)

$SQueue = GUICtrlCreateDummy()
$Snew = GUICtrlCreateDummy()
$SClose = GUICtrlCreateDummy()
$SUP = GUICtrlCreateDummy()
$SDown = GUICtrlCreateDummy()
Dim $AccelKeys[5][2] = [["!+q", $SQueue],["!+n", $Snew],["!+c", $SClose],["{UP}", $SUP],["{DOWN}", $SDown]]
GUISetAccelerators($AccelKeys)
GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $SQueue
            ConsoleWrite("queue" & @CRLF)
        Case $Snew
            ConsoleWrite("new" & @CRLF)
        Case $SClose
            ConsoleWrite("close" & @CRLF)
        Case $SUP
            ConsoleWrite("up" & @CRLF)
        Case $SDown
            ConsoleWrite("down" & @CRLF)
    EndSwitch
WEnd

[amin84]

Tnx. Good to know about GUICtrlCreateDummy().

[BrewManNH]

Is there a reason why you're necroposting so often, this thread is over 4 years old so there's really no need to resurrect it just to post a thank you.