Move and Resize an object

[Floppy]

Hi,

how can i create a movable and resizable object? for example, a resizable label?

thanks in advance

[Melba23]

@FSoft,

Create the control as normal and then use GUICtrlSetPos to place it where you wish at whatever size you want.

M23

[Floppy]

No, you don't understood me.

The object can be resizable also in compiled script.

For example, I can move/resize the object with the mouse without edit the script.

Edited December 22, 2008 by FSoft

[Kip]

guictrlsetpos, guigetcursorinfo

[rasim]

@FSoft

Example:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>

$hGUI = GUICreate("Test", 300, 200)

$cLabel = GUICtrlCreateLabel("Move me", 100, 50, 60, 20)
GUICtrlSetBkColor(-1, 0x00FF00)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _ControlMove($cLabel)
    EndSwitch
WEnd

Func _ControlMove($cID)
    Local $aCurPos = GUIGetCursorInfo()
    If @error Then Return False
    
    If $aCurPos[4] = $cID Then SendMessage(GUICtrlGetHandle($cLabel), $WM_SYSCOMMAND, BitOR($SC_MOVE, $HTCAPTION), 0)
EndFunc   ;==>_ControlMove

Func SendMessage($hWnd, $Msg, $wParam, $lParam)
    DllCall("User32.dll", "int", "SendMessage", _
                                 "hWnd", $hWnd, _
                                 "int", $Msg, _
                                 "int", $wParam, _
                                 "int", $lParam)
EndFunc   ;==>SendMessage

[Kip]

Better way: Moves all controls in a window.

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>

$hGUI = GUICreate("Test", 300, 200)

GUICtrlCreateLabel("Move me", 100, 50, 60, 20)
GUICtrlSetBkColor(-1, 0x00FF00)

GUICtrlCreateButton("hi",40,100,80,23)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $cInfo = GUIGetCursorInfo($hGUI)
            $iControl = $cInfo[4]
            
            
            If $iControl Then
                
                $aPos = ControlGetPos($hGUI,"",$iControl)
                
                $iSubtractX = $cInfo[0]-$aPos[0]
                $iSubtractY = $cInfo[1]-$aPos[1]
                
                Do
                    
                    $cInfo = GUIGetCursorInfo($hGUI)
                    
                    ControlMove($hGUI, "", $iControl, $cInfo[0]-$iSubtractX, $cInfo[1]-$iSubtractY)
                    
                Until Not $cInfo[2]
                
            EndIf
            
    EndSwitch
WEnd

Edited December 23, 2008 by Kip

[Floppy]

it works...thank you very much

[Kip]

Ofcourse it works.