Smooth Scrolling (Marquee) Text with GDI

[GtaSpider]

Hi and Happy New Year everyone

Does anyone know a way, how to scroll Text with GDIPlus smoothie with DrawString (_GDIPlus_DrawStringEx)?

I know, I can use the String... commands like StringTrimLeft and so one. But this dont looks smooth, if I use a nonmonospaced Font (like e.g. Arial)

I want to say e.g. he should go every 100ms 2 Pixels left. Dont matter, if the Text is "WWWW" or "IIII" ;-)

This should work on a graphic object.

Would be great, if someone have got an Idea, and sorry again for my bad horrible english.

Thanks

Your Spider

[monoceres]

Something like this maybe?

expandcollapse popup

#include <GDIPlus.au3>

Opt("GUIOnEventMode", 1)

$hwnd = GUICreate("GDI+ Example", 400, 300)
$label = GUICtrlCreateLabel("", 10, 10, 380, 40)
GUICtrlCreateButton("Start/Stop scrolling",150,50,100,30)
GUICtrlSetOnEvent(-1,"startstop")
GUISetOnEvent(-3, "close")
GUISetBkColor(0xF0F0F0)
GUISetState()

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND(ControlGetHandle($hwnd, "", $label))
$bitmap = _GDIPlus_BitmapCreateFromGraphics(380, 40, $graphics)
$backbuffer = _GDIPlus_ImageGetGraphicsContext($bitmap)

$ffamily = _GDIPlus_FontFamilyCreate("Arial")
$arial = _GDIPlus_FontCreate($ffamily, 24)

$sformat = _GDIPlus_StringFormatCreate()
_GDIPlus_StringFormatSetAlign($sformat, 1)
$blackbrush = _GDIPlus_BrushCreateSolid()

$pos = 0
$speed=0


Do
    _GDIPlus_GraphicsClear($backbuffer, 0xFFF0F0F0)
    
    $pos -= $speed
    $rectf = _GDIPlus_RectFCreate($pos, 0, 380, 40)
    If $pos < -300 Then $pos = 300
    
    
    _GDIPlus_GraphicsDrawStringEx($backbuffer, "Scrolling text", $arial, $rectf, $sformat, $blackbrush)
    
    _GDIPlus_GraphicsDrawImageRect($graphics, $bitmap, 0, 0, 380, 40)
    Sleep(10)
Until False

Func startstop()
    $speed=Not $speed
EndFunc



Func close()
    _GDIPlus_BrushDispose($blackbrush)
    _GDIPlus_StringFormatDispose($sformat)
    _GDIPlus_FontDispose($arial)
    _GDIPlus_FontFamilyDispose($ffamily)
    _GDIPlus_GraphicsDispose($backbuffer)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

[GtaSpider]

Hello

Hey, i like ya dude. Thank you

Doesn't looks bad, but there is a problem:

The width don't automatically fits to the Text length if I change the Text (the Text is sometimes 2 chars Len and sometimes 50 chars ;-) )

And i don't can use something like StringLen, because the string can be III or the string can be WWW, so the chars don't have the same width.

Have you an Idea? It's for my G15 ;-)

By the way: In some days I will release a complete new G15 LCD UDF. This UDF connect directly to the Logitech SDK and is so faster and better than the old one with the AvLCD.dll.

Spider

[SmOke_N]

Would probably be easier to use GUICtrlCreateObj + htm text/javascript for the scroll. No overhead and you don't have to be married to a loop.

[monoceres]

Hello

Hey, i like ya dude. Thank you

Doesn't looks bad, but there is a problem:

The width don't automatically fits to the Text length if I change the Text (the Text is sometimes 2 chars Len and sometimes 50 chars ;-) )

And i don't can use something like StringLen, because the string can be III or the string can be WWW, so the chars don't have the same width.

Have you an Idea? It's for my G15 ;-)

By the way: In some days I will release a complete new G15 LCD UDF. This UDF connect directly to the Logitech SDK and is so faster and better than the old one with the AvLCD.dll.

Spider

Ah I see. Well then _GDIPlus_GraphicsMeasureString does the trick

expandcollapse popup

#include <GDIPlus.au3>

Opt("GUIOnEventMode", 1)

$hwnd = GUICreate("GDI+ Example", 400, 100)
$label = GUICtrlCreateLabel("", 10, 10, 380, 40)
GUICtrlCreateButton("Start/Stop scrolling", 150, 50, 100, 30)
GUICtrlSetOnEvent(-1, "startstop")
GUISetOnEvent(-3, "close")
GUISetBkColor(0xF0F0F0)
GUISetState()

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND(ControlGetHandle($hwnd, "", $label))
$bitmap = _GDIPlus_BitmapCreateFromGraphics(380, 40, $graphics)
$backbuffer = _GDIPlus_ImageGetGraphicsContext($bitmap)

$ffamily = _GDIPlus_FontFamilyCreate("Arial")
$arial = _GDIPlus_FontCreate($ffamily, 24)

$sformat = _GDIPlus_StringFormatCreate()
;~ _GDIPlus_StringFormatSetAlign($sformat, 1)
$blackbrush = _GDIPlus_BrushCreateSolid()

$pos = 0
$speed = 1

$text = "This is a string"

Do
    _GDIPlus_GraphicsClear($backbuffer, 0xFFF0F0F0)


    $pos -= $speed
    $rectf = _GDIPlus_RectFCreate($pos, 0, 380, 40)
    $arr = _GDIPlus_GraphicsMeasureString($graphics, $text, $arial, $rectf, $sformat)
    $stringwidth = DllStructGetData($arr[0], "Width")
    If $pos < -$stringwidth Then $pos = $stringwidth*2


    _GDIPlus_GraphicsDrawStringEx($backbuffer, $text, $arial, $rectf, $sformat, $blackbrush)

    _GDIPlus_GraphicsDrawImageRect($graphics, $bitmap, 0, 0, 380, 40)
    Sleep(10)
Until False

Func startstop()
    $speed = Not $speed
EndFunc  ;==>startstop



Func close()
    _GDIPlus_BrushDispose($blackbrush)
    _GDIPlus_StringFormatDispose($sformat)
    _GDIPlus_FontDispose($arial)
    _GDIPlus_FontFamilyDispose($ffamily)
    _GDIPlus_GraphicsDispose($backbuffer)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

[GtaSpider]

Hello

Ah, thank you very much mate This is fantastic. Perfect

Your Spider

[a440hz]

Thank you very much for this useful script monoceres. I'm unable to get it to work with longer strings. Any suggestions?

-Regards, Joe

expandcollapse popup

#include <GDIPlus.au3>

Opt("GUIOnEventMode", 1)

$hwnd = GUICreate("GDI+ Example", 400, 100)
$label = GUICtrlCreateLabel("", 10, 10, 380, 40)
GUICtrlCreateButton("Start/Stop scrolling", 150, 50, 100, 30)
GUICtrlSetOnEvent(-1, "startstop")
GUISetOnEvent(-3, "close")
GUISetBkColor(0xF0F0F0)
GUISetState()

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND(ControlGetHandle($hwnd, "", $label))
$bitmap = _GDIPlus_BitmapCreateFromGraphics(380, 40, $graphics)
$backbuffer = _GDIPlus_ImageGetGraphicsContext($bitmap)

$ffamily = _GDIPlus_FontFamilyCreate("Arial")
$arial = _GDIPlus_FontCreate($ffamily, 24)

$sformat = _GDIPlus_StringFormatCreate()
;~ _GDIPlus_StringFormatSetAlign($sformat, 1)
$blackbrush = _GDIPlus_BrushCreateSolid()

$pos = 0
$speed = 1

$text = "This is a string that is too long to scroll right."

Do
    _GDIPlus_GraphicsClear($backbuffer, 0xFFF0F0F0)


    $pos -= $speed
    $rectf = _GDIPlus_RectFCreate($pos, 0, 380, 40)
    $arr = _GDIPlus_GraphicsMeasureString($graphics, $text, $arial, $rectf, $sformat)
    $stringwidth = DllStructGetData($arr[0], "Width")
    If $pos < -$stringwidth Then $pos = $stringwidth*2


    _GDIPlus_GraphicsDrawStringEx($backbuffer, $text, $arial, $rectf, $sformat, $blackbrush)

    _GDIPlus_GraphicsDrawImageRect($graphics, $bitmap, 0, 0, 380, 40)
    Sleep(10)
Until False

Func startstop()
    $speed = Not $speed
EndFunc  ;==>startstop



Func close()
    _GDIPlus_BrushDispose($blackbrush)
    _GDIPlus_StringFormatDispose($sformat)
    _GDIPlus_FontDispose($arial)
    _GDIPlus_FontFamilyDispose($ffamily)
    _GDIPlus_GraphicsDispose($backbuffer)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

[a440hz]

I found Marquee.au3 to do the trick for me.

[Melba23]

Hi,

If anyone is interested, Marquee.au3 can be found here.

M23

Edit: The board did not like the first link!

Edited May 9, 2010 by Melba23

[a440hz]

Hi,

If anyone is interested, Marquee.au3 can be found here.

M23

Edit: The board did not like the first link!

Hi Melba23 and thank you! Pardon me for not providing a link myself. Got so darned tied up trying to hurdle my own programming deficiencies that I neglected not only to acknowledge you for your excellent script but to offer an easy way for others to benefit from it.

All the best,

Joe