Cut sentecten after X chars

[andrew2]

i am looking for a way to cuut a long sentence afer X chars

i tried to count the stringlenght with StringLen

search for a whitespace and cut the string there with StringSplit but it wouldnt hel at all

does anybody has a tip for me

[Valuater]

Maybe,,,

$string = "123456789 abcdefghi"

$split = StringSplit($string, " ")

MsgBox(0x0, "", $split[1])

8)

[Rental]

StringLeft ( "string", count ) cuts the end off the string after X chars

[andrew2]

i know all both functions but i need to cut the sentence after x chars and make a twoline text out of it.

short explain of my problem would be nice hehe

i got a textbox in a gui the textbox is used to retrieve messages from a webpage mostly just text.

the textbox has a char limit of 65 what it can display but if i got a text which is 100 chars or more

i got displaying problems and would need a scrollbar and i dont want scrollbars so cut the sentence each 65 char

and put it to the next line.

[MrCreatoR]

Use StringLeft and then StringMid...

$sString = "Some long Data..."

$s65Chars = StringLeft($sString, 65)
$sAfter65Chars = StringMid($sString, 66)

[andrew2]

ok is there a way to repeat this until the end of the sentence is reached

[KaFu]

Have such a function in my script SMF...

expandcollapse popup

#include<GUIConstantsEx.au3>
#include<array.au3>

Local $msg

    GUICreate("My GUI",250,150)  ; will create a dialog box that when displayed is centered
    $c_label = GUICtrlCreateLabel("",20,20,200,200)
    GUICtrlSetFont(-1, 8, 400, 0, 'Lucida Console')
   
    GUICtrlSetData(-1,_String_Wrap( "abcdefghijklmnopqrstuvwxyzabcdefghijklmnopqrstuvwxyzabcdefghi" _
                                  & "jklmnopqrstuvwxyzabcdefghijklmnopqrstuvwxyzabcdefghijklmnopqr" _
                                  & "stuvwxyzabcdefghijklmnopqrstuvwxyz", 30))
   
    GUISetState(@SW_SHOW)       ; will display an empty dialog box

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    GUIDelete()



Func _String_Wrap($sString_Wrap_StringToSplit = "", $iString_Wrap_NoCharacters = 20)
   
    Local $aString_Wrap_StringToSplit, $aString_Wrap_StringToSplit_Save
    If StringLen($sString_Wrap_StringToSplit) > $iString_Wrap_NoCharacters Then
        StringReplace($sString_Wrap_StringToSplit, @CRLF, @LF)
        $aString_Wrap_StringToSplit = StringSplit($sString_Wrap_StringToSplit, @LF)
        For $i = 1 To UBound($aString_Wrap_StringToSplit) - 1
            $aString_Wrap_StringToSplit_Save = ""
            While StringLen($aString_Wrap_StringToSplit[$i]) > $iString_Wrap_NoCharacters
                $aString_Wrap_StringToSplit_Save &= StringLeft($aString_Wrap_StringToSplit[$i], $iString_Wrap_NoCharacters) & @LF
                $aString_Wrap_StringToSplit[$i] = StringRight($aString_Wrap_StringToSplit[$i], StringLen($aString_Wrap_StringToSplit[$i]) - $iString_Wrap_NoCharacters)
            WEnd
            $aString_Wrap_StringToSplit[$i] = $aString_Wrap_StringToSplit_Save & $aString_Wrap_StringToSplit[$i]
        Next
        Return _ArrayToString($aString_Wrap_StringToSplit, "", 1)
    Else
        Return $sString_Wrap_StringToSplit
    EndIf
EndFunc   ;==>_String_Wrap

If you use it on a label combined with the monospace font GUICtrlSetFont($c_label, 8, 400, 0, 'Lucida Console') the relative max-size always stays the same...

Edited December 8, 2008 by KaFu

[andrew2]

i wrote my own little function but somehow my script stops after the first value

Func _SplitStringAfterXChars ( $i_UserText, $i_StringToSplit = "<BR>", $i_StringDelimiterForce = 1)
$i_Splitted = StringSplit($i_UserText,$i_StringToSplit,$i_StringDelimiterForce)
$i_SplitNum = 1
While $i_SplitNum <= $i_Splitted[0]
return $i_Splitted[$i_SplitNum]
$i_SplitNum = $i_SplitNum + 1
WEnd
EndFunc

my srting delimiter is a htmlcode for nextline <BR> because my script retrieves html code

my problem know if my sentence would be Hello my<BR>World my function

only return Hello my and the world is complete

missing i appretiate your help kafu your function

is working but if i want to learn i need to know what is wrong in my

function so i can to it better next time

Edited December 8, 2008 by andrew2

[KaFu]

Help-File

Use the Return keyword to exit the function.

Return should be below the wend. Create a string in the wend like $string &= @crlf & $i_Splitted[$i_SplitNum]

[andrew2]

Help-File

Use the Return keyword to exit the function.

Return should be below the wend. Create a string in the wend like $string &= @crlf & $i_Splitted[$i_SplitNum]

id did now it looks like this

Func _SplitStringAfterXChars ( $i_UserText, $i_StringToSplit = " ", $i_StringDelimiterForce = 1)
$i_Splitted = StringSplit($i_UserText,$i_StringToSplit,$i_StringDelimiterForce)
$i_SplitNum = 1
While $i_SplitNum <= $i_Splitted[0]
$string &= @crlf & $i_Splitted[$i_SplitNum]
$i_SplitNum = $i_SplitNum + 1
WEnd
Return $string
EndFunc

i got the following error WARNING: $string possibly not declared/created yet

EDIT : Ok fixed i just declared $string = "" on the beginning and its working now thx kafu

Edited December 8, 2008 by andrew2

[KaFu]

MsgBox(0, "", _SplitStringAfterXChars("Hello my<BR>World", "<BR>"))

Func _SplitStringAfterXChars($i_UserText, $i_StringToSplit = " ", $i_StringDelimiterForce = 1)
    local $string
    $i_Splitted = StringSplit($i_UserText, $i_StringToSplit, $i_StringDelimiterForce)
    $i_SplitNum = 1
    While $i_SplitNum <= $i_Splitted[0]
        $string &= @CRLF & $i_Splitted[$i_SplitNum]
        $i_SplitNum = $i_SplitNum + 1
    WEnd
    Return $string
EndFunc   ;==>_SplitStringAfterXChars

[MrCreatoR]

ok is there a way to repeat this until the end of the sentence is reached

You can use StringRegExp to get an array:

#include <Array.au3>
#include <String.au3>

$sString = _StringRepeat("Some long Data..." & @CRLF, 100)

$a65Strings = StringRegExp($sString, "(?s).{0,64}[^\s]", 3)

If IsArray($a65Strings) Then
    ConsoleWrite("[0] Lenght = " & StringLen($a65Strings[0]) & @CRLF)
    ConsoleWrite("[29] Lenght = " & StringLen($a65Strings[29]) & @CRLF)
    
    _ArrayDisplay($a65Strings)
EndIf