listview icon problem

[zaini]

How to solve this problem..???

I want to display all the icon from C:\windows in list view...

but it always display a same icon for a different file...

if i put "GUICtrlSetImage(-1,$FileList[$i],0)" it place the icon on tab..

please some body help me to solve this...

expandcollapse popup

#include <GUIConstants.au3>
#include <GuiListView.au3>
#Include <File.au3>
#Include <Array.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$Tab1 = GUICtrlCreateTab(8, 32, 617, 313)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
$ListView1 = GUICtrlCreateListView("NO|File List", 16, 72, 593, 225)
GUICtrlSendMsg(-1, 0x101E, 0, 50)
GUICtrlSendMsg(-1, 0x101E, 1, 200)
$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$FileList=_FileListToArray("C:\windows\","*.exe")


For $i = 0 To UBound($FileList)-1
    $list = _GUICtrlListView_AddItem($ListView1, $i, 0)
        _GUICtrlListView_AddSubItem($ListView1, $list, $FileList[$i], 1, -1)
        GUICtrlSetImage($ListView1,$FileList[$i],0)
Next



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

[zaini]

there is a way..??

[Zedna]

#include <GUIConstants.au3>
#Include <File.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$Tab1 = GUICtrlCreateTab(8, 32, 617, 313)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
$ListView1 = GUICtrlCreateListView("NO|File List", 16, 72, 593, 225)
GUICtrlSendMsg(-1, 0x101E, 0, 50)
GUICtrlSendMsg(-1, 0x101E, 1, 200)
$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$FileList=_FileListToArray("C:\windows\","*.exe")

For $i = 0 To UBound($FileList)-1
    GUICtrlCreateListViewItem($i & '|' & $FileList[$i], $ListView1)
    GUICtrlSetImage(-1,$FileList[$i],0)
Next


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Edited December 22, 2008 by Zedna

[MrCreatoR]

You should use _GUICtrlListView_SetItemImage (and build an image list for that), or use standard functions to insert the items...

#include <GUIConstantsEx.au3>
#Include <File.au3>
;

$Form1 = GUICreate("Form1", 633, 447, 193, 125)

$Tab1 = GUICtrlCreateTab(8, 32, 617, 313)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)

$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")

$ListView1 = GUICtrlCreateListView("NO|File List", 16, 72, 593, 225)
GUICtrlSendMsg(-1, 0x101E, 0, 50)
GUICtrlSendMsg(-1, 0x101E, 1, 200)

$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW)

$FileList = _FileListToArray(@WindowsDir, "*.exe", 1)

For $i = 1 To $FileList[0]
    GUICtrlCreateListViewItem($i & "|" & $FileList[$i], $ListView1)
    GUICtrlSetImage(-1, @WindowsDir & "\" & $FileList[$i], 0)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[zaini]

Hahaha...just remove the include and is done..

thanks ZEDNA and MRCREATOR...

Edited December 22, 2008 by zaini