Editing an INI file

[ScripterGuy]

I know how to change the lines in an ini file, but my problem is that two lines are essentially the same, and I'm not sure how to edit the second one, because all the changes apply to the first line. Here is the section in question.

[PATH]

FILTER_ID=03

FILTER_ID=01

I want to change it to:

[PATH]

FILTER_ID=03

FILTER_ID=00

Here is what I've written....

CODE

;edit windisp.Ini

IniWrite("C:\windisp\windisp.ini", "DISPATCHER", "FILTER_ID", "03")

IniWrite("C:\windisp\windisp.ini", "DISPATCHER", "FILTER_ID", "00")

It's probably simple, but I'm really new to this...thanks for any help.

[DaRam]

The standard INI read/write routines are not setup to do this by design (handling duplicate keynames).

You will have to use the file routines to do this.

Check the AutoIt help file for FileOpen, FileRead, FileReadLine, FileWriteLine, and FileClose.

I know how to change the lines in an ini file, but my problem is that two lines are essentially the same, and I'm not sure how to edit the second one, because all the changes apply to the first line. Here is the section in question.

[PATH]

FILTER_ID=03

FILTER_ID=01

I want to change it to:

[PATH]

FILTER_ID=03

FILTER_ID=00

Here is what I've written....

CODE

;edit windisp.Ini

IniWrite("C:\windisp\windisp.ini", "DISPATCHER", "FILTER_ID", "03")

IniWrite("C:\windisp\windisp.ini", "DISPATCHER", "FILTER_ID", "00")

It's probably simple, but I'm really new to this...thanks for any help.

[MrCreatoR]

Something like this:

expandcollapse popup

_IniWriteEx("C:\windisp\windisp.ini", "PATH", "FILTER_ID", "00", 2)

Func _IniWriteEx($sIniFile, $sSection, $sKey, $sValue, $iKeyCount=1)
    Local $hFileOpen, $aFileRead, $iCounter = 0, $sIni_Content = ""
    
    $aFileRead = StringSplit(StringStripCR(FileRead($sIniFile)), @LF)
    If @error Then Return SetError(1, 0, 0)
    
    For $i = 1 To UBound($aFileRead)-1
        If $aFileRead[$i] = "[" & $sSection & "]" Then
            $sIni_Content &= $aFileRead[$i] & @CRLF
            $i += 1
            
            While Not StringRegExp($aFileRead[$i], "\[.*\]$")
                If StringRegExpReplace($aFileRead[$i], "(.*)=.*$", "\1") = $sKey Then
                    $iCounter += 1
                    
                    If $iCounter = $iKeyCount Then
                        $sIni_Content &= $sKey & "=" & $sValue & @CRLF
                        ExitLoop
                    EndIf
                EndIf
                
                $sIni_Content &= $aFileRead[$i] & @CRLF
                
                $i += 1
                If $i > $aFileRead[0] Then ExitLoop
            WEnd
        Else
            $sIni_Content &= $aFileRead[$i] & @CRLF
        EndIf
    Next
    
    $hFileOpen = FileOpen($sIniFile, 2)
    If $hFileOpen = -1 Then Return SetError(2, 0, 0)
    
    FileWrite($hFileOpen, StringStripWS($sIni_Content, 2))
    FileClose($hFileOpen)
    
    Return 1
EndFunc

Edited June 20, 2008 by MrCreatoR

[ScripterGuy]

Thanks. I'll take a look!

[ProgAndy]

You could do it with INNIReadSection, too:

expandcollapse popup

; @error values: 1 -> error in reading, 2 -> keynumber too small, 3-> error in writing, 4->Key(index) not found
_IniWriteEx("t.ini","PATH","FILTER_ID","009",2)
MsgBox(0, '', _IniReadEx("t.ini","PATH","FILTER_ID",2))
Func _IniWriteEx($sIniFile, $sSection, $sKey, $sValue, $iKeyCount=1)
    Local $sec = IniReadSection($sIniFile, $sSection)
    If @error Then Return SetError(1,0,0)
    If $iKeyCount < 1 Then Return SetError(2,0,0)
    Local $counter = 0, $i
    For $i = 1 To $sec[0][0]
        If $sec[$i][0] = $sKey Then
            $counter += 1
            If $counter = $iKeyCount Then
                $sec[$i][1] = $sValue
                IniWriteSection($sIniFile, $sSection,$sec)
                If @error Then Return SetError(3,0,0)
                Return 1
            EndIf
        EndIf
    Next
    Local $bound = Ubound($sec)
    Redim $sec[$bound+1][2]
    $sec[$bound][0] = $sKey
    $sec[$bound][1] = $sValue
                IniWriteSection($sIniFile, $sSection,$sec)
                If @error Then Return SetError(3,0,0)   
    Return 1
EndFunc

Func _IniReadEx($sIniFile, $sSection, $sKey, $iKeyCount=1)
    Local $sec = IniReadSection($sIniFile, $sSection)
    If @error Then Return SetError(1,0,"")
    If $iKeyCount < 1 Then Return SetError(2,0,"")
    Local $counter = 0, $i
    For $i = 1 To $sec[0][0]
        If $sec[$i][0] = $sKey Then
            $counter += 1
            If $counter = $iKeyCount Then
                Return $sec[$i][1]
            EndIf
        EndIf
    Next
    Return SetError(4,0,"")
EndFunc

Edited June 20, 2008 by ProgAndy