co-running two functions

[turbox]

I want the tray buttons working while it sleep

$prefsitem  = TrayCreateItem("Preferences")
TrayCreateItem("")
$aboutitem  = TrayCreateItem("About")
TrayCreateItem("")
$exititem   = TrayCreateItem("Exit")

TraySetState()

While 1
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $prefsitem
            Msgbox(64, "Preferences:", "OS:" & @OSVersion)
        Case $msg = $aboutitem
            Msgbox(64, "About:", "AutoIt3-Tray-sample.")
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

sleep(353522)

[James]

AutoIt is single threaded only. To get something close, try AdlibEnable().

[burners]

have your code trigger a seperate .au3 and run it at the same time with the first script controlling what the second one does.

[PsaltyDS]

I want the tray buttons working while it sleep

$prefsitem  = TrayCreateItem("Preferences")
TrayCreateItem("")
$aboutitem  = TrayCreateItem("About")
TrayCreateItem("")
$exititem   = TrayCreateItem("Exit")

TraySetState()

While 1
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $prefsitem
            Msgbox(64, "Preferences:", "OS:" & @OSVersion)
        Case $msg = $aboutitem
            Msgbox(64, "About:", "AutoIt3-Tray-sample.")
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

sleep(353522)

This is what event mode was invented for:

Opt("TrayOnEventMode", 1)
Opt("TrayAutoPause", 0)
Opt("TrayMenuMode", 1)

Global $prefsitem = TrayCreateItem("Preferences")
TrayItemSetOnEvent(-1, "_TrayItemHit")
TrayCreateItem("")
Global $aboutitem = TrayCreateItem("About")
TrayItemSetOnEvent(-1, "_TrayItemHit")
TrayCreateItem("")
Global $exititem = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "_TrayItemHit")
TraySetState()

While 1
    Sleep(353522)
WEnd

Func _TrayItemHit()
    Switch @TRAY_ID
        Case $prefsitem
            MsgBox(64, "Preferences", "You clicked on preferences")
        Case $aboutitem
            MsgBox(64, "About", "You clicked on about")
        Case $exititem
            Exit
    EndSwitch
EndFunc  ;==>_TrayItemHit

[rudi]

This is what event mode was invented for:

Opt("TrayOnEventMode", 1)

Thanks a lot! That's exactly what I searched for a few days ago.

@ Dev / Doku Team:

In the Help File all the Opt() do not have particular examples for all the options.

This sample code for Opt("TrayOnEventMode",1) might be enlighting for others, too?

Regards, Rudi.