Update GUI without a flicker

[MuffettsMan]

trying to update a gui in this small example with a timer however no matter how i attack it the button update 'flickers' at times... by calling an update function that seems to cut down on alot of the flicker though its still an issue so there must be a better / cleaner way to attack the problem..

example script with the problem:

expandcollapse popup

#include <GUIConstants.au3>
#include <Date.au3>
#AutoIt3Wrapper_run_debug_mode=Y

dim $time
dim $UpdateTimer

$UpdateTimer = TimerInit()
$time = TimerInit()
$time_till_update = 1000 

#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 200, 42, 1610, 414)
$Label1 = GUICtrlCreateLabel("Timer:", 8, 16, 33, 17)
$TimeButton = GUICtrlCreateButton("", 40, 8, 75, 25, 0)
$Reset = GUICtrlCreateButton("Reset", 120, 8, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg =$GUI_EVENT_CLOSE
            Exit
        Case $nMsg =$Reset
            reset_timer()
        Case Else
            sleep (10)
    EndSelect
    $dif = Int((TimerDiff($time))/1000)
    if TimerDiff($UpdateTimer) >= $time_till_update then
            reset_Updatetimer()     
            UpdateGUI() 
    endif 
WEnd


func reset_timer() 
    $time = TimerInit() 
endfunc 

func reset_Updatetimer() 
    $UpdateTimer = TimerInit() 
endfunc 

Func UpdateGUI()
    $TimeButton = GUICtrlCreateButton($dif, 40, 8, 75, 25, 0)
EndFunc

[jpm]

Use the GUIStState(@SW_LOCK/@SW_UNLOCK ) before and after your change

[jpm]

Use the GUIStState(@SW_LOCK/@SW_UNLOCK ) before and after your change

[MrCreatoR]

You are creating the button over and over, i don't understand why just not use GUICtrlSetData()...

expandcollapse popup

#include <GUIConstants.au3>
#include <Date.au3>
#AutoIt3Wrapper_run_debug_mode=Y

dim $time
dim $UpdateTimer

$UpdateTimer = TimerInit()
$time = TimerInit()
$time_till_update = 1000 

#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 200, 42, 610, 414)
$Label1 = GUICtrlCreateLabel("Timer:", 8, 16, 33, 17)
$TimeButton = GUICtrlCreateButton("", 40, 8, 75, 25, 0)
$Reset = GUICtrlCreateButton("Reset", 120, 8, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg =$GUI_EVENT_CLOSE
            Exit
        Case $nMsg =$Reset
            reset_timer()
        Case Else
            sleep (10)
    EndSelect
    $dif = Int((TimerDiff($time))/1000)
    if TimerDiff($UpdateTimer) >= $time_till_update then
            reset_Updatetimer()  
            UpdateGUI() 
    endif 
WEnd


func reset_timer() 
    $time = TimerInit() 
endfunc 

func reset_Updatetimer() 
    $UpdateTimer = TimerInit() 
endfunc 

Func UpdateGUI()
    If GUICtrlRead($TimeButton, 1) <> $dif Then GUICtrlSetData($TimeButton, $dif)
EndFunc

Edited June 19, 2008 by MrCreatoR