Labels losing click functionality when bmp added to form.

[benners]

I am having a problem with part of a script that uses bmp resources from a dll to display background images. I have made a function using code from Here that create a picture container and adds a bmp as a background image. The form has labels that perform actions when clicked the trouble is after loading the bmp the labels no longer function.

I think it may be something to do with the order of the controls but can't figure out how to send the bmp to the background, is it possible?.

Thanks

expandcollapse popup

#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <WinAPI.au3>

Opt("GUIOnEventMode", 1)
Dim $Icofile = @SystemDir & '\shell32.dll', $BackGrd

$Form2 = GUICreate("Form2", 285, 157, 219, 150)
Create_BMP($BackGrd, 14351, 0, 0, 284, 156)
$Label1 = GUICtrlCreateLabel("Google", 40, 56, 38, 17)
GUICtrlSetOnEvent(-1, 'lbl_clicked')
GUICtrlSetColor(-1, 0x0000FF)
GUICtrlSetCursor(-1, 0)
$Label2 = GUICtrlCreateLabel("AutoIt", 40, 76, 32, 17)
GUICtrlSetOnEvent(-1, 'lbl_clicked')
GUICtrlSetColor(-1, 0x0000FF)
GUICtrlSetCursor(-1, 0)
GUISetState(@SW_SHOW)

GUISetOnEvent($GUI_EVENT_CLOSE, "DoExit")

While 1
    Sleep(10)
WEnd

Func lbl_clicked()
    Switch @GUI_CtrlId
        Case $Label1
            MsgBox(0, '', 'Googling')
            
        Case $Label2
            MsgBox(0, '', 'Getting Help')
    EndSwitch
EndFunc  ;==>lbl_clicked

Func Create_BMP($Ctrl_ID, $iBMP, $iLeft = 0, $iTop = 0, $iWidth = 0, $iHeight = 0); Load BMP from a dll ($Ctrl_ID = Control ID to be created, $iBMP = Index of BMP in dll, $ileft & $iTop = Left & Top pos, $iWidth & $iHeight = Width & Height of pic container)
    Local $hBmp = 0
    
    $Ctrl_ID = GUICtrlCreatePic('', $iLeft, $iTop, $iWidth, $iHeight); Create the Picture container.
    $hBmp = _WinAPI_LoadImage(_WinAPI_LoadLibrary($Icofile), $iBMP, $IMAGE_BITMAP, $iWidth, $iHeight, $LR_DEFAULTCOLOR); Load the BMP
    GUICtrlSendMsg($Ctrl_ID, 0x0172, $IMAGE_BITMAP, $hBmp); Load the bmp into the container.
EndFunc  ;==>Create_BMP

Func DoExit()
    Exit
EndFunc  ;==>DoExit

[GEOSoft]

set the state of the BMP to disabled.

[benners]

set the state of the BMP to disabled.

Thanks GEOSoft, obvious really