Writing BACKSPACE

[faire]

I have a text file that looks like this:

option1
option2
option3
* empty line*

To append new text at the end of the file I use:

FileWriteLine($file, "some text")

Which results in:

option1
option2
option3
* empty line*
some text

Now I want to get rid of that *empty line* that's in the text file by default, by writing a backspace character.

I have tried this:

FileWriteLine($file, Chr(08) & "some text")

But that ends up looking like this:

option1
option2
option3
* empty line*
some text

Notice that character, which should be a backspace.. What's the proper way to do this?

Edited May 16, 2008 by faire

[jdisme]

Did you try send {BS}?

Edited May 16, 2008 by jdisme

[ProgAndy]

you have to use Winapi Functions ans FileSetPointerEx:

#include<Winapi.au3>
$File = _WinAPI_CreateFile("D:\TEMP\Test.txt",2)
DllCall("kernel32.dll","long","SetFilePointerEx","hwnd", $File, "uint64",-1,"long*",0,"dword",2)
MsgBox(0, '', "")
$b = DllStructCreate("Char[10]")
DllStructSetData($b,1,"asdfghjkl")
Dim $w
_WinAPI_WriteFile($File,DllStructGetPtr($B),9,$w)
_WinAPI_CloseHandle($File)

or you first have to Read the File and then write it from new

[GEOSoft]

If you know the line number (in this case 4) then you can use

#Include <File.au3>
_FileWriteToLine($File, 4, "some text")

[GEOSoft]

Another method would be

$test = StringStripWS(FileRead($file), 2) & @CRLF & "some text"
FileOpen($file,2)
FileWrite($File, $Test)
FileClose($File)

[faire]

you have to use Winapi Functions ans FileSetPointerEx:

...

or you first have to Read the File and then write it from new

I tried your code. It does get rid of the empty line, but still adds that character:

option1
option2
option3

asdfghj

Edit: hmm, it shows as a blank line here, but in Notepad it shows a block character (like backspace).

If you know the line number (in this case 4) then you can use

Unfortunately the line number isn't always the same.. Edited May 16, 2008 by faire

[faire]

Another method would be

$test = StringStripWS(FileRead($file), 2) & @CRLF & "some text"
FileOpen($file,2)
FileWrite($File, $Test)
FileClose($File)

You, sir, are the winner Works!

[ProgAndy]

I tried your code. It does get rid of the empty line, but still adds that character:

Edit: hmm, it shows as a blank line here, but in Notepad it shows a block character (like backspace).

Unfortunately the line number isn't always the same..

Jeah, you use @CRLF this are two characters

You would have to Change the -1 after the uint64 to -2, so you go back 2 chars

DllCall("kernel32.dll","long","SetFilePointerEx","hwnd", $File, "uint64",-1,"long*",0,"dword",2)

[PsaltyDS]

Maybe this makes more sense:

#include <File.au3>

Global $sFile = "C:\Temp\Test.txt"
Global $fLastLineBlank = False
Global $iLastLine = 0
Global $sNewLine = "This is my new line."

; Get last line
$iLastLine = _FileCountLines($sFile)

; See if last line is blank
If StringStripWS(FileReadLine($sFile, $iLastLine), 8) = "" Then $fLastLineBlank = True

; Write new line
If $fLastLineBlank Then
    _FileWriteToLine($sFile, $iLastLine, $sNewLine, True)
Else
    FileWriteLine($sFile, $sNewLine)
EndIf

P.S. When you view the file in a text editor and the last line appears empty, but contains no characters at all, that "line" doesn't actually exist. It's an artifact of the @CRLF at the end of the "previous" line. The format of the data is like this:

Line One.<@CRLF>
Line Two.<@CRLF>

But the presentation looks like this:

Line One.
Line Two.
<empty line>

Even though there are only two lines in the file, it looks like three in the editor (with line 3 "empty").

Edit: Fix typo (missing "=").

Edited May 16, 2008 by PsaltyDS

[GEOSoft]

In case you are still interested in this, I've added a function to my Filex.au3 UDF that removes all blank lines from a file.

Filex.au3

As usual there is a download button at the bottom of the page or you can just copy the code to the clipboard.