_GuiCtrllistview_DeleteAllItems not working when using imagelist.

[Nahuel]

I want to delete all items of a list without having to destroy the image list, because the listview will be re-used.

expandcollapse popup

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hImage, $hListView
    
    GUICreate("ListView Set Image List", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

; Load images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

; Add items
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

; Get image list handle
    MsgBox(0,"","Now will try to delete all items!")
    if Not _GUICtrlListView_DeleteAllItems($hlistview) Then MsgBox(0,"","Didn't work :(")

; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc  ;==>_Main

Hope it's clear

[Madza91]

Use _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($hListView))

[mmavipc]

use

_GUICtrlListView_DeleteAllItems(controlid)

Hope that helps

[Nahuel]

Use _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($hListView))

Yes, tried that. Works and it's incredibly faster, but the memory usage keeps growing. I read somewhere else that this is because that method doesn't delete the control id's.

Edited November 23, 2008 by Nahuel

[mmavipc]

Yes, tried that. Works and it's incredibly faster, but the memory usage keeps growing. I read somewhere else that this is because that method doesn't delete the control id's.

try storing all of the control ids of the items in an array then use a for loop with _GUICtrlListView_DeleteItem($hWnd, $iIndex) to delete them all?

[Nahuel]

try storing all of the control ids of the items in an array then use a for loop with _GUICtrlListView_DeleteItem($hWnd, $iIndex) to delete them all?

That's pretty much what _GuiCtrlListView_DeleteAllItems does. And deleting the items one by one doesn't work either with the control ID's when using an imagelist.

[mmavipc]

That's pretty much what _GuiCtrlListView_DeleteAllItems does. And deleting the items one by one doesn't work either with the control ID's when using an imagelist.

do what i said in combination with GUICtrlDelete ( controlID ) or try just using GUICtrlDelete ( controlID )

[Nahuel]

Thanks, but that doesn't work either.

[Madza91]

Oh...

Are you tried with GUICtrlSetImage() to set images (and you will not need ImageList) ?

Little example

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $input1, $msg
    
    GUICreate("listview items", 220, 250, -1, -1)

    $listview = GUICtrlCreateListView("col1  |col2|col3  ", 10, 10, 200, 150);,$LVS_SORTDESCENDING)
    $button = GUICtrlCreateButton("Value?", 75, 170, 70, 20)
    $item1 = GUICtrlCreateListViewItem("item2|col22|col23", $listview)
    $item2 = GUICtrlCreateListViewItem("item1|col12|col13", $listview)
    $input1 = GUICtrlCreateInput("", 20, 200, 150)
    GUISetState()
    GUICtrlSetData($item1, "ITEM1")
    GUICtrlSetData($item2, "||COL33")
    GUICtrlSetImage($item2, "shell32.dll", -5)
    GUICtrlDelete($item1)

    Do
    $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE
EndFunc ;==>Example

Edited November 23, 2008 by n3nE

[GaryFrost]

Being that the items were created using the UDFs you need to get the handle to the listview. Also might be a good idea to set the imagelist back to the old and destroy the new.

expandcollapse popup

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hImage, $hListView, $hOld
    
    GUICreate("ListView Set Image List", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

; Load images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    $hOld = _GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

; Add items
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

; Get image list handle
    MsgBox(0,"","Now will try to delete all items!")
    _GUICtrlListView_SetImageList($hListView, $hOld, 1)
    ConsoleWrite("Destroyed? " & _GUIImageList_Destroy($hImage) & @CRLF)
    if Not _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($hlistview)) Then    MsgBox(0,"","Didn't work :(")

; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc  ;==>_Main

[Nahuel]

Thank you