_GUICtrlTab_Create problem in resizing

[torels]

Hi there

I can't resize a tab control created with _GUICtrlTab_Create()

I tried using control move without success...

can anybody help plase ?

thanks in advance

[martin]

Hi there

I can't resize a tab control created with _GUICtrlTab_Create()

I tried using control move without success...

can anybody help plase ?

thanks in advance

Should work so I think you have made a mistake perhaps. Here is an example

ControlMove($hGui,"","[CLASS:SysTabControl32;INSTANCE:1]",2,2,200,150)

[torels]

thanks martin

Anyway... I had a stupid error XD

$width = ControlGetPos($Gui,"",$MainTab)
    $WinWidth = WinGetPos($gui)
    If $width < $WinWidth Then ;<------ THE ERROR now replaced with If $width[3] < $WinWidth[3] Then
        ControlMove($Gui,"",$MainTab, $width[0], $width[1], $WinWidth[2])
    EndIf

[rasim]

Hi there

I can't resize a tab control created with _GUICtrlTab_Create()

I tried using control move without success...

can anybody help plase ?

thanks in advance

Try this:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Global $hTab

_Main()

Func _Main()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("(UDF Created) Tab Control Create", 300, 200, -1, -1, _
                        BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $hTab = _GUICtrlTab_Create($hGUI, 10, 10, 280, 180)
    
    GUIRegisterMsg($WM_SIZE, "WM_SIZE")
    
    GUISetState()

    ; Add tabs
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
    
    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_SIZE($hWnd, $Msg, $wParam, $lParam)
    Local $iWidth = BitAND($lParam, 0x0000FFFF)
    Local $iHeight = BitShift($lParam, 16)
    
    _WinAPI_SetWindowPos($hTab, $hTab, 10, 10, $iWidth - 20, $iHeight - 20, BitOR($SWP_NOMOVE, $SWP_NOZORDER, $SWP_NOACTIVATE))
    
    Return $GUI_RUNDEFMSG
EndFunc