Unknown Problem

[Minikori]

Hey, working on a script that involves adding text to label, but also keeping the old text. I don't think I need to give an example so I won't

Thanks in advance.

Edited September 11, 2008 by Minikori

[Richard Robertson]

You could either keep a string variable with the text on it or set the text to (readtext + "new text").

[Minikori]

You could either keep a string variable with the text on it or set the text to (readtext + "new text").

I want do do your second idea, except I don't know how to get the current text(read text).

[cyanidemonkey]

$cominednewtext = GUICtrlRead($labelname) & "new test string."
GUICtrlSetData($labelname, $cominednewtext)

Edited September 11, 2008 by cyanidemonkey

[Minikori]

$cominednewtext = GUICtrlRead($labelname) & "new test string."
GUICtrlSetData($labelname, $cominednewtext)

Alright, here's my code, why isn't it working?

#include <GUIConstantsEx.au3>
#include <Misc.au3>

GUICreate("Test", 200, 250)

$Input = GUICtrlCreateInput("", 5, 225, 190, 20)
$Chat = GUICtrlCreateLabel("", 5, 5, 190, 215)
GUISetBkColor(0xFFFFFF)

GUISetState()
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case _IsPressed("0D")
            $InputGet = GUICtrlRead($Input)
            $TextSend = GUICtrlRead($Chat) & $InputGet
            GUICtrlSetData($Chat, $TextSend & @CRLF)
            GUICtrlSetData($Input, "")
    EndSelect
WEnd
Exit

[enaiman]

It is working but ... you aren't fast enough

_IsPressed is called too many times while you press the "Enter" key -> too many @CRLF are inserted and your next entry is too far away to be shown.

Do an experiment - run your code and do your best to hit the Enter key as fast as you can - you may be able to see the next entry (maybe). You can add also a Sleep(100) after _IsPressed and run it again - it will work, but, if you keep pressed a little longer the enter key - you will see that many lines are added.

Here is the fixed code:

#include <GUIConstantsEx.au3>
#include <Misc.au3>

GUICreate("Test", 200, 250)

$Input = GUICtrlCreateInput("", 5, 225, 190, 20)
$Chat = GUICtrlCreateLabel("", 5, 5, 190, 215)
GUISetBkColor(0xFFFFFF)

GUISetState()
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Input
            $InputGet = GUICtrlRead($Input)
            $TextSend = GUICtrlRead($Chat) & $InputGet
            GUICtrlSetData($Chat, $TextSend & @CRLF)
            GUICtrlSetData($Input, "")
    EndSelect
WEnd
Exit