Close All Open Windows with script

[Damien56546]

Hi,

I am using WinClose()

But I don't want to specify title, I want it to shut all windows that are currently open.

Is there a reg expression that covers ALL possibilities? how to do that ?

Cheers.

[Zedna]

Use WinList

[MrCreatoR]

Are you sure you want to do it? even the hidden windows? - Try this example:

$aWinList = WinList()

$sClose_WinList_Msg = ""
$sClose_WinList_Exec = ""

For $i = 1 To $aWinList[0][0]
    If $aWinList[$i][0] = "" Then ContinueLoop
    
    If BitAND(WinGetState($aWinList[$i][1]), 2) Then
        $sClose_WinList_Msg &= 'WinClose("' & $aWinList[$i][0] & '")' & @CRLF
        $sClose_WinList_Exec &= 'WinClose(' & $aWinList[$i][1] & ')|'
    EndIf
    
    ;To close them without warning, uncomment the next lines (the second one will close even hidden windows)
    ;If BitAND(WinGetState($aWinList[$i][1]), 2) Then WinClose($aWinList[$i][1])
    ;WinClose($aWinList[$i][1])
Next

$iAsk = MsgBox(52, "Attention...", "Are you sure? Close theese windows:" & @CRLF & @CRLF & $sClose_WinList_Msg)

If $iAsk = 6 Then
    $aWinList = StringSplit($sClose_WinList_Exec, "|")
    
    For $i = 1 To $aWinList[0]
        If $aWinList[$i] <> "" Then Execute($aWinList[$i])
    Next
EndIf