Icon on top of icon

[Minikori]

Is it possible to put one icon on top of another? Here's my code:

CODE

$PowerIco = GUICtrlCreateIcon("shell32.dll", -28, 85, 130)

$DeleteIco = GUICtrlCreateIcon("shell32.dll", -132, 85, 130)

[smashly]

Hi, you can set 2 images to 1 Icon control with a bit of trickery.

Here's a crude example that doesn't have any error checking for incorrect user input..

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>
#include <GDIPlus.au3>
#include <Constants.au3>

$hGui = GUICreate('', 200, 200, -1, -1)
$DeleteIco = GUICtrlCreateIcon("", 0, 10, 10, 32, 32)
GUICtrlSetTip(-1, "Click icon to delete.")
GUISetState(@SW_SHOW, $hGui)

$hIcon1 = _SetTwoIconsToOneIconControl($hGui, $DeleteIco, "shell32.dll", 27, 131)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            If $hIcon1 Then _WinAPI_DestroyIcon($hIcon1)
            Exit
        Case $DeleteIco
            GUICtrlDelete($DeleteIco)
            _WinAPI_DestroyIcon($hIcon1)
            $hIcon1 = 0
    EndSwitch
WEnd

Func _SetTwoIconsToOneIconControl($hWnd, $cID, $sFile, $iName1, $iName2)
    Local Const $STM_SETIMAGE = 0x0172
    Local $hCID, $tL1, $pL1, $tL2, $pL2, $hImage1, $hGraphic, $hImage2, $hIcon, $hSetIcon
    $hCID = GUICtrlGetHandle($cID)
    $tL1 = DllStructCreate("int Handle[1]")
    $pL1 = DllStructGetPtr($tL1)
    $tL2 = DllStructCreate("int Handle[1]")
    $pL2 = DllStructGetPtr($tL2)    
    _WinAPI_ExtractIconEx($sFile, $iName1, $pL1, 0, 1)
    _WinAPI_ExtractIconEx($sFile, $iName2, $pL2, 0, 1)
    _GDIPlus_Startup()
    $hImage1 = DllCall($ghGDIPDll,"int", "GdipCreateBitmapFromHICON", "hWnd", DllStructGetData($tL1, "Handle", 1), "int*", 0)
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1[2])
    $hImage2 = DllCall($ghGDIPDll,"int", "GdipCreateBitmapFromHICON", "hWnd", DllStructGetData($tL2, "Handle", 1), "int*", 0)
    _GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage2[2], 0, 0, _GDIPlus_ImageGetWidth($hImage1[2]), _GDIPlus_ImageGetHeight($hImage1[2]))
    $hIcon = DllCall($ghGDIPDll,"int", "GdipCreateHICONFromBitmap", "hWnd", $hImage1[2], "int*", 0)
    _GDIPlus_ImageDispose($hImage2)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_Shutdown()     
    $hSetIcon = DllCall("user32.dll", "hwnd", "SendMessage", "hwnd", $hCID, "int", $STM_SETIMAGE, "int", $IMAGE_ICON, "int", $hIcon[2])
    _WinAPI_DestroyIcon(DllStructGetData($tL1, "Handle", 1))
    _WinAPI_DestroyIcon(DllStructGetData($tL2, "Handle", 1))
    If $hSetIcon[0] <> 0 Then _WinAPI_DeleteObject($hSetIcon[0])
    Return $hIcon[2]
EndFunc

Any Questions ?

Cheers

Edit: Changed the way the hIcon is destroyed.

Edited August 13, 2008 by smashly

[MrCreatoR]

Very nice example smashly!

One question: can it be used to set an image for a Listbox item? I opened a thread with this question, and martin has pointed to this topic so i will see how to draw icon image on the control, but the problem is that list item have no(?) control id, how we can get the handle of each item (index) and apply this method to set the icon?

P.S

Sorry for the offtopic.

[martin]

Very nice example smashly!

One question: .. but the problem is that list item have no(?) control id, how we can get the handle of each item (index) and apply this method to set the icon?

I posted a question back in your thread MrCreator.