Highlight control when mouse is over it [RESOLVED]

[Minikori]

I'm trying to make it so that when the user's mouse goes over a control it highlights it. This is what I have, but it won't unhighlight the control once the mouse leaves it. Here's what I have:

While 1
    $msg = GUIGetMsg()
    $cur = GUIGetCursorInfo()
    GUICtrlSetBkColor($cur[4], 0xFF0000)
    ;More code...
WEnd

Any help?

Edited October 11, 2008 by Minikori

[Pain]

Take a look at this one and see if it helps.

http://www.autoitscript.com/forum/index.php?showtopic=33230

Edited October 10, 2008 by Pain

[AdmiralAlkex]

There is also GUICtrlSetOnHover_UDF.au3, it is very good, that's what i use in EMP.

[Minikori]

Take a look at this one and see if it helps.

http://www.autoitscript.com/forum/index.php?showtopic=33230

This would work, but I have over 100 controls, it would be too much code. Something else or a short example would be nice.

[martin]

This would work, but I have over 100 controls, it would be too much code. Something else or a short example would be nice.

Perhaps something like this.

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$Button1 = GUICtrlCreateButton("Button1", 120, 104, 75, 25, 0)
$Button2 = GUICtrlCreateButton("Button2", 320, 136, 75, 25, 0)
$Button3 = GUICtrlCreateButton("Button3", 168, 280, 75, 25, 0)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 240, 24, 97, 17)
$Radio1 = GUICtrlCreateRadio("Radio1", 416, 48, 113, 17)
$Input1 = GUICtrlCreateInput("Input1", 48, 16, 121, 21)
$Label1 = GUICtrlCreateLabel("", -72, -168, 36, 17, BitOr($WS_BORDER,$WS_CLIPSIBLINGS));, BitOR($WS_EX_CLIENTEDGE,$WS_EX_STATICEDGE))
GUICtrlSetBkColor(-1,0xffffaa)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$lastOver = 0
While 1
    $msg = GUIGetMsg()
    $cur = GUIGetCursorInfo()
    If IsArray($cur) Then
        ConsoleWrite($cur[4] & @CRLF)
        If $cur[4] <> $lastOver and $cur[4] <> $label1 and $cur[4] <> 0 Then
            $cp = controlgetpos($Form1,"",$cur[4])
            controlmove($Form1,"",$label1,$cp[0] - 4,$cp[1] - 4,$cp[2] + 8,$cp[3]+8)
            GUICtrlSetState($cur[4],$GUI_FOCUS)
            $lastOver = $cur[4]
        EndIf
    EndIf
  if $msg = -3 then exit
;More code...
WEnd

Edited October 10, 2008 by martin

[Minikori]

Perhaps something like this.

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$Button1 = GUICtrlCreateButton("Button1", 120, 104, 75, 25, 0)
$Button2 = GUICtrlCreateButton("Button2", 320, 136, 75, 25, 0)
$Button3 = GUICtrlCreateButton("Button3", 168, 280, 75, 25, 0)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 240, 24, 97, 17)
$Radio1 = GUICtrlCreateRadio("Radio1", 416, 48, 113, 17)
$Input1 = GUICtrlCreateInput("Input1", 48, 16, 121, 21)
$Label1 = GUICtrlCreateLabel("", -72, -168, 36, 17, BitOr($WS_BORDER,$WS_CLIPSIBLINGS));, BitOR($WS_EX_CLIENTEDGE,$WS_EX_STATICEDGE))
GUICtrlSetBkColor(-1,0xffffaa)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$lastOver = 0
While 1
    $msg = GUIGetMsg()
    $cur = GUIGetCursorInfo()
    If IsArray($cur) Then
        ConsoleWrite($cur[4] & @CRLF)
        If $cur[4] <> $lastOver and $cur[4] <> $label1 and $cur[4] <> 0 Then
            $cp = controlgetpos($Form1,"",$cur[4])
            controlmove($Form1,"",$label1,$cp[0] - 4,$cp[1] - 4,$cp[2] + 8,$cp[3]+8)
            GUICtrlSetState($cur[4],$GUI_FOCUS)
            $lastOver = $cur[4]
        EndIf
    EndIf
  if $msg = -3 then exit
;More code...
WEnd

Ok. This works, but like I said; I have over 100 controls, it would be too much code.

[Minikori]

Ok I edited your code and made it work, thanks.

[MrCreatoR]

As suggested by @AdmiralAlkex, you can also use GUICtrlSetOnHover, it will be much easier:

expandcollapse popup

#include <GuiCtrlSetOnHover_UDF.au3>
Opt("GuiOnEventMode", 1)

$Btn_Color = 0x7A9DD8
$Hover_Color = 0xFF0000 ;0x7AC5D8

$GUIMain = GUICreate("GuiCtrlSetOnHover - Letters Demo", 570, 200)
GUISetOnEvent(-3, "Quit")

GUICtrlCreateLetters(10, 60, 18, 20)

GUICtrlCreateButton("Close", 30, 120, 100, 30)
GUICtrlSetOnEvent(-1, "Quit")

GUICtrlSetFont(GUICtrlCreateLabel("Letter: ", 35, 170, 200, 20), 9, 800)
$Status_Label = GUICtrlCreateLabel("", 80, 171, 200, 20)
GUICtrlSetColor(-1, 0xFF0000)
GUICtrlSetFont(-1, 8.5, 800)

GUISetState()

While 1
    Sleep(100)
WEnd

Func GUICtrlCreateLetters($iLeft, $Top, $Width=15, $Height=15)
    Local $iLeft_Begin = $iLeft
    Local $iAsc_Char = 64
    For $i = 0 To 25
        $iLeft_Begin += 20
        $iAsc_Char += 1
        GUICtrlCreateButton(Chr($iAsc_Char), $iLeft_Begin, $Top, $Width, $Height)
        GUICtrlSetOnEvent(-1, "LetterEvents")
        GUICtrlSetOnHover(-1, "Hover_Func", "Leave_Hover_Func")
        GUICtrlSetBkColor(-1, $Btn_Color)
        GUICtrlSetFont(-1, 6)
    Next
EndFunc

Func LetterEvents()
    MsgBox(64, "Pressed", "Letter = " & GUICtrlRead(@GUI_CtrlId))
EndFunc

Func Hover_Func($CtrlID)
    GUICtrlSetBkColor($CtrlID, $Hover_Color)
    GUICtrlSetData($Status_Label, GUICtrlRead($CtrlID))
    Beep(1000, 20)
EndFunc

Func Leave_Hover_Func($CtrlID)
    GUICtrlSetBkColor($CtrlID, $Btn_Color)
    GUICtrlSetData($Status_Label, "")
EndFunc

Func Quit()
    Exit
EndFunc

[Minikori]

Thanks, but I'd prefer to do what I have because it doesn't require a UDF for the source.