Get Scite text in Au3 - how to ?

[torels]

Hi all!

I was Wondering how to get the text written in the scite...

does somebody know ?

thanks in advance

[Dickb]

Hi all!

I was Wondering how to get the text written in the scite...

does somebody know ?

thanks in advance

There is a device developed for that. It is called a "Keyboard".

[monoceres]

Using ControlSend:

ControlSend(@ScriptDir,"","[ID:350]",@CRLF&"hello")

The @ScriptDir is just there because I found it to be the easiest way to find the SciTE window

[AdmiralAlkex]

He could mean ConsoleWrite() but it's impossible to tell with that badly written grammar

[NELyon]

And I bet I'm the only one who noticed that he says he wants to Get the text written in SciTe

[PsaltyDS]

I was Wondering how to get the text written in the scite...

does somebody know ?

SciTE draws its own edit control "[CLASS:Scintilla]", which is not a standard Windows API control. Therefore the text is not directly visible to AutoIt. But, it was coded with standard shortcuts for select all, copy, and paste. So this works:

Opt("WinTitleMatchMode", 4)

; Read text from SciTE (already open)
WinWait("[CLASS:SciTEWindow; INSTANCE:1]")
$hSciTE = WinGetHandle("[CLASS:SciTEWindow; INSTANCE:1]")
WinActivate($hSciTE)
WinWaitActive($hSciTE)
ControlFocus($hSciTE, "", "[CLASS:Scintilla; INSTANCE:1]")
ControlSend($hSciTE, "", "[CLASS:Scintilla; INSTANCE:1]", "^a")
ControlSend($hSciTE, "", "[CLASS:Scintilla; INSTANCE:1]", "^c")

; Paste text to Notepad
Run("Notepad.exe")
WinWait("[TITLE:Untitled - Notepad]")
$hNotepad = WinGetHandle("[TITLE:Untitled - Notepad]")
WinActivate($hNotepad)
WinWaitActive($hNotepad)
ControlSend($hNotepad, "", "[CLASS:Edit; INSTANCE:1]", "^v")

The Scintilla Text Editor (SciTE) is an open source project, and maybe there is more elegant way to read the text using some automation interface, but the brute-force hack above gets the job done.

[Jos]

Just an alternative with less "hacking"

SendSciTE_Command("insert:text to insert at cursor replacing possible selected text.")
;
;
Func SendSciTE_Command($sCmd)
    Opt("WinSearchChildren", 1)
; Get SciTE DirectorHandle
    $SciTE_hwnd = WinGetHandle("DirectorExtension")
    Local $WM_COPYDATA = 74
    Local $CmdStruct = DllStructCreate('Char[' & StringLen($sCmd) + 1 & ']')
    DllStructSetData($CmdStruct, 1, $sCmd)
    Local $COPYDATA = DllStructCreate('Ptr;DWord;Ptr')
    DllStructSetData($COPYDATA, 1, 1)
    DllStructSetData($COPYDATA, 2, StringLen($sCmd) + 1)
    DllStructSetData($COPYDATA, 3, DllStructGetPtr($CmdStruct))
    DllCall('User32.dll', 'None', 'SendMessage', 'HWnd', $SciTE_hwnd, _
            'Int', $WM_COPYDATA, 'HWnd', 0, _
            'Ptr', DllStructGetPtr($COPYDATA))
EndFunc  ;==>SendSciTE_Command

[torels]

And I bet I'm the only one who noticed that he says he wants to Get the text written in SciTe

thanks PsaltyDS & JOS!